source: trunk/configure.ac @ 14383

Last change on this file since 14383 was 14383, checked in by mikedld, 7 years ago

Don't mess with MinGW printf support for now (tricky)

File size: 17.8 KB
Line 
1dnl convention: -TR MAJOR MINOR MAINT STATUS - (each a single char)
2dnl STATUS: "X" for prerelease beta builds,
3dnl         "Z" for unsupported trunk builds,
4dnl         "0" for stable, supported releases
5dnl these should be the only two lines you need to change
6m4_define([user_agent_prefix],[2.84+])
7m4_define([peer_id_prefix],[-TR284Z-])
8
9AC_INIT([transmission],[user_agent_prefix],[http://trac.transmissionbt.com/newticket])
10AC_SUBST(USERAGENT_PREFIX,[user_agent_prefix])
11AC_SUBST(PEERID_PREFIX,[peer_id_prefix])
12
13m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
14
15AC_CONFIG_MACRO_DIR([m4])
16
17dnl AM_CONFIG_HEADER(config.h)
18AC_CONFIG_SRCDIR(libtransmission/transmission.h)
19AM_INIT_AUTOMAKE([1.9 tar-pax no-dist-gzip dist-xz])
20LT_INIT
21LT_LIB_M
22
23if test m4_substr(peer_id_prefix,6,1) = "0"; then
24  supported_build=yes
25  CPPFLAGS="$CPPFLAGS -DNDEBUG"
26else
27  supported_build=no
28  if test "x$GCC" = "xyes" ; then
29    CFLAGS="$CFLAGS -g -O0"
30    CXXFLAGS="$CXXFLAGS -g -O0"
31  fi
32fi
33AM_CONDITIONAL(TR_UNSTABLE, test "x$supported_build" = "xno")
34
35##
36##
37##   MANDATORY for everything
38##
39##
40CURL_MINIMUM=7.15.4
41AC_SUBST(CURL_MINIMUM)
42LIBEVENT_MINIMUM=2.0.10
43AC_SUBST(LIBEVENT_MINIMUM)
44OPENSSL_MINIMUM=0.9.4
45AC_SUBST(OPENSSL_MINIMUM)
46ZLIB_MINIMUM=1.2.3
47AC_SUBST(ZLIB_MINIMUM)
48
49##
50##
51##   MANDATORY for the GTK+ client
52##
53##
54
55GTK_MINIMUM=3.4.0
56AC_SUBST(GTK_MINIMUM)
57GLIB_MINIMUM=2.32.0
58AC_SUBST(GLIB_MINIMUM)
59GIO_MINIMUM=2.26.0
60AC_SUBST(GIO_MINIMUM)
61
62##
63##
64##   OPTIONAL for the GTK+ client
65##
66##
67
68# create the tray icon with AppIndicator
69LIBAPPINDICATOR_MINIMUM=0.4.90
70AC_SUBST(LIBAPPINDICATOR_MINIMUM)
71
72
73AC_PROG_CC
74AC_PROG_CXX
75AC_C_INLINE
76if test "x$GCC" = "xyes" ; then
77
78    CFLAGS="$CFLAGS -std=gnu99 -ggdb3 -Wall -W -Wpointer-arith -Wformat-security -Wundef -Wcast-align -Wstrict-prototypes -Wmissing-declarations -Wmissing-format-attribute -Wredundant-decls -Wnested-externs -Wunused-parameter -Wwrite-strings -Winline -Wfloat-equal"
79
80    dnl figure out gcc version
81    AC_MSG_CHECKING([gcc version])
82    GCC_VERSION=`$CC -dumpversion`
83    GCC_MAJOR=`echo $GCC_VERSION | cut -d . -f1`
84    GCC_MINOR=`echo $GCC_VERSION | cut -d . -f2`
85    GCC_VERSION_NUM=`(expr $GCC_MAJOR "*" 100 + $GCC_MINOR) 2>/dev/null`
86
87    AC_MSG_RESULT($GCC_VERSION)
88    if test $GCC_VERSION_NUM -ge 304; then
89        dnl these were added in 3.4
90        CFLAGS="$CFLAGS -Wextra -Wdeclaration-after-statement -Winit-self"
91    fi
92    if test $GCC_VERSION_NUM -ge 403; then
93        dnl these were added in 4.3
94        CFLAGS="$CFLAGS -Wvariadic-macros"
95    fi
96fi
97
98AC_HEADER_STDC
99AC_HEADER_TIME
100
101AC_CHECK_HEADERS([stdbool.h])
102AC_CHECK_FUNCS([iconv_open pread pwrite lrintf strlcpy daemon dirname basename canonicalize_file_name strcasecmp localtime_r fallocate64 posix_fallocate memmem strsep strtold syslog valloc getpagesize posix_memalign statvfs htonll ntohll mkdtemp])
103AC_PROG_INSTALL
104AC_PROG_MAKE_SET
105ACX_PTHREAD
106
107if test "x$ac_cv_func_strtold" != "xyes" ; then
108    CPPFLAGS="$CPPFLAGS -Dstrtold=strtod"
109fi
110
111AC_SEARCH_LIBS(cos, [m])
112AC_SEARCH_LIBS([socket], [socket net])
113AC_SEARCH_LIBS([gethostbyname], [nsl bind])
114AC_SEARCH_LIBS([quotacursor_skipidtype], [quota])
115PKG_CHECK_MODULES(OPENSSL, [openssl >= $OPENSSL_MINIMUM], , [CHECK_SSL()])
116PKG_CHECK_MODULES(LIBCURL, [libcurl >= $CURL_MINIMUM])
117PKG_CHECK_MODULES(LIBEVENT, [libevent >= $LIBEVENT_MINIMUM])
118PKG_CHECK_MODULES(ZLIB, [zlib >= $ZLIB_MINIMUM])
119
120AC_SYS_LARGEFILE
121AC_CHECK_FUNCS([lseek64])
122
123AC_FUNC_GETMNTENT
124
125dnl ----------------------------------------------------------------------------
126dnl
127dnl posix_fadvise
128
129dnl can posix_fadvise be used
130AC_CHECK_DECLS(posix_fadvise, [], [], [
131#define _XOPEN_SOURCE 600
132#include <fcntl.h>])
133AC_CHECK_FUNCS([posix_fadvise])
134
135
136dnl ----------------------------------------------------------------------------
137dnl
138dnl file monitoring for the daemon
139
140AC_CHECK_HEADER([sys/inotify.h],
141                [AC_CHECK_FUNC([inotify_init],[have_inotify="yes"],[have_inotify="no"])],
142                [have_inotify="no"])
143AC_ARG_WITH([inotify],
144            [AS_HELP_STRING([--with-inotify],[Enable inotify support (default=auto)])],
145            [want_inotify=${withval}],
146            [want_inotify=${have_inotify}])
147if test "x$want_inotify" = "xyes" ; then
148    if test "x$have_inotify" = "xyes"; then
149      AC_DEFINE([WITH_INOTIFY],[1])
150    else
151      AC_MSG_ERROR("inotify not found!")
152    fi
153fi
154
155AC_CHECK_HEADER([sys/event.h],
156                [AC_CHECK_FUNC([kqueue],[have_kqueue="yes"],[have_kqueue="no"])],
157                [have_kqueue="no"])
158AC_ARG_WITH([kqueue],
159            [AS_HELP_STRING([--with-kqueue],[Enable kqueue support (default=auto)])],
160            [want_kqueue=${withval}],
161            [want_kqueue=${have_kqueue}])
162if test "x$want_kqueue" = "xyes" ; then
163    if test "x$have_kqueue" = "xyes"; then
164      AC_DEFINE([WITH_KQUEUE],[1])
165    else
166      AC_MSG_ERROR("kqueue not found!")
167    fi
168fi
169
170AC_CHECK_HEADERS([sys/statvfs.h \
171                  xfs/xfs.h])
172
173
174dnl ----------------------------------------------------------------------------
175dnl
176dnl file monitoring for the daemon
177
178# Check whether to enable systemd startup notification.
179# This requires libsystemd-daemon.
180AC_ARG_WITH([systemd-daemon], AS_HELP_STRING([--with-systemd-daemon],
181            [Add support for systemd startup notification (default is autodetected)]),
182            [USE_SYSTEMD_DAEMON=$withval], [USE_SYSTEMD_DAEMON=auto])
183AS_IF([test "x$USE_SYSTEMD_DAEMON" != "xno"], [
184    PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
185        [AC_DEFINE(USE_SYSTEMD_DAEMON,1,[Use systemd startup notification])],
186        [AS_IF([test "x$USE_SYSTEMD_DAEMON" = "xyes"],
187            [AC_MSG_ERROR([systemd startup notification support requested, but libsystemd-daemon not found.])]
188        )]
189    )
190])
191
192
193dnl ----------------------------------------------------------------------------
194dnl
195dnl  dht
196
197DHT_CFLAGS="-I\$(top_srcdir)/third-party/dht"
198DHT_LIBS="\$(top_builddir)/third-party/dht/libdht.a"
199AC_SUBST(DHT_CFLAGS)
200AC_SUBST(DHT_LIBS)
201
202
203dnl ----------------------------------------------------------------------------
204dnl
205dnl  utp
206
207AC_CHECK_LIB([rt],
208             [clock_gettime],
209             [libutp_extra_libs="-lrt"],
210             [libutp_extra_libs=""])
211
212AC_MSG_CHECKING([µTP])
213build_utp="no"
214if test "x$CXX" != "x" ; then
215    have_utp="yes"
216else
217    have_utp="no"
218fi
219AC_ARG_ENABLE([utp],
220              AS_HELP_STRING([--enable-utp],[build µTP support]),
221              [want_utp=${enableval}],
222              [want_utp=${have_utp}])
223if test "x$want_utp" = "xyes" ; then
224    if test "x$have_utp" = "xyes"; then
225        LIBUTP_CFLAGS="-I\$(top_srcdir)/third-party/"
226        LIBUTP_LIBS="\$(top_builddir)/third-party/libutp/libutp.a"
227        LIBUTP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/libutp/libutp.a"
228        if test "x$libutp_extra_libs" != "x" ; then
229            LIBUTP_LIBS="$LIBUTP_LIBS $libutp_extra_libs"
230            LIBUTP_LIBS_QT="$LIBUTP_LIBS_QT $libutp_extra_libs"
231        fi
232        AC_DEFINE([WITH_UTP],[1])
233        build_utp="yes"
234    else
235      AC_MSG_ERROR("Unable to build uTP support -- C++ compiler not found")
236    fi
237fi
238AC_SUBST(LIBUTP_CFLAGS)
239AC_SUBST(LIBUTP_LIBS)
240AC_SUBST(LIBUTP_LIBS_QT)
241AM_CONDITIONAL([BUILD_UTP],[test "x$build_utp" = "xyes"])
242AC_MSG_RESULT([$build_utp])
243
244
245dnl
246dnl  look for preinstalled miniupnpc...
247dnl
248
249ac_save_LIBS="$LIBS"
250LIBS="-lminiupnpc"
251AC_MSG_CHECKING([system miniupnpc library])
252
253dnl See if ANY version of miniupnpc is installed
254AC_LINK_IFELSE(
255  [AC_LANG_PROGRAM([#include <miniupnpc/miniupnpc.h>],
256                   [struct UPNPDev dev;])],
257  [upnp_version="unknown"],
258  [upnp_version="none"]
259)
260
261dnl Let's hope it's 1.7 or higher, since it provides
262dnl MINIUPNPC_API_VERSION and we won't have to figure
263dnl it out on our own
264if test "x$upnp_version" = "xunknown" ; then
265  AC_RUN_IFELSE(
266    [AC_LANG_PROGRAM(
267      [#include <stdlib.h>
268       #include <miniupnpc/miniupnpc.h>],
269      [#ifdef MINIUPNPC_API_VERSION
270       return EXIT_SUCCESS;
271       #else
272       return EXIT_FAILURE;
273       #endif]
274    )],
275    [upnp_version=">= 1.7"]
276  )
277fi
278
279dnl Or maybe it's miniupnp 1.6
280if test "x$upnp_version" = "xunknown" ; then
281  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
282    #include <stdlib.h>
283    #include <errno.h>
284    #include <miniupnpc/miniupnpc.h>
285    #include <miniupnpc/upnpcommands.h>
286  ]], [[
287    struct UPNPDev * devlist;
288    struct UPNPUrls urls;
289    struct IGDdatas data;
290    char lanaddr[16];
291    char portStr[8];
292    char intPort[8];
293    char intClient[16];
294    upnpDiscover( 2000, NULL, NULL, 0, 0, &errno );
295    UPNP_GetValidIGD( devlist, &urls, &data, lanaddr, sizeof( lanaddr ) );
296    UPNP_GetSpecificPortMappingEntry( urls.controlURL, data.first.servicetype,
297                        portStr, "TCP", intClient, intPort, NULL, NULL, NULL );
298  ]])],[
299  AC_DEFINE(MINIUPNPC_API_VERSION, 8, [miniupnpc 1.6 has API version 8])
300  upnp_version="1.6"])
301fi
302
303dnl Or maybe it's miniupnp 1.5
304if test "x$upnp_version" = "xunknown" ; then
305  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
306    #include <stdlib.h>
307    #include <miniupnpc/miniupnpc.h>
308    #include <miniupnpc/upnpcommands.h>
309  ]], [[
310    struct UPNPDev * devlist;
311    struct UPNPUrls urls;
312    struct IGDdatas data;
313    char lanaddr[16];
314    char portStr[8];
315    char intPort[8];
316    char intClient[16];
317    upnpDiscover( 2000, NULL, NULL, 0 );
318    UPNP_GetValidIGD( devlist, &urls, &data, lanaddr, sizeof( lanaddr ) );
319    UPNP_GetSpecificPortMappingEntry( urls.controlURL, data.first.servicetype,
320                        portStr, "TCP", intClient, intPort );
321  ]])],[
322  AC_DEFINE(MINIUPNPC_API_VERSION, 5, [miniupnpc 1.5 has API version 5])
323  upnp_version="1.5"])
324fi
325
326# ... and the results of our tests
327LIBS="$ac_save_LIBS"
328AC_MSG_RESULT([$upnp_version])
329AM_CONDITIONAL([BUILD_MINIUPNP],[test "x$upnp_version" = "xnone"])
330if test "x$upnp_version" = "xnone" ; then
331    LIBUPNP_CFLAGS="-I\$(top_srcdir)/third-party/"
332    LIBUPNP_LIBS="\$(top_builddir)/third-party/miniupnp/libminiupnp.a"
333    LIBUPNP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/miniupnp/libminiupnp.a"
334else
335    AC_DEFINE([SYSTEM_MINIUPNP])
336    LIBUPNP_CFLAGS=""
337    LIBUPNP_LIBS="-lminiupnpc"
338    LIBUPNP_LIBS_QT="-lminiupnpc"
339fi
340AC_SUBST(LIBUPNP_CFLAGS)
341AC_SUBST(LIBUPNP_LIBS)
342AC_SUBST(LIBUPNP_LIBS_QT)
343
344
345 
346
347dnl ----------------------------------------------------------------------------
348dnl
349dnl  Allow usage of system natpmp library
350
351LIBNATPMP_CFLAGS="-I\$(top_srcdir)/third-party/libnatpmp/"
352LIBNATPMP_LIBS="\$(top_builddir)/third-party/libnatpmp/libnatpmp.a"
353LIBNATPMP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/libnatpmp/libnatpmp.a"
354build_bundled_natpmp="yes"
355AC_ARG_ENABLE([external-natpmp],
356              AS_HELP_STRING([--enable-external-natpmp],[Use system external-natpmp]),
357              [want_external_natpmp=${enableval}],
358              [want_external_natpmp=no])
359if test "x$want_external_natpmp" != "xno" ; then
360        dnl Would be lovely if it had pkgconfig
361        LIBNATPMP_CFLAGS="" 
362        LIBNATPMP_LIBS="-lnatpmp"
363        LIBNATPMP_LIBS_QT="-lnatpmp"
364        build_bundled_natpmp="no"
365fi
366AM_CONDITIONAL([BUILD_NATPMP],[test "x$build_bundled_natpmp" = "xyes"])
367AC_SUBST(LIBNATPMP_CFLAGS)
368AC_SUBST(LIBNATPMP_LIBS)
369AC_SUBST(LIBNATPMP_LIBS_QT)
370
371
372dnl ----------------------------------------------------------------------------
373dnl
374dnl  detection for the GTK+ client
375
376AC_ARG_ENABLE([nls],
377              [AS_HELP_STRING([--enable-nls],[enable native language support])],,
378              [enable_nls=yes])
379PKG_CHECK_EXISTS([gtk+-3.0 >= $GTK_MINIMUM
380                  glib-2.0 >= $GLIB_MINIMUM
381                  gio-2.0 >= $GIO_MINIMUM,
382                  gmodule-2.0 >= $GLIB_MINIMUM
383                  gthread-2.0 >= $GLIB_MINIMUM],
384                 [have_gtk=yes],
385                 [have_gtk=no])
386AC_ARG_WITH([gtk], AS_HELP_STRING([--with-gtk],[with Gtk]),
387            [with_gtk=$withval],
388            [with_gtk=$have_gtk])
389AM_CONDITIONAL([BUILD_GTK],[test "x$with_gtk" = "xyes"])
390use_libappindicator=no
391if test "x$with_gtk" = "xyes" ; then
392
393    if test "x$enable_nls" = "xno" ; then
394        AC_MSG_ERROR("The gtk client cannot be built without nls support.  Try adding either --enable-nls or --without-gtk" )
395    fi
396
397    PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= $GTK_MINIMUM
398                              glib-2.0 >= $GLIB_MINIMUM
399                              gio-2.0 >= $GIO_MINIMUM,
400                              gmodule-2.0 >= $GLIB_MINIMUM
401                              gthread-2.0 >= $GLIB_MINIMUM])
402    PKG_CHECK_MODULES([LIBAPPINDICATOR],
403                      [appindicator3-0.1 >= $LIBAPPINDICATOR_MINIMUM],
404                      [have_libappindicator=yes],
405                      [have_libappindicator=no])
406    if test "x$have_libappindicator" = "xyes"; then
407        use_libappindicator=yes
408        AC_DEFINE([HAVE_LIBAPPINDICATOR], 1)
409    else
410        LIBAPPINDICATOR_CFLAGS=
411        LIBAPPINDICATOR_LIBS=
412    fi
413fi
414
415dnl This section is only used for internationalization.
416dnl If you don't need translations and this section gives you trouble --
417dnl such as if you're building for a headless system --
418dnl it's okay to tear this section out and re-build the configure script.
419dnl
420dnl Note to packagers: the bump to intltool 0.40 was made to fix
421dnl a "make check" failure on some systems.  if upgrading to 0.40 is
422dnl a problem and the old version was working fine for you,
423dnl it should be safe to re-edit 0.40 back down to 0.23
424
425use_nls=no
426if test "x$enable_nls" = "xyes" ; then
427    use_nls=yes
428    m4_ifdef([IT_PROG_INTLTOOL],
429             [IT_PROG_INTLTOOL([0.35.0],[no-xml])],
430             [AC_MSG_ERROR("--enable-nls requires intltool to be installed.")])
431    AC_CHECK_HEADERS([libintl.h])
432    GETTEXT_PACKAGE=transmission-gtk
433    AC_SUBST(GETTEXT_PACKAGE)
434    AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
435    AM_GLIB_GNU_GETTEXT
436    transmissionlocaledir='${prefix}/${DATADIRNAME}/locale'
437    AC_SUBST(transmissionlocaledir)
438fi
439AC_SUBST(INTLLIBS)
440
441
442dnl ----------------------------------------------------------------------------
443dnl
444dnl  platform-specific stuff.
445
446AC_CANONICAL_HOST
447have_darwin="no"
448have_msw="no"
449case $host_os in
450
451   *mingw32*)
452     have_msw="yes"
453     CXXFLAGS="$CXXFLAGS -mms-bitfields -mwin32 -mwindows"
454     CPPFLAGS="$CPPFLAGS -DWINVER=0x0600 -D_WIN32_WINNT=0x0600 -DWIN32_LEAN_AND_MEAN"
455     # CPPFLAGS="$CPPFLAGS -D__USE_MINGW_ANSI_STDIO=1 -D__STDC_FORMAT_MACROS=1"
456     LIBS="$LIBS -liphlpapi -lshell32 -lws2_32"
457     transmissionlocaledir="locale"
458     if test -z "$host_alias"; then
459       hostaliaswindres=
460     else
461       hostaliaswindres="$host_alias-windres";
462     fi
463     AC_CHECK_TOOL(WINDRES, windres)
464     ;;
465
466  *darwin*)
467    have_darwin="yes"
468    ;;
469
470esac
471
472AC_ARG_ENABLE([lightweight],
473              AS_HELP_STRING([--enable-lightweight],[optimize libtransmission for low-resource systems: smaller cache size, prefer unencrypted peer connections, etc.]),
474              [enable_lightweight=${enableval}],
475              [enable_lightweight="no"])
476if test "x$enable_lightweight" = "xyes" ; then
477  AC_DEFINE([TR_LIGHTWEIGHT],[1],[optimize libtransmission for low-resource systems])
478fi
479
480AC_ARG_ENABLE([cli],
481              [AS_HELP_STRING([--enable-cli],[build command-line client])],
482              [build_cli=${enableval}],
483              [build_cli="yes"])
484AM_CONDITIONAL([BUILD_CLI],[test "x$build_cli" = "xyes"])
485
486AC_ARG_ENABLE([mac],
487              [AS_HELP_STRING([--enable-mac],[build Mac client])],
488              [build_mac=${enableval}],
489              [build_mac=${have_darwin}])
490AM_CONDITIONAL([BUILD_MAC],[test "x$build_mac" = "xyes"])
491
492AC_ARG_ENABLE([daemon],
493              [AS_HELP_STRING([--enable-daemon],[build daemon])],
494              [build_daemon=${enableval}],
495              [build_daemon="yes"])
496AM_CONDITIONAL([BUILD_DAEMON],[test "x$build_daemon" = "xyes"])
497
498
499if test "x$build_mac" = "xyes" ; then
500   AC_DEFINE([BUILD_MAC_CLIENT], 1)
501    # Make sure the proper Mac SDK is installed
502    if test ! -d /Developer/SDKs/MacOSX10.5.sdk; then
503      cat << EOF
504You need to install the Mac OS X 10.5 SDK in order to build Transmission
505with --enable-mac:
506  Get your Xcode CD or package
507  Restart the install
508  When it gets to "Installation Type", select "Customize"
509  Select "Mac OS X 10.5 SDK" under "Cross Development"
510  Finish the install.
511EOF
512      exit 1
513    fi
514fi
515AM_CONDITIONAL(WIN32, test "x$have_msw" = "xyes")
516
517dnl ----------------------------------------------------------------------------
518dnl
519dnl  Generate the output
520
521AC_CONFIG_FILES([Makefile
522                 transmission-gtk.spec
523                 cli/Makefile
524                 daemon/Makefile
525                 extras/Makefile
526                 libtransmission/Makefile
527                 utils/Makefile
528                 third-party/Makefile
529                 third-party/dht/Makefile
530                 third-party/libutp/Makefile
531                 third-party/libnatpmp/Makefile
532                 third-party/miniupnp/Makefile
533                 macosx/Makefile
534                 gtk/Makefile
535                 gtk/icons/Makefile
536                 qt/config.pri
537                 web/Makefile
538                 web/images/Makefile
539                 web/style/Makefile
540                 web/style/jqueryui/Makefile
541                 web/style/jqueryui/images/Makefile
542                 web/style/transmission/Makefile
543                 web/style/transmission/images/Makefile
544                 web/style/transmission/images/buttons/Makefile
545                 web/javascript/Makefile
546                 web/javascript/jquery/Makefile
547                 po/Makefile.in])
548
549AC_OUTPUT
550
551echo "
552
553Configuration:
554
555   Source code location:                              ${srcdir}
556   Compiler:                                          ${CXX}
557
558   Build libtransmission:                             yes
559      * optimized for low-resource systems:           ${enable_lightweight}
560      * µTP enabled:                                  ${build_utp}
561
562   Build Command-Line client:                         ${build_cli}
563
564   Build GTK+ client:                                 ${with_gtk}
565      * libappindicator for an Ubuntu-style tray:     ${use_libappindicator}
566
567   Build Daemon:                                      ${build_daemon}
568
569   Build Mac client:                                  ${build_mac}
570
571"
Note: See TracBrowser for help on using the repository browser.