source: trunk/configure.ac @ 11792

Last change on this file since 11792 was 11792, checked in by jordan, 11 years ago

(trunk) update NEWS and bump version to 2.20 beta 3.

File size: 16.0 KB
Line 
1dnl convention: -TR MAJOR MINOR MAINT STATUS - (each a single char)
2dnl STATUS: "X" for prerelease beta builds,
3dnl         "Z" for unsupported trunk builds,
4dnl         "0" for stable, supported releases
5dnl these should be the only two lines you need to change
6m4_define([user_agent_prefix],[2.20b3])
7m4_define([peer_id_prefix],[-TR213X-])
8
9AC_INIT([transmission],
10        [user_agent_prefix],
11        [http://trac.transmissionbt.com/newticket])
12AC_SUBST(USERAGENT_PREFIX,[user_agent_prefix])
13AC_SUBST(PEERID_PREFIX,[peer_id_prefix])
14
15m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
16
17AC_CONFIG_MACRO_DIR([m4])
18
19dnl AM_CONFIG_HEADER(config.h)
20AC_CONFIG_SRCDIR(libtransmission/transmission.h)
21AM_INIT_AUTOMAKE([1.9 tar-ustar])
22AC_PROG_LIBTOOL
23
24if test m4_substr(peer_id_prefix,6,1) = "0"; then
25  supported_build=yes
26  CPPFLAGS="$CPPFLAGS -DNDEBUG"
27else
28  supported_build=no
29  if test "x$GCC" = "xyes" ; then
30    CFLAGS="$CFLAGS -g -O0"
31    CXXFLAGS="$CXXFLAGS -g -O0"
32  fi
33fi
34AM_CONDITIONAL(TR_UNSTABLE, test "x$supported_build" = "xno")
35
36##
37##
38##   MANDATORY for everything
39##
40##
41CURL_MINIMUM=7.15.4
42AC_SUBST(CURL_MINIMUM)
43LIBEVENT_MINIMUM=2.0.10
44AC_SUBST(LIBEVENT_MINIUM)
45OPENSSL_MINIMUM=0.9.4
46AC_SUBST(OPENSSL_MINIMUM)
47
48##
49##
50##   MANDATORY for the GTK+ client
51##
52##
53GLIB_MINIMUM=2.8.0
54AC_SUBST(GLIB_MINIMUM)
55GTK_MINIMUM=2.8.0
56AC_SUBST(GTK_MINIMUM)
57
58##
59##
60##   OPTIONAL for the GTK+ client
61##
62##
63# play the XDG "download done" sound...
64CANBERRA_MINIMUM=0.10
65AC_SUBST(CANBERRA_MINIMUM)
66# inhibit hibernation when a torrent is active...
67DBUS_GLIB_MINIMUM=0.70
68AC_SUBST(DBUS_GLIB_MINIMUM)
69# register the GTK+ client as a magnet link handler...
70GCONF2_MINIMUM=2.20.0
71AC_SUBST(GCONF2_MINIMUM)
72# implement "watch" directories to use new .torrent files...
73GIO_MINIMUM=2.15.5
74AC_SUBST(GIO_MINIMUM)
75# pop up a "download done" notice...
76LIBNOTIFY_MINIMUM=0.4.3
77AC_SUBST(LIBNOTIFY_MINIMUM)
78# create the tray icon with AppIndicator
79LIBAPPINDICATOR_MINIMUM=0.0.11
80  AC_SUBST(LIBAPPINDICATOR_MINIMUM)
81
82
83AC_PROG_CC
84AC_PROG_CXX
85AC_C_INLINE
86if test "x$GCC" = "xyes" ; then
87
88    CFLAGS="$CFLAGS -std=gnu99 -ggdb3 -Wall -W -Wpointer-arith -Wformat-security -Wcast-align -Wundef -Wcast-align -Wstrict-prototypes -Wmissing-declarations -Wmissing-format-attribute -Wredundant-decls -Wnested-externs -Wunused-parameter -Wwrite-strings -Winline -Wfloat-equal"
89
90    dnl figure out gcc version
91    AC_MSG_CHECKING([gcc version])
92    GCC_VERSION=`$CC -dumpversion`
93    GCC_MAJOR=`echo $GCC_VERSION | cut -d . -f1`
94    GCC_MINOR=`echo $GCC_VERSION | cut -d . -f2`
95    GCC_VERSION_NUM=`(expr $GCC_MAJOR "*" 100 + $GCC_MINOR) 2>/dev/null`
96
97    AC_MSG_RESULT($GCC_VERSION)
98    if test $GCC_VERSION_NUM -ge 304; then
99        dnl these were added in 3.4
100        CFLAGS="$CFLAGS -Wextra -Wdeclaration-after-statement -Winit-self"
101    fi
102    if test $GCC_VERSION_NUM -ge 403; then
103        dnl these were added in 4.3
104        CFLAGS="$CFLAGS -Wvariadic-macros"
105    fi
106fi
107
108AC_HEADER_STDC
109AC_HEADER_TIME
110
111AC_CHECK_FUNCS([iconv_open pread pwrite lrintf strlcpy daemon dirname basename strcasecmp localtime_r fallocate64 posix_fallocate memmem strsep strtold syslog valloc getpagesize posix_memalign statvfs])
112AC_PROG_INSTALL
113AC_PROG_MAKE_SET
114ACX_PTHREAD
115
116if test "x$ac_cv_func_strtold" != "xyes" ; then
117    CPPFLAGS="$CPPFLAGS -Dstrtold=strtod"
118fi
119
120AC_SEARCH_LIBS(cos, [m])
121AC_SEARCH_LIBS([socket], [socket net])
122AC_SEARCH_LIBS([gethostbyname], [nsl bind])
123PKG_CHECK_MODULES(OPENSSL, [openssl >= $OPENSSL_MINIMUM], , [CHECK_SSL()])
124PKG_CHECK_MODULES(LIBCURL, [libcurl >= $CURL_MINIMUM])
125PKG_CHECK_MODULES(LIBEVENT, [libevent >= $LIBEVENT_MINIMUM])
126AC_PATH_ZLIB
127
128AC_SYS_LARGEFILE
129AC_CHECK_FUNCS([lseek64])
130
131
132dnl ----------------------------------------------------------------------------
133dnl
134dnl posix_fadvise
135
136dnl can posix_fadvise be used
137AC_CHECK_DECLS(posix_fadvise, [], [], [
138#define _XOPEN_SOURCE 600
139#include <fcntl.h>])
140AC_CHECK_FUNCS([posix_fadvise])
141
142
143dnl ----------------------------------------------------------------------------
144dnl
145dnl file monitoring for the daemon
146
147AC_CHECK_HEADER([sys/inotify.h],
148                [AC_CHECK_FUNC([inotify_init],[have_inotify="yes"],[have_inotify="no"])],
149                [have_inotify="no"])
150AC_ARG_WITH([inotify],
151            [AS_HELP_STRING([--with-inotify],[Enable inotify support (default=auto)])],
152            [want_inotify=${withval}],
153            [want_inotify=${have_inotify}])
154if test "x$want_inotify" = "xyes" ; then
155    if test "x$have_inotify" = "xyes"; then
156      AC_DEFINE([WITH_INOTIFY],[1])
157    else
158      AC_MSG_ERROR("inotify not found!")
159    fi
160fi
161 
162AC_CHECK_HEADER([sys/event.h],
163                [AC_CHECK_FUNC([kqueue],[have_kqueue="yes"],[have_kqueue="no"])],
164                [have_kqueue="no"])
165AC_ARG_WITH([kqueue],
166            [AS_HELP_STRING([--with-kqueue],[Enable kqueue support (default=auto)])],
167            [want_kqueue=${withval}],
168            [want_kqueue=${have_kqueue}])
169if test "x$want_kqueue" = "xyes" ; then
170    if test "x$have_kqueue" = "xyes"; then
171      AC_DEFINE([WITH_KQUEUE],[1])
172    else
173      AC_MSG_ERROR("kqueue not found!")
174    fi
175fi
176
177AC_CHECK_HEADERS([sys/statvfs.h \
178                  xfs/xfs.h])
179
180
181dnl ----------------------------------------------------------------------------
182dnl
183dnl va_copy
184
185AC_MSG_CHECKING([how to copy va_list])
186AC_TRY_LINK([#include <stdarg.h>], [va_list ap1, ap2; va_copy(ap1, ap2);],
187    AC_MSG_RESULT([va_copy]),
188        [ AH_TEMPLATE([va_copy], [define if va_copy is not available])
189        AC_TRY_LINK([#include <stdarg.h>], [va_list ap1, ap2; __va_copy(ap1, ap2);],
190        [ AC_DEFINE([va_copy], [__va_copy])
191        AC_MSG_RESULT([__va_copy])],
192        [ AC_DEFINE([va_copy(dest,src)], [memcpy(&dest,&src,sizeof(va_list))])
193        AC_MSG_RESULT([memcpy])]
194    )
195])
196
197
198dnl libevent likes to link against librt if possible
199dnl for clock_gettime() and clock_settime()
200dnl TODO(libevent2): this can probably be removed after
201dnl we switch to libevent2, since it will have PKG_CONFIG
202AC_CHECK_LIB([rt],
203             [clock_gettime],
204             [libevent_extra_libs="-lrt"],
205             [libevent_extra_libs=""])
206
207
208dnl ----------------------------------------------------------------------------
209dnl
210dnl  dht
211
212DHT_CFLAGS="-I\$(top_srcdir)/third-party/dht"
213DHT_LIBS="\$(top_builddir)/third-party/dht/libdht.a"
214AC_SUBST(DHT_CFLAGS)
215AC_SUBST(DHT_LIBS)
216
217
218dnl ----------------------------------------------------------------------------
219dnl
220dnl  detection for the GTK+ client
221
222PKG_CHECK_MODULES(GTK,
223                  [gtk+-2.0 >= $GTK_MINIMUM
224                   glib-2.0 >= $GLIB_MINIMUM
225                   gmodule-2.0 >= $GLIB_MINIMUM
226                   gthread-2.0 >= $GLIB_MINIMUM],
227                  [have_gtk=yes],
228                  [have_gtk=no])
229AC_ARG_ENABLE([gtk],
230              AS_HELP_STRING([--enable-gtk],[build gtk client]),
231              [want_gtk=${enableval}],
232              [want_gtk=${have_gtk}])
233build_gtk=no
234use_gio=no
235use_libappindicator=no
236use_libnotify=no
237use_dbus_glib=no
238use_canberra=no
239use_gconf2=no
240if test "x$want_gtk" = "xyes" ; then
241    if test "x$have_gtk" = "xyes"; then
242      build_gtk=yes
243    else
244      AC_MSG_ERROR("GTK+ not found!")
245    fi
246fi
247AM_CONDITIONAL([BUILD_GTK],[test "x$build_gtk" = "xyes"])
248
249if test "x$build_gtk" = "xyes"; then
250
251    PKG_CHECK_MODULES([GIO],
252                      [gio-2.0 >= $GIO_MINIMUM],
253                      [use_gio=yes],
254                      [use_gio=no])
255    if test "x$use_gio" = "xyes"; then
256        AC_DEFINE([HAVE_GIO], 1)
257    fi
258
259    PKG_CHECK_MODULES([LIBNOTIFY],
260                      [libnotify >= $LIBNOTIFY_MINIMUM],
261                      [have_libnotify=yes],
262                      [have_libnotify=no])
263    AC_ARG_ENABLE([libnotify],
264                  AS_HELP_STRING([--enable-libnotify],[enable notifications]),,
265                  [enable_libnotify=yes])
266    use_libnotify=no
267    if test "x$have_libnotify" = "xyes"; then
268        if test "x$enable_libnotify" = "xyes" ; then
269            use_libnotify=yes
270            AC_DEFINE([HAVE_LIBNOTIFY], 1)
271        else
272            LIBNOTIFY_CFLAGS=
273            LIBNOTIFY_LIBS=
274        fi
275    fi
276
277    PKG_CHECK_MODULES([LIBAPPINDICATOR],
278                      [appindicator-0.1 >= $LIBAPPINDICATOR_MINIMUM],
279                      [have_libappindicator=yes],
280                      [have_libappindicator=no])
281
282    AC_ARG_ENABLE([libappindicator],
283                  AS_HELP_STRING([--enable-libappindicator],[enable AppIndicator support]),,
284                  [enable_libappindicator=yes])
285    use_libappindicator=no
286    if test "x$have_libappindicator" = "xyes"; then
287        if test "x$enable_libappindicator" = "xyes" ; then
288            use_libappindicator=yes
289            AC_DEFINE([HAVE_LIBAPPINDICATOR], 1)
290        else
291            LIBAPPINDICATOR_CFLAGS=
292            LIBAPPINDICATOR_LIBS=
293        fi
294    fi
295
296    PKG_CHECK_MODULES([LIBCANBERRA],
297                      [libcanberra-gtk >= $CANBERRA_MINIMUM],
298                      [have_libcanberra=yes],
299                      [have_libcanberra=no])
300    AC_ARG_ENABLE([libcanberra],
301                  AS_HELP_STRING([--enable-libcanberra],[enable sounds]),,
302                  [enable_libcanberra=yes])
303    if test "x$have_libcanberra" = "xyes"; then
304        if test "x$enable_libcanberra" = "xyes" ; then
305            use_canberra=yes
306            AC_DEFINE([HAVE_LIBCANBERRA], 1)
307        else
308            LIBCANBERRA_CFLAGS=
309            LIBCANBERRA_LIBS=
310        fi
311    fi
312
313    PKG_CHECK_MODULES([GCONF2],
314                      [gconf-2.0 >= $GCONF2_MINIMUM],
315                      [have_gconf2=yes],
316                      [have_gconf2=no])
317    AC_ARG_ENABLE([gconf2],
318                  AS_HELP_STRING([--enable-gconf2],[enable GConf support]),,
319                  [enable_gconf2=yes])
320    if test "x$have_gconf2" = "xyes"; then
321        if test "x$enable_gconf2" = "xyes" ; then
322            use_gconf2=yes
323            AC_DEFINE([HAVE_GCONF2], 1)
324        else
325            GCONF2_CFLAGS=
326            GCONF2_LIBS=
327        fi
328    fi
329
330    PKG_CHECK_MODULES([DBUS_GLIB],
331                      [dbus-glib-1 >= $DBUS_GLIB_MINIMUM],
332                      [use_dbus_glib=yes],
333                      [use_dbus_glib=no])
334    if test "x$use_dbus_glib" = "xyes"; then
335        AC_DEFINE([HAVE_DBUS_GLIB], 1)
336    fi
337    if test "x$use_dbus_glib" = "xyes"; then
338        AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool, no)
339        if test "x$DBUS_BINDING_TOOL" = xno; then
340          AC_MSG_WARN([Cannot find dbus-binding-tool])
341          use_dbus_glib="no (dbus-binding-tool not found)"
342        fi
343    fi
344fi
345
346AC_ARG_ENABLE([nls],
347              AS_HELP_STRING([--enable-nls],[enable native language support]),,
348              [enable_nls=yes])
349
350if test "x$build_gtk" = "xyes" -a  "x$enable_nls" = "xno" ; then
351    AC_MSG_ERROR("The gtk client cannot be built without nls support.  Try adding either --enable-nls or --disable-gtk" )
352fi
353
354dnl This section is only used for internationalization.
355dnl If you don't need translations and this section gives you trouble --
356dnl such as if you're building for a headless system --
357dnl it's okay to tear this section out and re-build the configure script.
358dnl
359dnl Note to packagers: the bump to intltool 0.40 was made to fix
360dnl a "make check" failure on some systems.  if upgrading to 0.40 is
361dnl a problem and the old version was working fine for you,
362dnl it should be safe to re-edit 0.40 back down to 0.23
363
364use_nls=no
365if test "x$enable_nls" = "xyes" ; then
366    use_nls=yes
367    IT_PROG_INTLTOOL([0.35.0],[no-xml])
368    AC_CHECK_HEADERS([libintl.h])
369    GETTEXT_PACKAGE=transmission-gtk
370    AC_SUBST(GETTEXT_PACKAGE)
371    AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
372    AM_GLIB_GNU_GETTEXT
373    transmissionlocaledir='${prefix}/${DATADIRNAME}/locale'
374    AC_SUBST(transmissionlocaledir)
375fi
376AC_SUBST(INTLLIBS)
377
378
379dnl ----------------------------------------------------------------------------
380dnl
381dnl  platform-specific stuff.
382
383AC_CANONICAL_HOST
384have_darwin="no"
385have_msw="no"
386case $host_os in
387
388   *mingw32*)
389     have_msw="yes"
390     CXXFLAGS="$CXXFLAGS -mms-bitfields -mwin32 -mwindows"
391     CPPFLAGS="$CPPFLAGS -DWIN32 -D_WIN32 -DWIN32_LEAN_AND_MEAN"
392     LIBS="$LIBS -liphlpapi -lshell32 -lws2_32"
393     transmissionlocaledir="locale"
394     if test -z "$host_alias"; then
395       hostaliaswindres=
396     else
397       hostaliaswindres="$host_alias-windres";
398     fi
399     AC_CHECK_TOOL(WINDRES, windres)
400     ;;
401
402  *darwin*)
403    have_darwin="yes"
404    CFLAGS="-DMACOSX $CFLAGS"
405    ;;
406
407esac
408
409AC_ARG_ENABLE([lightweight],
410              AS_HELP_STRING([--enable-lightweight],[optimize libtransmission for low-resource systems: smaller cache size, prefer unencrypted peer connections, etc.]),
411              [enable_lightweight=${enableval}],
412              [enable_lightweight="no"])
413if test "x$enable_lightweight" = "xyes" ; then
414  AC_DEFINE([TR_LIGHTWEIGHT],[1],[optimize libtransmission for low-resource systems])
415fi
416
417AC_ARG_ENABLE([cli],
418              [AS_HELP_STRING([--enable-cli],[build command-line client])],
419              [build_cli=${enableval}],
420              [build_cli="yes"])
421AM_CONDITIONAL([BUILD_CLI],[test "x$build_cli" = "xyes"])
422
423AC_ARG_ENABLE([mac],
424              [AS_HELP_STRING([--enable-mac],[build Mac client])],
425              [build_mac=${enableval}],
426              [build_mac=${have_darwin}])
427AM_CONDITIONAL([BUILD_MAC],[test "x$build_mac" = "xyes"])
428
429AC_ARG_ENABLE([daemon],
430              [AS_HELP_STRING([--enable-daemon],[build daemon])],
431              [build_daemon=${enableval}],
432              [build_daemon="yes"])
433AM_CONDITIONAL([BUILD_DAEMON],[test "x$build_daemon" = "xyes"])
434
435
436if test "x$build_mac" = "xyes" ; then
437    # Make sure the proper Mac SDK is installed
438    if test ! -d /Developer/SDKs/MacOSX10.5.sdk; then
439      cat << EOF
440You need to install the Mac OS X 10.5 SDK in order to build Transmission
441with --enable-mac:
442  Get your Xcode CD or package
443  Restart the install
444  When it gets to "Installation Type", select "Customize"
445  Select "Mac OS X 10.5 SDK" under "Cross Development"
446  Finish the install.
447EOF
448      exit 1
449    fi
450fi
451if test "x$have_darwin" = "xyes"; then
452    AC_DEFINE([HAVE_DARWIN], 1)
453fi
454if test "x$have_msw" = "xyes"; then
455    AC_DEFINE([HAVE_MSW], 1)
456fi
457AM_CONDITIONAL(WIN32, test "x$have_msw" = "xyes")
458
459dnl ----------------------------------------------------------------------------
460dnl
461dnl  Generate the output
462
463AC_CONFIG_FILES([Makefile
464                 transmission-gtk.spec
465                 cli/Makefile
466                 daemon/Makefile
467                 extras/Makefile
468                 libtransmission/Makefile
469                 utils/Makefile
470                 third-party/Makefile
471                 third-party/miniupnp/Makefile
472                 third-party/libnatpmp/Makefile
473                 third-party/dht/Makefile
474                 macosx/Makefile
475                 gtk/Makefile
476                 gtk/icons/Makefile
477                 web/Makefile
478                 web/images/Makefile
479                 web/images/buttons/Makefile
480                 web/images/graphics/Makefile
481                 web/images/progress/Makefile
482                 web/javascript/Makefile
483                 web/javascript/jquery/Makefile
484                 web/stylesheets/Makefile
485                 po/Makefile.in])
486
487AC_OUTPUT
488
489echo "
490
491Configuration:
492
493   Source code location:                              ${srcdir}
494   Compiler:                                          ${CXX}
495
496   Build libtransmission:                             yes
497
498      * optimized for low-resource systems:           ${enable_lightweight}
499
500   Build Command-Line client:                         ${build_cli}
501
502   Build GTK+ client:                                 ${build_gtk}
503
504     Optional dependencies for GTK+ client:
505
506      * dbus support:                                 ${use_dbus_glib}
507      * gio for watchdir support:                     ${use_gio}
508      * libnotify for 'download completed' popups:    ${use_libnotify}
509      * libcanberra for 'download completed' sounds:  ${use_canberra}
510      * gconf2 to register as a magnet link handler:  ${use_gconf2}
511      * libappindicator for an Ubuntu-style tray:     ${use_libappindicator}
512
513   Build Daemon:                                      ${build_daemon}
514
515   Build Mac client:                                  ${build_mac}
516
517"
Note: See TracBrowser for help on using the repository browser.