source: trunk/configure.ac @ 13220

Last change on this file since 13220 was 13220, checked in by livings124, 10 years ago

bump version to 2.50b1

File size: 18.0 KB
Line 
1dnl convention: -TR MAJOR MINOR MAINT STATUS - (each a single char)
2dnl STATUS: "X" for prerelease beta builds,
3dnl         "Z" for unsupported trunk builds,
4dnl         "0" for stable, supported releases
5dnl these should be the only two lines you need to change
6m4_define([user_agent_prefix],[2.50b1])
7m4_define([peer_id_prefix],[-TR242X-])
8
9AC_INIT([transmission],
10        [user_agent_prefix],
11        [http://trac.transmissionbt.com/newticket])
12AC_SUBST(USERAGENT_PREFIX,[user_agent_prefix])
13AC_SUBST(PEERID_PREFIX,[peer_id_prefix])
14
15m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
16
17AC_CONFIG_MACRO_DIR([m4])
18
19dnl AM_CONFIG_HEADER(config.h)
20AC_CONFIG_SRCDIR(libtransmission/transmission.h)
21AM_INIT_AUTOMAKE([1.9 tar-pax])
22AC_PROG_LIBTOOL
23
24if test m4_substr(peer_id_prefix,6,1) = "0"; then
25  supported_build=yes
26  CPPFLAGS="$CPPFLAGS -DNDEBUG"
27else
28  supported_build=no
29  if test "x$GCC" = "xyes" ; then
30    CFLAGS="$CFLAGS -g -O0"
31    CXXFLAGS="$CXXFLAGS -g -O0"
32  fi
33fi
34AM_CONDITIONAL(TR_UNSTABLE, test "x$supported_build" = "xno")
35
36##
37##
38##   MANDATORY for everything
39##
40##
41CURL_MINIMUM=7.15.4
42AC_SUBST(CURL_MINIMUM)
43LIBEVENT_MINIMUM=2.0.10
44AC_SUBST(LIBEVENT_MINIUM)
45OPENSSL_MINIMUM=0.9.4
46AC_SUBST(OPENSSL_MINIMUM)
47
48##
49##
50##   MANDATORY for the GTK+ client
51##
52##
53
54GTK2_MINIMUM=2.22.0
55AC_SUBST(GTK2_MINIMUM)
56GTK3_MINIMUM=3.2.0
57AC_SUBST(GTK3_MINIMUM)
58GLIB_MINIMUM=2.28.0
59AC_SUBST(GLIB_MINIMUM)
60GIO_MINIMUM=2.26.0
61AC_SUBST(GIO_MINIMUM)
62
63##
64##
65##   OPTIONAL for the GTK+ client
66##
67##
68
69# create the tray icon with AppIndicator
70LIBAPPINDICATOR_MINIMUM=0.0.11
71AC_SUBST(LIBAPPINDICATOR_MINIMUM)
72
73
74AC_PROG_CC
75AC_PROG_CXX
76AC_CHECK_PROG([HAVE_CXX],[$CXX],[yes],[no])
77AC_C_INLINE
78if test "x$GCC" = "xyes" ; then
79
80    CFLAGS="$CFLAGS -std=gnu99 -ggdb3 -Wall -W -Wpointer-arith -Wformat-security -Wcast-align -Wundef -Wcast-align -Wstrict-prototypes -Wmissing-declarations -Wmissing-format-attribute -Wredundant-decls -Wnested-externs -Wunused-parameter -Wwrite-strings -Winline -Wfloat-equal"
81
82    dnl figure out gcc version
83    AC_MSG_CHECKING([gcc version])
84    GCC_VERSION=`$CC -dumpversion`
85    GCC_MAJOR=`echo $GCC_VERSION | cut -d . -f1`
86    GCC_MINOR=`echo $GCC_VERSION | cut -d . -f2`
87    GCC_VERSION_NUM=`(expr $GCC_MAJOR "*" 100 + $GCC_MINOR) 2>/dev/null`
88
89    AC_MSG_RESULT($GCC_VERSION)
90    if test $GCC_VERSION_NUM -ge 304; then
91        dnl these were added in 3.4
92        CFLAGS="$CFLAGS -Wextra -Wdeclaration-after-statement -Winit-self"
93    fi
94    if test $GCC_VERSION_NUM -ge 403; then
95        dnl these were added in 4.3
96        CFLAGS="$CFLAGS -Wvariadic-macros"
97    fi
98fi
99
100AC_HEADER_STDC
101AC_HEADER_TIME
102
103AC_CHECK_HEADERS([stdbool.h])
104AC_CHECK_FUNCS([iconv_open pread pwrite lrintf strlcpy daemon dirname basename strcasecmp localtime_r fallocate64 posix_fallocate memmem strsep strtold syslog valloc getpagesize posix_memalign statvfs htonll ntohll mkdtemp])
105AC_PROG_INSTALL
106AC_PROG_MAKE_SET
107ACX_PTHREAD
108
109if test "x$ac_cv_func_strtold" != "xyes" ; then
110    CPPFLAGS="$CPPFLAGS -Dstrtold=strtod"
111fi
112
113AC_SEARCH_LIBS(cos, [m])
114AC_SEARCH_LIBS([socket], [socket net])
115AC_SEARCH_LIBS([gethostbyname], [nsl bind])
116PKG_CHECK_MODULES(OPENSSL, [openssl >= $OPENSSL_MINIMUM], , [CHECK_SSL()])
117PKG_CHECK_MODULES(LIBCURL, [libcurl >= $CURL_MINIMUM])
118PKG_CHECK_MODULES(LIBEVENT, [libevent >= $LIBEVENT_MINIMUM])
119AC_PATH_ZLIB
120
121AC_SYS_LARGEFILE
122AC_CHECK_FUNCS([lseek64])
123
124
125dnl ----------------------------------------------------------------------------
126dnl
127dnl posix_fadvise
128
129dnl can posix_fadvise be used
130AC_CHECK_DECLS(posix_fadvise, [], [], [
131#define _XOPEN_SOURCE 600
132#include <fcntl.h>])
133AC_CHECK_FUNCS([posix_fadvise])
134
135
136dnl ----------------------------------------------------------------------------
137dnl
138dnl file monitoring for the daemon
139
140AC_CHECK_HEADER([sys/inotify.h],
141                [AC_CHECK_FUNC([inotify_init],[have_inotify="yes"],[have_inotify="no"])],
142                [have_inotify="no"])
143AC_ARG_WITH([inotify],
144            [AS_HELP_STRING([--with-inotify],[Enable inotify support (default=auto)])],
145            [want_inotify=${withval}],
146            [want_inotify=${have_inotify}])
147if test "x$want_inotify" = "xyes" ; then
148    if test "x$have_inotify" = "xyes"; then
149      AC_DEFINE([WITH_INOTIFY],[1])
150    else
151      AC_MSG_ERROR("inotify not found!")
152    fi
153fi
154
155AC_CHECK_HEADER([sys/event.h],
156                [AC_CHECK_FUNC([kqueue],[have_kqueue="yes"],[have_kqueue="no"])],
157                [have_kqueue="no"])
158AC_ARG_WITH([kqueue],
159            [AS_HELP_STRING([--with-kqueue],[Enable kqueue support (default=auto)])],
160            [want_kqueue=${withval}],
161            [want_kqueue=${have_kqueue}])
162if test "x$want_kqueue" = "xyes" ; then
163    if test "x$have_kqueue" = "xyes"; then
164      AC_DEFINE([WITH_KQUEUE],[1])
165    else
166      AC_MSG_ERROR("kqueue not found!")
167    fi
168fi
169
170AC_CHECK_HEADERS([sys/statvfs.h \
171                  xfs/xfs.h])
172
173
174dnl ----------------------------------------------------------------------------
175dnl
176dnl va_copy
177
178AC_MSG_CHECKING([how to copy va_list])
179AC_TRY_LINK([#include <stdarg.h>], [va_list ap1, ap2; va_copy(ap1, ap2);],
180    AC_MSG_RESULT([va_copy]),
181        [ AH_TEMPLATE([va_copy], [define if va_copy is not available])
182        AC_TRY_LINK([#include <stdarg.h>], [va_list ap1, ap2; __va_copy(ap1, ap2);],
183        [ AC_DEFINE([va_copy], [__va_copy])
184        AC_MSG_RESULT([__va_copy])],
185        [ AC_DEFINE([va_copy(dest,src)], [memcpy(&dest,&src,sizeof(va_list))])
186        AC_MSG_RESULT([memcpy])]
187    )
188])
189
190
191dnl ----------------------------------------------------------------------------
192dnl
193dnl  dht
194
195DHT_CFLAGS="-I\$(top_srcdir)/third-party/dht"
196DHT_LIBS="\$(top_builddir)/third-party/dht/libdht.a"
197AC_SUBST(DHT_CFLAGS)
198AC_SUBST(DHT_LIBS)
199
200
201dnl ----------------------------------------------------------------------------
202dnl
203dnl  utp
204
205AC_CHECK_LIB([rt],
206             [clock_gettime],
207             [libutp_extra_libs="-lrt"],
208             [libutp_extra_libs=""])
209
210AC_MSG_CHECKING([µTP])
211build_utp="no"
212if test "x$HAVE_CXX" = "xyes" ; then
213    have_utp="yes"
214else
215    have_utp="no"
216fi
217AC_ARG_ENABLE([utp],
218              AS_HELP_STRING([--enable-utp],[build µTP support]),
219              [want_utp=${enableval}],
220              [want_utp=${have_utp}])
221if test "x$want_utp" = "xyes" ; then
222    if test "x$have_utp" = "xyes"; then
223        LIBUTP_CFLAGS="-I\$(top_srcdir)/third-party/"
224        LIBUTP_LIBS="\$(top_builddir)/third-party/libutp/libutp.a"
225        LIBUTP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/libutp/libutp.a"
226        if test "x$libutp_extra_libs" != "x" ; then
227            LIBUTP_LIBS="$LIBUTP_LIBS $libutp_extra_libs"
228            LIBUTP_LIBS_QT="$LIBUTP_LIBS_QT $libutp_extra_libs"
229        fi
230        AC_DEFINE([WITH_UTP],[1])
231        build_utp="yes"
232    else
233      AC_MSG_ERROR("Unable to build uTP support -- C++ compiler not found")
234    fi
235fi
236AC_SUBST(LIBUTP_CFLAGS)
237AC_SUBST(LIBUTP_LIBS)
238AC_SUBST(LIBUTP_LIBS_QT)
239AM_CONDITIONAL([BUILD_UTP],[test "x$build_utp" = "xyes"])
240AC_MSG_RESULT([$build_utp])
241
242
243dnl
244dnl  look for preinstalled miniupnpc...
245dnl
246
247AC_MSG_CHECKING([supported miniupnp library])
248upnp_version="none"
249ac_save_LIBS="$LIBS"
250LIBS="-lminiupnpc"
251# See if the OS has its miniupnp 1.5 installed
252AC_TRY_LINK([
253    #include <stdlib.h>
254    #include <miniupnpc/miniupnpc.h>
255    #include <miniupnpc/upnpcommands.h>
256],[
257    struct UPNPDev * devlist;
258    struct UPNPUrls    urls;
259    struct IGDdatas    data;
260    char lanaddr[16];
261    char portStr[8];
262    char intPort[8];
263    char intClient[16];
264    upnpDiscover( 2000, NULL, NULL, 0 );
265    UPNP_GetValidIGD( devlist, &urls, &data, lanaddr, sizeof( lanaddr ) );
266    UPNP_GetSpecificPortMappingEntry( urls.controlURL, data.first.servicetype,
267                        portStr, "TCP", intClient, intPort );
268],[
269AC_DEFINE(HAVE_MINIUPNP_15, 1, [Define to 1 if you have miniupnpc version 1.5])
270upnp_version="1.5"])
271
272# See if the OS has its miniupnp 1.6 installed
273AC_TRY_LINK([
274    #include <stdlib.h>
275    #include <errno.h>
276    #include <miniupnpc/miniupnpc.h>
277    #include <miniupnpc/upnpcommands.h>
278],[
279    struct UPNPDev * devlist;
280    struct UPNPUrls    urls;
281    struct IGDdatas    data;
282    char lanaddr[16];
283    char portStr[8];
284    char intPort[8];
285    char intClient[16];
286    upnpDiscover( 2000, NULL, NULL, 0, 0, &errno );
287    UPNP_GetValidIGD( devlist, &urls, &data, lanaddr, sizeof( lanaddr ) );
288    UPNP_GetSpecificPortMappingEntry( urls.controlURL, data.first.servicetype,
289                        portStr, "TCP", intClient, intPort, NULL, NULL, NULL );
290],[
291AC_DEFINE(HAVE_MINIUPNP_16, 1, [Define to 1 if you have miniupnpc version 1.6])
292upnp_version="1.6"])
293
294# ... and the results of our tests
295LIBS="$ac_save_LIBS"
296AC_MSG_RESULT([$upnp_version])
297AM_CONDITIONAL([BUILD_MINIUPNP],[test "x$upnp_version" = "xnone"])
298if test "x$upnp_version" = "xnone" ; then
299    LIBUPNP_CFLAGS="-I\$(top_srcdir)/third-party/"
300    LIBUPNP_LIBS="\$(top_builddir)/third-party/miniupnp/libminiupnp.a"
301    LIBUPNP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/miniupnp/libminiupnp.a"
302    dnl because this is the version that we bundle...
303    AC_DEFINE(HAVE_MINIUPNP_16, 1, [Define to 1 if you have miniupnpc version 1.6])
304else
305    AC_DEFINE([SYSTEM_MINIUPNP])
306    LIBUPNP_CFLAGS=""
307    LIBUPNP_LIBS="-lminiupnpc"
308    LIBUPNP_LIBS_QT="-lminiupnpc"
309fi
310AC_SUBST(LIBUPNP_CFLAGS)
311AC_SUBST(LIBUPNP_LIBS)
312AC_SUBST(LIBUPNP_LIBS_QT)
313
314
315 
316
317dnl ----------------------------------------------------------------------------
318dnl
319dnl  Allow usage of system natpmp library
320
321LIBNATPMP_CFLAGS="-I\$(top_srcdir)/third-party/libnatpmp/"
322LIBNATPMP_LIBS="\$(top_builddir)/third-party/libnatpmp/libnatpmp.a"
323LIBNATPMP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/libnatpmp/libnatpmp.a"
324build_bundled_natpmp="yes"
325AC_ARG_ENABLE([external-natpmp],
326              AS_HELP_STRING([--enable-external-natpmp],[Use system external-natpmp]),
327              [want_external_natpmp=${enableval}],
328              [want_external_natpmp=no])
329if test "x$want_external_natpmp" != "xno" ; then
330        dnl Would be lovely if it had pkgconfig
331        LIBNATPMP_CFLAGS="" 
332        LIBNATPMP_LIBS="-lnatpmp"
333        LIBNATPMP_LIBS_QT="-lnatpmp"
334        build_bundled_natpmp="no"
335fi
336AM_CONDITIONAL([BUILD_NATPMP],[test "x$build_bundled_natpmp" = "xyes"])
337AC_SUBST(LIBNATPMP_CFLAGS)
338AC_SUBST(LIBNATPMP_LIBS)
339AC_SUBST(LIBNATPMP_LIBS_QT)
340
341
342dnl ----------------------------------------------------------------------------
343dnl
344dnl  detection for the GTK+ client
345
346
347gtk_version="none"
348with_gtk_default="no"
349PKG_CHECK_EXISTS([gtk+-2.0 >= $GTK2_MINIMUM],[gtk_version="2" with_gtk_default="yes"])
350PKG_CHECK_EXISTS([gtk+-3.0 >= $GTK3_MINIMUM],[gtk_version="3" with_gtk_default="yes"])
351AC_ARG_WITH([gtk], AC_HELP_STRING([--with-gtk],[with Gtk]),
352            [with_gtk=$withval],
353            [with_gtk=$with_gtk_default])
354if test "x$with_gtk" = "x2" ; then
355    PKG_CHECK_EXISTS([gtk+-2.0 >= $GTK2_MINIMUM],[gtk_version="2" with_gtk="yes"],[gtk_version="none" with_gtk="no"])
356fi
357if test "x$with_gtk" = "x3" ; then
358    PKG_CHECK_EXISTS([gtk+-3.0 >= $GTK3_MINIMUM],[gtk_version="3" with_gtk="yes"],[gtk_version="none" with_gtk="no"])
359fi
360AC_ARG_ENABLE([nls],
361              [AS_HELP_STRING([--enable-nls],[enable native language support])],,
362              [enable_nls=yes])
363AM_CONDITIONAL([BUILD_GTK],[test "x$with_gtk" = "xyes"])
364use_libappindicator=no
365if test "x$with_gtk" = "xyes" ; then
366
367    if test "x$gtk_version" = "xnone" ; then
368        AC_MSG_ERROR("GTK+ not found!")
369    fi
370    if test "x$enable_nls" = "xno" ; then
371        AC_MSG_ERROR("The gtk client cannot be built without nls support.  Try adding either --enable-nls or --without-gtk" )
372    fi
373
374    if test "x$gtk_version" = "x3"; then
375
376        PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= $GTK3_MINIMUM
377                                  glib-2.0 >= $GLIB_MINIMUM
378                                  gio-2.0 >= $GIO_MINIMUM,
379                                  gmodule-2.0 >= $GLIB_MINIMUM
380                                  gthread-2.0 >= $GLIB_MINIMUM])
381        PKG_CHECK_MODULES([LIBAPPINDICATOR],
382                          [appindicator3-0.1 >= $LIBAPPINDICATOR_MINIMUM],
383                          [have_libappindicator=yes],
384                          [have_libappindicator=no])
385        AC_MSG_NOTICE([using GTK+ 3])
386    else
387
388        PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= $GTK2_MINIMUM
389                                  glib-2.0 >= $GLIB_MINIMUM
390                                  gio-2.0 >= $GIO_MINIMUM,
391                                  gmodule-2.0 >= $GLIB_MINIMUM
392                                  gthread-2.0 >= $GLIB_MINIMUM])
393        PKG_CHECK_MODULES([LIBAPPINDICATOR],
394                          [appindicator-0.1 >= $LIBAPPINDICATOR_MINIMUM],
395                          [have_libappindicator=yes],
396                          [have_libappindicator=no])
397        AC_MSG_NOTICE([using GTK+ 2])
398
399    fi
400
401    if test "x$have_libappindicator" = "xyes"; then
402        use_libappindicator=yes
403        AC_DEFINE([HAVE_LIBAPPINDICATOR], 1)
404    else
405        LIBAPPINDICATOR_CFLAGS=
406        LIBAPPINDICATOR_LIBS=
407    fi
408fi
409
410dnl This section is only used for internationalization.
411dnl If you don't need translations and this section gives you trouble --
412dnl such as if you're building for a headless system --
413dnl it's okay to tear this section out and re-build the configure script.
414dnl
415dnl Note to packagers: the bump to intltool 0.40 was made to fix
416dnl a "make check" failure on some systems.  if upgrading to 0.40 is
417dnl a problem and the old version was working fine for you,
418dnl it should be safe to re-edit 0.40 back down to 0.23
419
420use_nls=no
421if test "x$enable_nls" = "xyes" ; then
422    use_nls=yes
423    m4_ifdef([IT_PROG_INTLTOOL],
424             [IT_PROG_INTLTOOL([0.35.0],[no-xml])],
425             [AC_MSG_ERROR("--enable-nls requires intltool to be installed.")])
426    AC_CHECK_HEADERS([libintl.h])
427    GETTEXT_PACKAGE=transmission-gtk
428    AC_SUBST(GETTEXT_PACKAGE)
429    AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
430    AM_GLIB_GNU_GETTEXT
431    transmissionlocaledir='${prefix}/${DATADIRNAME}/locale'
432    AC_SUBST(transmissionlocaledir)
433fi
434AC_SUBST(INTLLIBS)
435
436
437dnl ----------------------------------------------------------------------------
438dnl
439dnl  platform-specific stuff.
440
441AC_CANONICAL_HOST
442have_darwin="no"
443have_msw="no"
444case $host_os in
445
446   *mingw32*)
447     have_msw="yes"
448     CXXFLAGS="$CXXFLAGS -mms-bitfields -mwin32 -mwindows"
449     CPPFLAGS="$CPPFLAGS -DWIN32 -D_WIN32 -DWIN32_LEAN_AND_MEAN"
450     LIBS="$LIBS -liphlpapi -lshell32 -lws2_32"
451     transmissionlocaledir="locale"
452     if test -z "$host_alias"; then
453       hostaliaswindres=
454     else
455       hostaliaswindres="$host_alias-windres";
456     fi
457     AC_CHECK_TOOL(WINDRES, windres)
458     ;;
459
460  *darwin*)
461    have_darwin="yes"
462    CFLAGS="-DMACOSX $CFLAGS"
463    ;;
464
465esac
466
467AC_ARG_ENABLE([lightweight],
468              AS_HELP_STRING([--enable-lightweight],[optimize libtransmission for low-resource systems: smaller cache size, prefer unencrypted peer connections, etc.]),
469              [enable_lightweight=${enableval}],
470              [enable_lightweight="no"])
471if test "x$enable_lightweight" = "xyes" ; then
472  AC_DEFINE([TR_LIGHTWEIGHT],[1],[optimize libtransmission for low-resource systems])
473fi
474
475AC_ARG_ENABLE([cli],
476              [AS_HELP_STRING([--enable-cli],[build command-line client])],
477              [build_cli=${enableval}],
478              [build_cli="yes"])
479AM_CONDITIONAL([BUILD_CLI],[test "x$build_cli" = "xyes"])
480
481AC_ARG_ENABLE([mac],
482              [AS_HELP_STRING([--enable-mac],[build Mac client])],
483              [build_mac=${enableval}],
484              [build_mac=${have_darwin}])
485AM_CONDITIONAL([BUILD_MAC],[test "x$build_mac" = "xyes"])
486
487AC_ARG_ENABLE([daemon],
488              [AS_HELP_STRING([--enable-daemon],[build daemon])],
489              [build_daemon=${enableval}],
490              [build_daemon="yes"])
491AM_CONDITIONAL([BUILD_DAEMON],[test "x$build_daemon" = "xyes"])
492
493
494if test "x$build_mac" = "xyes" ; then
495    # Make sure the proper Mac SDK is installed
496    if test ! -d /Developer/SDKs/MacOSX10.5.sdk; then
497      cat << EOF
498You need to install the Mac OS X 10.5 SDK in order to build Transmission
499with --enable-mac:
500  Get your Xcode CD or package
501  Restart the install
502  When it gets to "Installation Type", select "Customize"
503  Select "Mac OS X 10.5 SDK" under "Cross Development"
504  Finish the install.
505EOF
506      exit 1
507    fi
508fi
509if test "x$have_darwin" = "xyes"; then
510    AC_DEFINE([HAVE_DARWIN], 1)
511fi
512if test "x$have_msw" = "xyes"; then
513    AC_DEFINE([HAVE_MSW], 1)
514fi
515AM_CONDITIONAL(WIN32, test "x$have_msw" = "xyes")
516
517dnl ----------------------------------------------------------------------------
518dnl
519dnl  Generate the output
520
521AC_CONFIG_FILES([Makefile
522                 transmission-gtk.spec
523                 cli/Makefile
524                 daemon/Makefile
525                 extras/Makefile
526                 libtransmission/Makefile
527                 utils/Makefile
528                 third-party/Makefile
529                 third-party/dht/Makefile
530                 third-party/libutp/Makefile
531                 third-party/libnatpmp/Makefile
532                 third-party/miniupnp/Makefile
533                 macosx/Makefile
534                 gtk/Makefile
535                 gtk/icons/Makefile
536                 qt/config.pri
537                 web/Makefile
538                 web/images/Makefile
539                 web/style/Makefile
540                 web/style/jqueryui/Makefile
541                 web/style/jqueryui/images/Makefile
542                 web/style/transmission/Makefile
543                 web/style/transmission/images/Makefile
544                 web/style/transmission/images/buttons/Makefile
545                 web/javascript/Makefile
546                 web/javascript/jquery/Makefile
547                 po/Makefile.in])
548
549AC_OUTPUT
550
551echo "
552
553Configuration:
554
555   Source code location:                              ${srcdir}
556   Compiler:                                          ${CXX}
557
558   Build libtransmission:                             yes
559      * optimized for low-resource systems:           ${enable_lightweight}
560      * µTP enabled:                                  ${build_utp}
561
562   Build Command-Line client:                         ${build_cli}
563
564   Build GTK+ client:                                 ${with_gtk} (GTK+ $gtk_version)
565      * libappindicator for an Ubuntu-style tray:     ${use_libappindicator}
566
567   Build Daemon:                                      ${build_daemon}
568
569   Build Mac client:                                  ${build_mac}
570
571"
Note: See TracBrowser for help on using the repository browser.