BuildingTransmissionQtMac: qtr-macx.pro

File qtr-macx.pro, 2.4 KB (added by nnc, 11 years ago)
Line 
1TARGET = transmission-qt
2NAME = "Transmission"
3DESCRIPTION = "Transmission: a fast, easy, and free BitTorrent client"
4VERSION = 2.00
5LICENSE = "GPL"
6
7target.path = /bin
8INSTALLS += target
9
10unix: INSTALLS += man
11man.path = /share/man/man1/
12man.files = transmission-qt.1
13
14CONFIG += qt qdbus thread release
15QT += network
16!macx {
17        CONFIG += debug link_pkgconfig
18        PKGCONFIG = fontconfig libcurl openssl dbus-1
19}
20
21TRANSMISSION_TOP = ..
22INCLUDEPATH += $${TRANSMISSION_TOP}
23macx {
24        CONFIG(release, debug|release) {
25                LIB_PATH = $${TRANSMISSION_TOP}/build/Release
26        } else {
27                LIB_PATH = $${TRANSMISSION_TOP}/build/Debug
28        }
29        LIBS += $${LIB_PATH}/libtransmission.a
30        LIBS += $${LIB_PATH}/libdht.a
31        LIBS += $${LIB_PATH}/libminiupnp.a
32        LIBS += $${LIB_PATH}/libnatpmp.a
33} else {
34        LIBS += $${TRANSMISSION_TOP}/libtransmission/libtransmission.a
35        LIBS += $${TRANSMISSION_TOP}/third-party/dht/libdht.a
36        LIBS += $${TRANSMISSION_TOP}/third-party/miniupnp/libminiupnp.a
37        LIBS += $${TRANSMISSION_TOP}/third-party/libnatpmp/libnatpmp.a
38}
39unix:LIBS += -levent
40macx:LIBS += -lcurl -lssl -lcrypto -liconv -framework CoreFoundation
41win32:DEFINES += QT_DBUS
42win32:LIBS += -levent -lws2_32 -lintl
43win32:LIBS += -lidn -liconv -lwldap32 -liphlpapi
44
45TRANSLATIONS += translations/transmission_en.ts \
46                translations/transmission_es.ts \
47                translations/transmission_pt_BR.ts \
48                translations/transmission_ru.ts
49
50FORMS += mainwin.ui
51RESOURCES += application.qrc
52SOURCES += about.cc \
53           add-data.cc \
54           app.cc \
55           dbus-adaptor.cc \
56           details.cc \
57           favicon.cc \
58           file-tree.cc \
59           filterbar.cc \
60           filters.cc \
61           formatter.cc \
62           hig.cc \
63           license.cc \
64           mainwin.cc \
65           make-dialog.cc \
66           options.cc \
67           prefs.cc \
68           prefs-dialog.cc \
69           relocate.cc \
70           session.cc \
71           session-dialog.cc \
72           squeezelabel.cc \
73           stats-dialog.cc \
74           torrent.cc torrent-delegate.cc \
75           torrent-delegate-min.cc \
76           torrent-filter.cc \
77           torrent-model.cc \
78           tracker-delegate.cc \
79           tracker-model.cc \
80           tracker-model-filter.cc \
81           triconpushbutton.cc \
82           utils.cc \
83           watchdir.cc
84HEADERS += $$replace(SOURCES, .cc, .h)
85HEADERS += speed.h types.h
86
87win32:RC_FILE = qtr.rc