source: trunk/configure.ac @ 13268

Last change on this file since 13268 was 13268, checked in by jordan, 10 years ago

(trunk) fix bug #4826 where overriding the C++ compliler via the CXX environment variable didn't work

File size: 18.1 KB
Line 
1dnl convention: -TR MAJOR MINOR MAINT STATUS - (each a single char)
2dnl STATUS: "X" for prerelease beta builds,
3dnl         "Z" for unsupported trunk builds,
4dnl         "0" for stable, supported releases
5dnl these should be the only two lines you need to change
6m4_define([user_agent_prefix],[2.50+])
7m4_define([peer_id_prefix],[-TR250Z-])
8
9AC_INIT([transmission],
10        [user_agent_prefix],
11        [http://trac.transmissionbt.com/newticket])
12AC_SUBST(USERAGENT_PREFIX,[user_agent_prefix])
13AC_SUBST(PEERID_PREFIX,[peer_id_prefix])
14
15m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
16
17AC_CONFIG_MACRO_DIR([m4])
18
19dnl AM_CONFIG_HEADER(config.h)
20AC_CONFIG_SRCDIR(libtransmission/transmission.h)
21AM_INIT_AUTOMAKE([1.9 tar-pax])
22AC_PROG_LIBTOOL
23
24if test m4_substr(peer_id_prefix,6,1) = "0"; then
25  supported_build=yes
26  CPPFLAGS="$CPPFLAGS -DNDEBUG"
27else
28  supported_build=no
29  if test "x$GCC" = "xyes" ; then
30    CFLAGS="$CFLAGS -g -O0"
31    CXXFLAGS="$CXXFLAGS -g -O0"
32  fi
33fi
34AM_CONDITIONAL(TR_UNSTABLE, test "x$supported_build" = "xno")
35
36##
37##
38##   MANDATORY for everything
39##
40##
41CURL_MINIMUM=7.15.4
42AC_SUBST(CURL_MINIMUM)
43LIBEVENT_MINIMUM=2.0.10
44AC_SUBST(LIBEVENT_MINIUM)
45OPENSSL_MINIMUM=0.9.4
46AC_SUBST(OPENSSL_MINIMUM)
47
48##
49##
50##   MANDATORY for the GTK+ client
51##
52##
53
54GTK2_MINIMUM=2.22.0
55AC_SUBST(GTK2_MINIMUM)
56GTK3_MINIMUM=3.2.0
57AC_SUBST(GTK3_MINIMUM)
58GLIB_MINIMUM=2.28.0
59AC_SUBST(GLIB_MINIMUM)
60GIO_MINIMUM=2.26.0
61AC_SUBST(GIO_MINIMUM)
62
63##
64##
65##   OPTIONAL for the GTK+ client
66##
67##
68
69# create the tray icon with AppIndicator
70LIBAPPINDICATOR_MINIMUM=0.0.11
71AC_SUBST(LIBAPPINDICATOR_MINIMUM)
72
73
74AC_PROG_CC
75AC_PROG_CXX
76AC_MSG_CHECKING([for $CXX])
77if test -f "$CXX"; then
78    HAVE_CXX="yes"
79else
80    HAVE_CXX="no"
81fi
82AC_MSG_RESULT([$HAVE_CXX])
83AC_C_INLINE
84if test "x$GCC" = "xyes" ; then
85
86    CFLAGS="$CFLAGS -std=gnu99 -ggdb3 -Wall -W -Wpointer-arith -Wformat-security -Wcast-align -Wundef -Wcast-align -Wstrict-prototypes -Wmissing-declarations -Wmissing-format-attribute -Wredundant-decls -Wnested-externs -Wunused-parameter -Wwrite-strings -Winline -Wfloat-equal"
87
88    dnl figure out gcc version
89    AC_MSG_CHECKING([gcc version])
90    GCC_VERSION=`$CC -dumpversion`
91    GCC_MAJOR=`echo $GCC_VERSION | cut -d . -f1`
92    GCC_MINOR=`echo $GCC_VERSION | cut -d . -f2`
93    GCC_VERSION_NUM=`(expr $GCC_MAJOR "*" 100 + $GCC_MINOR) 2>/dev/null`
94
95    AC_MSG_RESULT($GCC_VERSION)
96    if test $GCC_VERSION_NUM -ge 304; then
97        dnl these were added in 3.4
98        CFLAGS="$CFLAGS -Wextra -Wdeclaration-after-statement -Winit-self"
99    fi
100    if test $GCC_VERSION_NUM -ge 403; then
101        dnl these were added in 4.3
102        CFLAGS="$CFLAGS -Wvariadic-macros"
103    fi
104fi
105
106AC_HEADER_STDC
107AC_HEADER_TIME
108
109AC_CHECK_HEADERS([stdbool.h])
110AC_CHECK_FUNCS([iconv_open pread pwrite lrintf strlcpy daemon dirname basename strcasecmp localtime_r fallocate64 posix_fallocate memmem strsep strtold syslog valloc getpagesize posix_memalign statvfs htonll ntohll mkdtemp])
111AC_PROG_INSTALL
112AC_PROG_MAKE_SET
113ACX_PTHREAD
114
115if test "x$ac_cv_func_strtold" != "xyes" ; then
116    CPPFLAGS="$CPPFLAGS -Dstrtold=strtod"
117fi
118
119AC_SEARCH_LIBS(cos, [m])
120AC_SEARCH_LIBS([socket], [socket net])
121AC_SEARCH_LIBS([gethostbyname], [nsl bind])
122PKG_CHECK_MODULES(OPENSSL, [openssl >= $OPENSSL_MINIMUM], , [CHECK_SSL()])
123PKG_CHECK_MODULES(LIBCURL, [libcurl >= $CURL_MINIMUM])
124PKG_CHECK_MODULES(LIBEVENT, [libevent >= $LIBEVENT_MINIMUM])
125AC_PATH_ZLIB
126
127AC_SYS_LARGEFILE
128AC_CHECK_FUNCS([lseek64])
129
130
131dnl ----------------------------------------------------------------------------
132dnl
133dnl posix_fadvise
134
135dnl can posix_fadvise be used
136AC_CHECK_DECLS(posix_fadvise, [], [], [
137#define _XOPEN_SOURCE 600
138#include <fcntl.h>])
139AC_CHECK_FUNCS([posix_fadvise])
140
141
142dnl ----------------------------------------------------------------------------
143dnl
144dnl file monitoring for the daemon
145
146AC_CHECK_HEADER([sys/inotify.h],
147                [AC_CHECK_FUNC([inotify_init],[have_inotify="yes"],[have_inotify="no"])],
148                [have_inotify="no"])
149AC_ARG_WITH([inotify],
150            [AS_HELP_STRING([--with-inotify],[Enable inotify support (default=auto)])],
151            [want_inotify=${withval}],
152            [want_inotify=${have_inotify}])
153if test "x$want_inotify" = "xyes" ; then
154    if test "x$have_inotify" = "xyes"; then
155      AC_DEFINE([WITH_INOTIFY],[1])
156    else
157      AC_MSG_ERROR("inotify not found!")
158    fi
159fi
160
161AC_CHECK_HEADER([sys/event.h],
162                [AC_CHECK_FUNC([kqueue],[have_kqueue="yes"],[have_kqueue="no"])],
163                [have_kqueue="no"])
164AC_ARG_WITH([kqueue],
165            [AS_HELP_STRING([--with-kqueue],[Enable kqueue support (default=auto)])],
166            [want_kqueue=${withval}],
167            [want_kqueue=${have_kqueue}])
168if test "x$want_kqueue" = "xyes" ; then
169    if test "x$have_kqueue" = "xyes"; then
170      AC_DEFINE([WITH_KQUEUE],[1])
171    else
172      AC_MSG_ERROR("kqueue not found!")
173    fi
174fi
175
176AC_CHECK_HEADERS([sys/statvfs.h \
177                  xfs/xfs.h])
178
179
180dnl ----------------------------------------------------------------------------
181dnl
182dnl va_copy
183
184AC_MSG_CHECKING([how to copy va_list])
185AC_TRY_LINK([#include <stdarg.h>], [va_list ap1, ap2; va_copy(ap1, ap2);],
186    AC_MSG_RESULT([va_copy]),
187        [ AH_TEMPLATE([va_copy], [define if va_copy is not available])
188        AC_TRY_LINK([#include <stdarg.h>], [va_list ap1, ap2; __va_copy(ap1, ap2);],
189        [ AC_DEFINE([va_copy], [__va_copy])
190        AC_MSG_RESULT([__va_copy])],
191        [ AC_DEFINE([va_copy(dest,src)], [memcpy(&dest,&src,sizeof(va_list))])
192        AC_MSG_RESULT([memcpy])]
193    )
194])
195
196
197dnl ----------------------------------------------------------------------------
198dnl
199dnl  dht
200
201DHT_CFLAGS="-I\$(top_srcdir)/third-party/dht"
202DHT_LIBS="\$(top_builddir)/third-party/dht/libdht.a"
203AC_SUBST(DHT_CFLAGS)
204AC_SUBST(DHT_LIBS)
205
206
207dnl ----------------------------------------------------------------------------
208dnl
209dnl  utp
210
211AC_CHECK_LIB([rt],
212             [clock_gettime],
213             [libutp_extra_libs="-lrt"],
214             [libutp_extra_libs=""])
215
216AC_MSG_CHECKING([µTP])
217build_utp="no"
218if test "x$HAVE_CXX" = "xyes" ; then
219    have_utp="yes"
220else
221    have_utp="no"
222fi
223AC_ARG_ENABLE([utp],
224              AS_HELP_STRING([--enable-utp],[build µTP support]),
225              [want_utp=${enableval}],
226              [want_utp=${have_utp}])
227if test "x$want_utp" = "xyes" ; then
228    if test "x$have_utp" = "xyes"; then
229        LIBUTP_CFLAGS="-I\$(top_srcdir)/third-party/"
230        LIBUTP_LIBS="\$(top_builddir)/third-party/libutp/libutp.a"
231        LIBUTP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/libutp/libutp.a"
232        if test "x$libutp_extra_libs" != "x" ; then
233            LIBUTP_LIBS="$LIBUTP_LIBS $libutp_extra_libs"
234            LIBUTP_LIBS_QT="$LIBUTP_LIBS_QT $libutp_extra_libs"
235        fi
236        AC_DEFINE([WITH_UTP],[1])
237        build_utp="yes"
238    else
239      AC_MSG_ERROR("Unable to build uTP support -- C++ compiler not found")
240    fi
241fi
242AC_SUBST(LIBUTP_CFLAGS)
243AC_SUBST(LIBUTP_LIBS)
244AC_SUBST(LIBUTP_LIBS_QT)
245AM_CONDITIONAL([BUILD_UTP],[test "x$build_utp" = "xyes"])
246AC_MSG_RESULT([$build_utp])
247
248
249dnl
250dnl  look for preinstalled miniupnpc...
251dnl
252
253AC_MSG_CHECKING([supported miniupnp library])
254upnp_version="none"
255ac_save_LIBS="$LIBS"
256LIBS="-lminiupnpc"
257# See if the OS has its miniupnp 1.5 installed
258AC_TRY_LINK([
259    #include <stdlib.h>
260    #include <miniupnpc/miniupnpc.h>
261    #include <miniupnpc/upnpcommands.h>
262],[
263    struct UPNPDev * devlist;
264    struct UPNPUrls    urls;
265    struct IGDdatas    data;
266    char lanaddr[16];
267    char portStr[8];
268    char intPort[8];
269    char intClient[16];
270    upnpDiscover( 2000, NULL, NULL, 0 );
271    UPNP_GetValidIGD( devlist, &urls, &data, lanaddr, sizeof( lanaddr ) );
272    UPNP_GetSpecificPortMappingEntry( urls.controlURL, data.first.servicetype,
273                        portStr, "TCP", intClient, intPort );
274],[
275AC_DEFINE(HAVE_MINIUPNP_15, 1, [Define to 1 if you have miniupnpc version 1.5])
276upnp_version="1.5"])
277
278# See if the OS has its miniupnp 1.6 installed
279AC_TRY_LINK([
280    #include <stdlib.h>
281    #include <errno.h>
282    #include <miniupnpc/miniupnpc.h>
283    #include <miniupnpc/upnpcommands.h>
284],[
285    struct UPNPDev * devlist;
286    struct UPNPUrls    urls;
287    struct IGDdatas    data;
288    char lanaddr[16];
289    char portStr[8];
290    char intPort[8];
291    char intClient[16];
292    upnpDiscover( 2000, NULL, NULL, 0, 0, &errno );
293    UPNP_GetValidIGD( devlist, &urls, &data, lanaddr, sizeof( lanaddr ) );
294    UPNP_GetSpecificPortMappingEntry( urls.controlURL, data.first.servicetype,
295                        portStr, "TCP", intClient, intPort, NULL, NULL, NULL );
296],[
297AC_DEFINE(HAVE_MINIUPNP_16, 1, [Define to 1 if you have miniupnpc version 1.6])
298upnp_version="1.6"])
299
300# ... and the results of our tests
301LIBS="$ac_save_LIBS"
302AC_MSG_RESULT([$upnp_version])
303AM_CONDITIONAL([BUILD_MINIUPNP],[test "x$upnp_version" = "xnone"])
304if test "x$upnp_version" = "xnone" ; then
305    LIBUPNP_CFLAGS="-I\$(top_srcdir)/third-party/"
306    LIBUPNP_LIBS="\$(top_builddir)/third-party/miniupnp/libminiupnp.a"
307    LIBUPNP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/miniupnp/libminiupnp.a"
308    dnl because this is the version that we bundle...
309    AC_DEFINE(HAVE_MINIUPNP_16, 1, [Define to 1 if you have miniupnpc version 1.6])
310else
311    AC_DEFINE([SYSTEM_MINIUPNP])
312    LIBUPNP_CFLAGS=""
313    LIBUPNP_LIBS="-lminiupnpc"
314    LIBUPNP_LIBS_QT="-lminiupnpc"
315fi
316AC_SUBST(LIBUPNP_CFLAGS)
317AC_SUBST(LIBUPNP_LIBS)
318AC_SUBST(LIBUPNP_LIBS_QT)
319
320
321 
322
323dnl ----------------------------------------------------------------------------
324dnl
325dnl  Allow usage of system natpmp library
326
327LIBNATPMP_CFLAGS="-I\$(top_srcdir)/third-party/libnatpmp/"
328LIBNATPMP_LIBS="\$(top_builddir)/third-party/libnatpmp/libnatpmp.a"
329LIBNATPMP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/libnatpmp/libnatpmp.a"
330build_bundled_natpmp="yes"
331AC_ARG_ENABLE([external-natpmp],
332              AS_HELP_STRING([--enable-external-natpmp],[Use system external-natpmp]),
333              [want_external_natpmp=${enableval}],
334              [want_external_natpmp=no])
335if test "x$want_external_natpmp" != "xno" ; then
336        dnl Would be lovely if it had pkgconfig
337        LIBNATPMP_CFLAGS="" 
338        LIBNATPMP_LIBS="-lnatpmp"
339        LIBNATPMP_LIBS_QT="-lnatpmp"
340        build_bundled_natpmp="no"
341fi
342AM_CONDITIONAL([BUILD_NATPMP],[test "x$build_bundled_natpmp" = "xyes"])
343AC_SUBST(LIBNATPMP_CFLAGS)
344AC_SUBST(LIBNATPMP_LIBS)
345AC_SUBST(LIBNATPMP_LIBS_QT)
346
347
348dnl ----------------------------------------------------------------------------
349dnl
350dnl  detection for the GTK+ client
351
352
353gtk_version="none"
354with_gtk_default="no"
355PKG_CHECK_EXISTS([gtk+-2.0 >= $GTK2_MINIMUM],[gtk_version="2" with_gtk_default="yes"])
356PKG_CHECK_EXISTS([gtk+-3.0 >= $GTK3_MINIMUM],[gtk_version="3" with_gtk_default="yes"])
357AC_ARG_WITH([gtk], AC_HELP_STRING([--with-gtk],[with Gtk]),
358            [with_gtk=$withval],
359            [with_gtk=$with_gtk_default])
360if test "x$with_gtk" = "x2" ; then
361    PKG_CHECK_EXISTS([gtk+-2.0 >= $GTK2_MINIMUM],[gtk_version="2" with_gtk="yes"],[gtk_version="none" with_gtk="no"])
362fi
363if test "x$with_gtk" = "x3" ; then
364    PKG_CHECK_EXISTS([gtk+-3.0 >= $GTK3_MINIMUM],[gtk_version="3" with_gtk="yes"],[gtk_version="none" with_gtk="no"])
365fi
366AC_ARG_ENABLE([nls],
367              [AS_HELP_STRING([--enable-nls],[enable native language support])],,
368              [enable_nls=yes])
369AM_CONDITIONAL([BUILD_GTK],[test "x$with_gtk" = "xyes"])
370use_libappindicator=no
371if test "x$with_gtk" = "xyes" ; then
372
373    if test "x$gtk_version" = "xnone" ; then
374        AC_MSG_ERROR("GTK+ not found!")
375    fi
376    if test "x$enable_nls" = "xno" ; then
377        AC_MSG_ERROR("The gtk client cannot be built without nls support.  Try adding either --enable-nls or --without-gtk" )
378    fi
379
380    if test "x$gtk_version" = "x3"; then
381
382        PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= $GTK3_MINIMUM
383                                  glib-2.0 >= $GLIB_MINIMUM
384                                  gio-2.0 >= $GIO_MINIMUM,
385                                  gmodule-2.0 >= $GLIB_MINIMUM
386                                  gthread-2.0 >= $GLIB_MINIMUM])
387        PKG_CHECK_MODULES([LIBAPPINDICATOR],
388                          [appindicator3-0.1 >= $LIBAPPINDICATOR_MINIMUM],
389                          [have_libappindicator=yes],
390                          [have_libappindicator=no])
391        AC_MSG_NOTICE([using GTK+ 3])
392    else
393
394        PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= $GTK2_MINIMUM
395                                  glib-2.0 >= $GLIB_MINIMUM
396                                  gio-2.0 >= $GIO_MINIMUM,
397                                  gmodule-2.0 >= $GLIB_MINIMUM
398                                  gthread-2.0 >= $GLIB_MINIMUM])
399        PKG_CHECK_MODULES([LIBAPPINDICATOR],
400                          [appindicator-0.1 >= $LIBAPPINDICATOR_MINIMUM],
401                          [have_libappindicator=yes],
402                          [have_libappindicator=no])
403        AC_MSG_NOTICE([using GTK+ 2])
404
405    fi
406
407    if test "x$have_libappindicator" = "xyes"; then
408        use_libappindicator=yes
409        AC_DEFINE([HAVE_LIBAPPINDICATOR], 1)
410    else
411        LIBAPPINDICATOR_CFLAGS=
412        LIBAPPINDICATOR_LIBS=
413    fi
414fi
415
416dnl This section is only used for internationalization.
417dnl If you don't need translations and this section gives you trouble --
418dnl such as if you're building for a headless system --
419dnl it's okay to tear this section out and re-build the configure script.
420dnl
421dnl Note to packagers: the bump to intltool 0.40 was made to fix
422dnl a "make check" failure on some systems.  if upgrading to 0.40 is
423dnl a problem and the old version was working fine for you,
424dnl it should be safe to re-edit 0.40 back down to 0.23
425
426use_nls=no
427if test "x$enable_nls" = "xyes" ; then
428    use_nls=yes
429    m4_ifdef([IT_PROG_INTLTOOL],
430             [IT_PROG_INTLTOOL([0.35.0],[no-xml])],
431             [AC_MSG_ERROR("--enable-nls requires intltool to be installed.")])
432    AC_CHECK_HEADERS([libintl.h])
433    GETTEXT_PACKAGE=transmission-gtk
434    AC_SUBST(GETTEXT_PACKAGE)
435    AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
436    AM_GLIB_GNU_GETTEXT
437    transmissionlocaledir='${prefix}/${DATADIRNAME}/locale'
438    AC_SUBST(transmissionlocaledir)
439fi
440AC_SUBST(INTLLIBS)
441
442
443dnl ----------------------------------------------------------------------------
444dnl
445dnl  platform-specific stuff.
446
447AC_CANONICAL_HOST
448have_darwin="no"
449have_msw="no"
450case $host_os in
451
452   *mingw32*)
453     have_msw="yes"
454     CXXFLAGS="$CXXFLAGS -mms-bitfields -mwin32 -mwindows"
455     CPPFLAGS="$CPPFLAGS -DWIN32 -D_WIN32 -DWIN32_LEAN_AND_MEAN"
456     LIBS="$LIBS -liphlpapi -lshell32 -lws2_32"
457     transmissionlocaledir="locale"
458     if test -z "$host_alias"; then
459       hostaliaswindres=
460     else
461       hostaliaswindres="$host_alias-windres";
462     fi
463     AC_CHECK_TOOL(WINDRES, windres)
464     ;;
465
466  *darwin*)
467    have_darwin="yes"
468    CFLAGS="-DMACOSX $CFLAGS"
469    ;;
470
471esac
472
473AC_ARG_ENABLE([lightweight],
474              AS_HELP_STRING([--enable-lightweight],[optimize libtransmission for low-resource systems: smaller cache size, prefer unencrypted peer connections, etc.]),
475              [enable_lightweight=${enableval}],
476              [enable_lightweight="no"])
477if test "x$enable_lightweight" = "xyes" ; then
478  AC_DEFINE([TR_LIGHTWEIGHT],[1],[optimize libtransmission for low-resource systems])
479fi
480
481AC_ARG_ENABLE([cli],
482              [AS_HELP_STRING([--enable-cli],[build command-line client])],
483              [build_cli=${enableval}],
484              [build_cli="yes"])
485AM_CONDITIONAL([BUILD_CLI],[test "x$build_cli" = "xyes"])
486
487AC_ARG_ENABLE([mac],
488              [AS_HELP_STRING([--enable-mac],[build Mac client])],
489              [build_mac=${enableval}],
490              [build_mac=${have_darwin}])
491AM_CONDITIONAL([BUILD_MAC],[test "x$build_mac" = "xyes"])
492
493AC_ARG_ENABLE([daemon],
494              [AS_HELP_STRING([--enable-daemon],[build daemon])],
495              [build_daemon=${enableval}],
496              [build_daemon="yes"])
497AM_CONDITIONAL([BUILD_DAEMON],[test "x$build_daemon" = "xyes"])
498
499
500if test "x$build_mac" = "xyes" ; then
501    # Make sure the proper Mac SDK is installed
502    if test ! -d /Developer/SDKs/MacOSX10.5.sdk; then
503      cat << EOF
504You need to install the Mac OS X 10.5 SDK in order to build Transmission
505with --enable-mac:
506  Get your Xcode CD or package
507  Restart the install
508  When it gets to "Installation Type", select "Customize"
509  Select "Mac OS X 10.5 SDK" under "Cross Development"
510  Finish the install.
511EOF
512      exit 1
513    fi
514fi
515if test "x$have_darwin" = "xyes"; then
516    AC_DEFINE([HAVE_DARWIN], 1)
517fi
518if test "x$have_msw" = "xyes"; then
519    AC_DEFINE([HAVE_MSW], 1)
520fi
521AM_CONDITIONAL(WIN32, test "x$have_msw" = "xyes")
522
523dnl ----------------------------------------------------------------------------
524dnl
525dnl  Generate the output
526
527AC_CONFIG_FILES([Makefile
528                 transmission-gtk.spec
529                 cli/Makefile
530                 daemon/Makefile
531                 extras/Makefile
532                 libtransmission/Makefile
533                 utils/Makefile
534                 third-party/Makefile
535                 third-party/dht/Makefile
536                 third-party/libutp/Makefile
537                 third-party/libnatpmp/Makefile
538                 third-party/miniupnp/Makefile
539                 macosx/Makefile
540                 gtk/Makefile
541                 gtk/icons/Makefile
542                 qt/config.pri
543                 web/Makefile
544                 web/images/Makefile
545                 web/style/Makefile
546                 web/style/jqueryui/Makefile
547                 web/style/jqueryui/images/Makefile
548                 web/style/transmission/Makefile
549                 web/style/transmission/images/Makefile
550                 web/style/transmission/images/buttons/Makefile
551                 web/javascript/Makefile
552                 web/javascript/jquery/Makefile
553                 po/Makefile.in])
554
555AC_OUTPUT
556
557echo "
558
559Configuration:
560
561   Source code location:                              ${srcdir}
562   Compiler:                                          ${CXX}
563
564   Build libtransmission:                             yes
565      * optimized for low-resource systems:           ${enable_lightweight}
566      * µTP enabled:                                  ${build_utp}
567
568   Build Command-Line client:                         ${build_cli}
569
570   Build GTK+ client:                                 ${with_gtk} (GTK+ $gtk_version)
571      * libappindicator for an Ubuntu-style tray:     ${use_libappindicator}
572
573   Build Daemon:                                      ${build_daemon}
574
575   Build Mac client:                                  ${build_mac}
576
577"
Note: See TracBrowser for help on using the repository browser.