source: trunk/configure.ac @ 13376

Last change on this file since 13376 was 13376, checked in by livings124, 11 years ago

2.60+
File size: 18.2 KB
Line 
1dnl convention: -TR MAJOR MINOR MAINT STATUS - (each a single char)
2dnl STATUS: "X" for prerelease beta builds,
3dnl         "Z" for unsupported trunk builds,
4dnl         "0" for stable, supported releases
5dnl these should be the only two lines you need to change
6m4_define([user_agent_prefix],[2.60+])
7m4_define([peer_id_prefix],[-TR260Z-])
8
9AC_INIT([transmission],
10        [user_agent_prefix],
11        [http://trac.transmissionbt.com/newticket])
12AC_SUBST(USERAGENT_PREFIX,[user_agent_prefix])
13AC_SUBST(PEERID_PREFIX,[peer_id_prefix])
14
15m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
16
17AC_CONFIG_MACRO_DIR([m4])
18
19dnl AM_CONFIG_HEADER(config.h)
20AC_CONFIG_SRCDIR(libtransmission/transmission.h)
21AM_INIT_AUTOMAKE([1.9 tar-pax])
22AC_PROG_LIBTOOL
23
24if test m4_substr(peer_id_prefix,6,1) = "0"; then
25  supported_build=yes
26  CPPFLAGS="$CPPFLAGS -DNDEBUG"
27else
28  supported_build=no
29  if test "x$GCC" = "xyes" ; then
30    CFLAGS="$CFLAGS -g -O0"
31    CXXFLAGS="$CXXFLAGS -g -O0"
32  fi
33fi
34AM_CONDITIONAL(TR_UNSTABLE, test "x$supported_build" = "xno")
35
36##
37##
38##   MANDATORY for everything
39##
40##
41CURL_MINIMUM=7.15.4
42AC_SUBST(CURL_MINIMUM)
43LIBEVENT_MINIMUM=2.0.10
44AC_SUBST(LIBEVENT_MINIUM)
45OPENSSL_MINIMUM=0.9.4
46AC_SUBST(OPENSSL_MINIMUM)
47
48##
49##
50##   MANDATORY for the GTK+ client
51##
52##
53
54GTK2_MINIMUM=2.22.0
55AC_SUBST(GTK2_MINIMUM)
56GTK3_MINIMUM=3.2.0
57AC_SUBST(GTK3_MINIMUM)
58GLIB_MINIMUM=2.28.0
59AC_SUBST(GLIB_MINIMUM)
60GIO_MINIMUM=2.26.0
61AC_SUBST(GIO_MINIMUM)
62
63##
64##
65##   OPTIONAL for the GTK+ client
66##
67##
68
69# create the tray icon with AppIndicator
70LIBAPPINDICATOR_MINIMUM=0.4.90
71AC_SUBST(LIBAPPINDICATOR_MINIMUM)
72
73
74AC_PROG_CC
75AC_PROG_CXX
76if test "x$CXX" != "x"; then # CXX is set...
77  if test -f "$CXX"; then # maybe it's an absolute path passed in env variables...
78    AC_MSG_CHECKING([for $CXX])
79    HAVE_CXX="yes"
80    AC_MSG_RESULT([$HAVE_CXX])
81  else
82    AC_CHECK_PROG([HAVE_CXX],[$CXX],[yes],[no])
83  fi
84fi
85AC_C_INLINE
86if test "x$GCC" = "xyes" ; then
87
88    CFLAGS="$CFLAGS -std=gnu99 -ggdb3 -Wall -W -Wpointer-arith -Wformat-security -Wcast-align -Wundef -Wcast-align -Wstrict-prototypes -Wmissing-declarations -Wmissing-format-attribute -Wredundant-decls -Wnested-externs -Wunused-parameter -Wwrite-strings -Winline -Wfloat-equal"
89
90    dnl figure out gcc version
91    AC_MSG_CHECKING([gcc version])
92    GCC_VERSION=`$CC -dumpversion`
93    GCC_MAJOR=`echo $GCC_VERSION | cut -d . -f1`
94    GCC_MINOR=`echo $GCC_VERSION | cut -d . -f2`
95    GCC_VERSION_NUM=`(expr $GCC_MAJOR "*" 100 + $GCC_MINOR) 2>/dev/null`
96
97    AC_MSG_RESULT($GCC_VERSION)
98    if test $GCC_VERSION_NUM -ge 304; then
99        dnl these were added in 3.4
100        CFLAGS="$CFLAGS -Wextra -Wdeclaration-after-statement -Winit-self"
101    fi
102    if test $GCC_VERSION_NUM -ge 403; then
103        dnl these were added in 4.3
104        CFLAGS="$CFLAGS -Wvariadic-macros"
105    fi
106fi
107
108AC_HEADER_STDC
109AC_HEADER_TIME
110
111AC_CHECK_HEADERS([stdbool.h])
112AC_CHECK_FUNCS([iconv_open pread pwrite lrintf strlcpy daemon dirname basename strcasecmp localtime_r fallocate64 posix_fallocate memmem strsep strtold syslog valloc getpagesize posix_memalign statvfs htonll ntohll mkdtemp])
113AC_PROG_INSTALL
114AC_PROG_MAKE_SET
115ACX_PTHREAD
116
117if test "x$ac_cv_func_strtold" != "xyes" ; then
118    CPPFLAGS="$CPPFLAGS -Dstrtold=strtod"
119fi
120
121AC_SEARCH_LIBS(cos, [m])
122AC_SEARCH_LIBS([socket], [socket net])
123AC_SEARCH_LIBS([gethostbyname], [nsl bind])
124PKG_CHECK_MODULES(OPENSSL, [openssl >= $OPENSSL_MINIMUM], , [CHECK_SSL()])
125PKG_CHECK_MODULES(LIBCURL, [libcurl >= $CURL_MINIMUM])
126PKG_CHECK_MODULES(LIBEVENT, [libevent >= $LIBEVENT_MINIMUM])
127AC_PATH_ZLIB
128
129AC_SYS_LARGEFILE
130AC_CHECK_FUNCS([lseek64])
131
132
133dnl ----------------------------------------------------------------------------
134dnl
135dnl posix_fadvise
136
137dnl can posix_fadvise be used
138AC_CHECK_DECLS(posix_fadvise, [], [], [
139#define _XOPEN_SOURCE 600
140#include <fcntl.h>])
141AC_CHECK_FUNCS([posix_fadvise])
142
143
144dnl ----------------------------------------------------------------------------
145dnl
146dnl file monitoring for the daemon
147
148AC_CHECK_HEADER([sys/inotify.h],
149                [AC_CHECK_FUNC([inotify_init],[have_inotify="yes"],[have_inotify="no"])],
150                [have_inotify="no"])
151AC_ARG_WITH([inotify],
152            [AS_HELP_STRING([--with-inotify],[Enable inotify support (default=auto)])],
153            [want_inotify=${withval}],
154            [want_inotify=${have_inotify}])
155if test "x$want_inotify" = "xyes" ; then
156    if test "x$have_inotify" = "xyes"; then
157      AC_DEFINE([WITH_INOTIFY],[1])
158    else
159      AC_MSG_ERROR("inotify not found!")
160    fi
161fi
162
163AC_CHECK_HEADER([sys/event.h],
164                [AC_CHECK_FUNC([kqueue],[have_kqueue="yes"],[have_kqueue="no"])],
165                [have_kqueue="no"])
166AC_ARG_WITH([kqueue],
167            [AS_HELP_STRING([--with-kqueue],[Enable kqueue support (default=auto)])],
168            [want_kqueue=${withval}],
169            [want_kqueue=${have_kqueue}])
170if test "x$want_kqueue" = "xyes" ; then
171    if test "x$have_kqueue" = "xyes"; then
172      AC_DEFINE([WITH_KQUEUE],[1])
173    else
174      AC_MSG_ERROR("kqueue not found!")
175    fi
176fi
177
178AC_CHECK_HEADERS([sys/statvfs.h \
179                  xfs/xfs.h])
180
181
182dnl ----------------------------------------------------------------------------
183dnl
184dnl va_copy
185
186AC_MSG_CHECKING([how to copy va_list])
187AC_TRY_LINK([#include <stdarg.h>], [va_list ap1, ap2; va_copy(ap1, ap2);],
188    AC_MSG_RESULT([va_copy]),
189        [ AH_TEMPLATE([va_copy], [define if va_copy is not available])
190        AC_TRY_LINK([#include <stdarg.h>], [va_list ap1, ap2; __va_copy(ap1, ap2);],
191        [ AC_DEFINE([va_copy], [__va_copy])
192        AC_MSG_RESULT([__va_copy])],
193        [ AC_DEFINE([va_copy(dest,src)], [memcpy(&dest,&src,sizeof(va_list))])
194        AC_MSG_RESULT([memcpy])]
195    )
196])
197
198
199dnl ----------------------------------------------------------------------------
200dnl
201dnl  dht
202
203DHT_CFLAGS="-I\$(top_srcdir)/third-party/dht"
204DHT_LIBS="\$(top_builddir)/third-party/dht/libdht.a"
205AC_SUBST(DHT_CFLAGS)
206AC_SUBST(DHT_LIBS)
207
208
209dnl ----------------------------------------------------------------------------
210dnl
211dnl  utp
212
213AC_CHECK_LIB([rt],
214             [clock_gettime],
215             [libutp_extra_libs="-lrt"],
216             [libutp_extra_libs=""])
217
218AC_MSG_CHECKING([µTP])
219build_utp="no"
220if test "x$HAVE_CXX" = "xyes" ; then
221    have_utp="yes"
222else
223    have_utp="no"
224fi
225AC_ARG_ENABLE([utp],
226              AS_HELP_STRING([--enable-utp],[build µTP support]),
227              [want_utp=${enableval}],
228              [want_utp=${have_utp}])
229if test "x$want_utp" = "xyes" ; then
230    if test "x$have_utp" = "xyes"; then
231        LIBUTP_CFLAGS="-I\$(top_srcdir)/third-party/"
232        LIBUTP_LIBS="\$(top_builddir)/third-party/libutp/libutp.a"
233        LIBUTP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/libutp/libutp.a"
234        if test "x$libutp_extra_libs" != "x" ; then
235            LIBUTP_LIBS="$LIBUTP_LIBS $libutp_extra_libs"
236            LIBUTP_LIBS_QT="$LIBUTP_LIBS_QT $libutp_extra_libs"
237        fi
238        AC_DEFINE([WITH_UTP],[1])
239        build_utp="yes"
240    else
241      AC_MSG_ERROR("Unable to build uTP support -- C++ compiler not found")
242    fi
243fi
244AC_SUBST(LIBUTP_CFLAGS)
245AC_SUBST(LIBUTP_LIBS)
246AC_SUBST(LIBUTP_LIBS_QT)
247AM_CONDITIONAL([BUILD_UTP],[test "x$build_utp" = "xyes"])
248AC_MSG_RESULT([$build_utp])
249
250
251dnl
252dnl  look for preinstalled miniupnpc...
253dnl
254
255AC_MSG_CHECKING([supported miniupnp library])
256upnp_version="none"
257ac_save_LIBS="$LIBS"
258LIBS="-lminiupnpc"
259# See if the OS has its miniupnp 1.5 installed
260AC_TRY_LINK([
261    #include <stdlib.h>
262    #include <miniupnpc/miniupnpc.h>
263    #include <miniupnpc/upnpcommands.h>
264],[
265    struct UPNPDev * devlist;
266    struct UPNPUrls    urls;
267    struct IGDdatas    data;
268    char lanaddr[16];
269    char portStr[8];
270    char intPort[8];
271    char intClient[16];
272    upnpDiscover( 2000, NULL, NULL, 0 );
273    UPNP_GetValidIGD( devlist, &urls, &data, lanaddr, sizeof( lanaddr ) );
274    UPNP_GetSpecificPortMappingEntry( urls.controlURL, data.first.servicetype,
275                        portStr, "TCP", intClient, intPort );
276],[
277AC_DEFINE(HAVE_MINIUPNP_15, 1, [Define to 1 if you have miniupnpc version 1.5])
278upnp_version="1.5"])
279
280# See if the OS has its miniupnp 1.6 installed
281AC_TRY_LINK([
282    #include <stdlib.h>
283    #include <errno.h>
284    #include <miniupnpc/miniupnpc.h>
285    #include <miniupnpc/upnpcommands.h>
286],[
287    struct UPNPDev * devlist;
288    struct UPNPUrls    urls;
289    struct IGDdatas    data;
290    char lanaddr[16];
291    char portStr[8];
292    char intPort[8];
293    char intClient[16];
294    upnpDiscover( 2000, NULL, NULL, 0, 0, &errno );
295    UPNP_GetValidIGD( devlist, &urls, &data, lanaddr, sizeof( lanaddr ) );
296    UPNP_GetSpecificPortMappingEntry( urls.controlURL, data.first.servicetype,
297                        portStr, "TCP", intClient, intPort, NULL, NULL, NULL );
298],[
299AC_DEFINE(HAVE_MINIUPNP_16, 1, [Define to 1 if you have miniupnpc version 1.6])
300upnp_version="1.6"])
301
302# ... and the results of our tests
303LIBS="$ac_save_LIBS"
304AC_MSG_RESULT([$upnp_version])
305AM_CONDITIONAL([BUILD_MINIUPNP],[test "x$upnp_version" = "xnone"])
306if test "x$upnp_version" = "xnone" ; then
307    LIBUPNP_CFLAGS="-I\$(top_srcdir)/third-party/"
308    LIBUPNP_LIBS="\$(top_builddir)/third-party/miniupnp/libminiupnp.a"
309    LIBUPNP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/miniupnp/libminiupnp.a"
310    dnl because this is the version that we bundle...
311    AC_DEFINE(HAVE_MINIUPNP_16, 1, [Define to 1 if you have miniupnpc version 1.6])
312else
313    AC_DEFINE([SYSTEM_MINIUPNP])
314    LIBUPNP_CFLAGS=""
315    LIBUPNP_LIBS="-lminiupnpc"
316    LIBUPNP_LIBS_QT="-lminiupnpc"
317fi
318AC_SUBST(LIBUPNP_CFLAGS)
319AC_SUBST(LIBUPNP_LIBS)
320AC_SUBST(LIBUPNP_LIBS_QT)
321
322
323 
324
325dnl ----------------------------------------------------------------------------
326dnl
327dnl  Allow usage of system natpmp library
328
329LIBNATPMP_CFLAGS="-I\$(top_srcdir)/third-party/libnatpmp/"
330LIBNATPMP_LIBS="\$(top_builddir)/third-party/libnatpmp/libnatpmp.a"
331LIBNATPMP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/libnatpmp/libnatpmp.a"
332build_bundled_natpmp="yes"
333AC_ARG_ENABLE([external-natpmp],
334              AS_HELP_STRING([--enable-external-natpmp],[Use system external-natpmp]),
335              [want_external_natpmp=${enableval}],
336              [want_external_natpmp=no])
337if test "x$want_external_natpmp" != "xno" ; then
338        dnl Would be lovely if it had pkgconfig
339        LIBNATPMP_CFLAGS="" 
340        LIBNATPMP_LIBS="-lnatpmp"
341        LIBNATPMP_LIBS_QT="-lnatpmp"
342        build_bundled_natpmp="no"
343fi
344AM_CONDITIONAL([BUILD_NATPMP],[test "x$build_bundled_natpmp" = "xyes"])
345AC_SUBST(LIBNATPMP_CFLAGS)
346AC_SUBST(LIBNATPMP_LIBS)
347AC_SUBST(LIBNATPMP_LIBS_QT)
348
349
350dnl ----------------------------------------------------------------------------
351dnl
352dnl  detection for the GTK+ client
353
354
355gtk_version="none"
356with_gtk_default="no"
357PKG_CHECK_EXISTS([gtk+-2.0 >= $GTK2_MINIMUM],[gtk_version="2" with_gtk_default="yes"])
358PKG_CHECK_EXISTS([gtk+-3.0 >= $GTK3_MINIMUM],[gtk_version="3" with_gtk_default="yes"])
359AC_ARG_WITH([gtk], AC_HELP_STRING([--with-gtk],[with Gtk]),
360            [with_gtk=$withval],
361            [with_gtk=$with_gtk_default])
362if test "x$with_gtk" = "x2" ; then
363    PKG_CHECK_EXISTS([gtk+-2.0 >= $GTK2_MINIMUM],[gtk_version="2" with_gtk="yes"],[gtk_version="none" with_gtk="no"])
364fi
365if test "x$with_gtk" = "x3" ; then
366    PKG_CHECK_EXISTS([gtk+-3.0 >= $GTK3_MINIMUM],[gtk_version="3" with_gtk="yes"],[gtk_version="none" with_gtk="no"])
367fi
368AC_ARG_ENABLE([nls],
369              [AS_HELP_STRING([--enable-nls],[enable native language support])],,
370              [enable_nls=yes])
371AM_CONDITIONAL([BUILD_GTK],[test "x$with_gtk" = "xyes"])
372use_libappindicator=no
373if test "x$with_gtk" = "xyes" ; then
374
375    if test "x$gtk_version" = "xnone" ; then
376        AC_MSG_ERROR("GTK+ not found!")
377    fi
378    if test "x$enable_nls" = "xno" ; then
379        AC_MSG_ERROR("The gtk client cannot be built without nls support.  Try adding either --enable-nls or --without-gtk" )
380    fi
381
382    if test "x$gtk_version" = "x3"; then
383
384        PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= $GTK3_MINIMUM
385                                  glib-2.0 >= $GLIB_MINIMUM
386                                  gio-2.0 >= $GIO_MINIMUM,
387                                  gmodule-2.0 >= $GLIB_MINIMUM
388                                  gthread-2.0 >= $GLIB_MINIMUM])
389        PKG_CHECK_MODULES([LIBAPPINDICATOR],
390                          [appindicator3-0.1 >= $LIBAPPINDICATOR_MINIMUM],
391                          [have_libappindicator=yes],
392                          [have_libappindicator=no])
393        AC_MSG_NOTICE([using GTK+ 3])
394    else
395
396        PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= $GTK2_MINIMUM
397                                  glib-2.0 >= $GLIB_MINIMUM
398                                  gio-2.0 >= $GIO_MINIMUM,
399                                  gmodule-2.0 >= $GLIB_MINIMUM
400                                  gthread-2.0 >= $GLIB_MINIMUM])
401        PKG_CHECK_MODULES([LIBAPPINDICATOR],
402                          [appindicator-0.1 >= $LIBAPPINDICATOR_MINIMUM],
403                          [have_libappindicator=yes],
404                          [have_libappindicator=no])
405        AC_MSG_NOTICE([using GTK+ 2])
406
407    fi
408
409    if test "x$have_libappindicator" = "xyes"; then
410        use_libappindicator=yes
411        AC_DEFINE([HAVE_LIBAPPINDICATOR], 1)
412    else
413        LIBAPPINDICATOR_CFLAGS=
414        LIBAPPINDICATOR_LIBS=
415    fi
416fi
417
418dnl This section is only used for internationalization.
419dnl If you don't need translations and this section gives you trouble --
420dnl such as if you're building for a headless system --
421dnl it's okay to tear this section out and re-build the configure script.
422dnl
423dnl Note to packagers: the bump to intltool 0.40 was made to fix
424dnl a "make check" failure on some systems.  if upgrading to 0.40 is
425dnl a problem and the old version was working fine for you,
426dnl it should be safe to re-edit 0.40 back down to 0.23
427
428use_nls=no
429if test "x$enable_nls" = "xyes" ; then
430    use_nls=yes
431    m4_ifdef([IT_PROG_INTLTOOL],
432             [IT_PROG_INTLTOOL([0.35.0],[no-xml])],
433             [AC_MSG_ERROR("--enable-nls requires intltool to be installed.")])
434    AC_CHECK_HEADERS([libintl.h])
435    GETTEXT_PACKAGE=transmission-gtk
436    AC_SUBST(GETTEXT_PACKAGE)
437    AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
438    AM_GLIB_GNU_GETTEXT
439    transmissionlocaledir='${prefix}/${DATADIRNAME}/locale'
440    AC_SUBST(transmissionlocaledir)
441fi
442AC_SUBST(INTLLIBS)
443
444
445dnl ----------------------------------------------------------------------------
446dnl
447dnl  platform-specific stuff.
448
449AC_CANONICAL_HOST
450have_darwin="no"
451have_msw="no"
452case $host_os in
453
454   *mingw32*)
455     have_msw="yes"
456     CXXFLAGS="$CXXFLAGS -mms-bitfields -mwin32 -mwindows"
457     CPPFLAGS="$CPPFLAGS -DWIN32 -D_WIN32 -DWIN32_LEAN_AND_MEAN"
458     LIBS="$LIBS -liphlpapi -lshell32 -lws2_32"
459     transmissionlocaledir="locale"
460     if test -z "$host_alias"; then
461       hostaliaswindres=
462     else
463       hostaliaswindres="$host_alias-windres";
464     fi
465     AC_CHECK_TOOL(WINDRES, windres)
466     ;;
467
468  *darwin*)
469    have_darwin="yes"
470    CFLAGS="-DMACOSX $CFLAGS"
471    ;;
472
473esac
474
475AC_ARG_ENABLE([lightweight],
476              AS_HELP_STRING([--enable-lightweight],[optimize libtransmission for low-resource systems: smaller cache size, prefer unencrypted peer connections, etc.]),
477              [enable_lightweight=${enableval}],
478              [enable_lightweight="no"])
479if test "x$enable_lightweight" = "xyes" ; then
480  AC_DEFINE([TR_LIGHTWEIGHT],[1],[optimize libtransmission for low-resource systems])
481fi
482
483AC_ARG_ENABLE([cli],
484              [AS_HELP_STRING([--enable-cli],[build command-line client])],
485              [build_cli=${enableval}],
486              [build_cli="yes"])
487AM_CONDITIONAL([BUILD_CLI],[test "x$build_cli" = "xyes"])
488
489AC_ARG_ENABLE([mac],
490              [AS_HELP_STRING([--enable-mac],[build Mac client])],
491              [build_mac=${enableval}],
492              [build_mac=${have_darwin}])
493AM_CONDITIONAL([BUILD_MAC],[test "x$build_mac" = "xyes"])
494
495AC_ARG_ENABLE([daemon],
496              [AS_HELP_STRING([--enable-daemon],[build daemon])],
497              [build_daemon=${enableval}],
498              [build_daemon="yes"])
499AM_CONDITIONAL([BUILD_DAEMON],[test "x$build_daemon" = "xyes"])
500
501
502if test "x$build_mac" = "xyes" ; then
503    # Make sure the proper Mac SDK is installed
504    if test ! -d /Developer/SDKs/MacOSX10.5.sdk; then
505      cat << EOF
506You need to install the Mac OS X 10.5 SDK in order to build Transmission
507with --enable-mac:
508  Get your Xcode CD or package
509  Restart the install
510  When it gets to "Installation Type", select "Customize"
511  Select "Mac OS X 10.5 SDK" under "Cross Development"
512  Finish the install.
513EOF
514      exit 1
515    fi
516fi
517if test "x$have_darwin" = "xyes"; then
518    AC_DEFINE([HAVE_DARWIN], 1)
519fi
520if test "x$have_msw" = "xyes"; then
521    AC_DEFINE([HAVE_MSW], 1)
522fi
523AM_CONDITIONAL(WIN32, test "x$have_msw" = "xyes")
524
525dnl ----------------------------------------------------------------------------
526dnl
527dnl  Generate the output
528
529AC_CONFIG_FILES([Makefile
530                 transmission-gtk.spec
531                 cli/Makefile
532                 daemon/Makefile
533                 extras/Makefile
534                 libtransmission/Makefile
535                 utils/Makefile
536                 third-party/Makefile
537                 third-party/dht/Makefile
538                 third-party/libutp/Makefile
539                 third-party/libnatpmp/Makefile
540                 third-party/miniupnp/Makefile
541                 macosx/Makefile
542                 gtk/Makefile
543                 gtk/icons/Makefile
544                 qt/config.pri
545                 web/Makefile
546                 web/images/Makefile
547                 web/style/Makefile
548                 web/style/jqueryui/Makefile
549                 web/style/jqueryui/images/Makefile
550                 web/style/transmission/Makefile
551                 web/style/transmission/images/Makefile
552                 web/style/transmission/images/buttons/Makefile
553                 web/javascript/Makefile
554                 web/javascript/jquery/Makefile
555                 po/Makefile.in])
556
557AC_OUTPUT
558
559echo "
560
561Configuration:
562
563   Source code location:                              ${srcdir}
564   Compiler:                                          ${CXX}
565
566   Build libtransmission:                             yes
567      * optimized for low-resource systems:           ${enable_lightweight}
568      * µTP enabled:                                  ${build_utp}
569
570   Build Command-Line client:                         ${build_cli}
571
572   Build GTK+ client:                                 ${with_gtk} (GTK+ $gtk_version)
573      * libappindicator for an Ubuntu-style tray:     ${use_libappindicator}
574
575   Build Daemon:                                      ${build_daemon}
576
577   Build Mac client:                                  ${build_mac}
578
579"
Note: See TracBrowser for help on using the repository browser.