source: trunk/configure.ac @ 14407

Last change on this file since 14407 was 14407, checked in by mikedld, 7 years ago

#5805: Allow building against system libutp (patch by jbeich)

File size: 18.2 KB
Line 
1dnl convention: -TR MAJOR MINOR MAINT STATUS - (each a single char)
2dnl STATUS: "X" for prerelease beta builds,
3dnl         "Z" for unsupported trunk builds,
4dnl         "0" for stable, supported releases
5dnl these should be the only two lines you need to change
6m4_define([user_agent_prefix],[2.84+])
7m4_define([peer_id_prefix],[-TR284Z-])
8
9AC_INIT([transmission],[user_agent_prefix],[http://trac.transmissionbt.com/newticket])
10AC_SUBST(USERAGENT_PREFIX,[user_agent_prefix])
11AC_SUBST(PEERID_PREFIX,[peer_id_prefix])
12
13m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
14
15AC_CONFIG_MACRO_DIR([m4])
16
17dnl AM_CONFIG_HEADER(config.h)
18AC_CONFIG_SRCDIR(libtransmission/transmission.h)
19AM_INIT_AUTOMAKE([1.9 tar-pax no-dist-gzip dist-xz])
20LT_INIT
21LT_LIB_M
22
23if test m4_substr(peer_id_prefix,6,1) = "0"; then
24  supported_build=yes
25  CPPFLAGS="$CPPFLAGS -DNDEBUG"
26else
27  supported_build=no
28  if test "x$GCC" = "xyes" ; then
29    CFLAGS="$CFLAGS -g -O0"
30    CXXFLAGS="$CXXFLAGS -g -O0"
31  fi
32fi
33AM_CONDITIONAL(TR_UNSTABLE, test "x$supported_build" = "xno")
34
35##
36##
37##   MANDATORY for everything
38##
39##
40CURL_MINIMUM=7.15.4
41AC_SUBST(CURL_MINIMUM)
42LIBEVENT_MINIMUM=2.0.10
43AC_SUBST(LIBEVENT_MINIMUM)
44OPENSSL_MINIMUM=0.9.4
45AC_SUBST(OPENSSL_MINIMUM)
46ZLIB_MINIMUM=1.2.3
47AC_SUBST(ZLIB_MINIMUM)
48
49##
50##
51##   MANDATORY for the GTK+ client
52##
53##
54
55GTK_MINIMUM=3.4.0
56AC_SUBST(GTK_MINIMUM)
57GLIB_MINIMUM=2.32.0
58AC_SUBST(GLIB_MINIMUM)
59GIO_MINIMUM=2.26.0
60AC_SUBST(GIO_MINIMUM)
61
62##
63##
64##   OPTIONAL for the GTK+ client
65##
66##
67
68# create the tray icon with AppIndicator
69LIBAPPINDICATOR_MINIMUM=0.4.90
70AC_SUBST(LIBAPPINDICATOR_MINIMUM)
71
72
73AC_PROG_CC
74AC_PROG_CXX
75AC_C_INLINE
76if test "x$GCC" = "xyes" ; then
77
78    CFLAGS="$CFLAGS -std=gnu99 -ggdb3 -Wall -W -Wpointer-arith -Wformat-security -Wundef -Wcast-align -Wstrict-prototypes -Wmissing-declarations -Wmissing-format-attribute -Wredundant-decls -Wnested-externs -Wunused-parameter -Wwrite-strings -Winline -Wfloat-equal"
79
80    dnl figure out gcc version
81    AC_MSG_CHECKING([gcc version])
82    GCC_VERSION=`$CC -dumpversion`
83    GCC_MAJOR=`echo $GCC_VERSION | cut -d . -f1`
84    GCC_MINOR=`echo $GCC_VERSION | cut -d . -f2`
85    GCC_VERSION_NUM=`(expr $GCC_MAJOR "*" 100 + $GCC_MINOR) 2>/dev/null`
86
87    AC_MSG_RESULT($GCC_VERSION)
88    if test $GCC_VERSION_NUM -ge 304; then
89        dnl these were added in 3.4
90        CFLAGS="$CFLAGS -Wextra -Wdeclaration-after-statement -Winit-self"
91    fi
92    if test $GCC_VERSION_NUM -ge 403; then
93        dnl these were added in 4.3
94        CFLAGS="$CFLAGS -Wvariadic-macros"
95    fi
96fi
97
98AC_HEADER_STDC
99AC_HEADER_TIME
100
101AC_CHECK_HEADERS([stdbool.h])
102AC_CHECK_FUNCS([iconv_open pread pwrite lrintf strlcpy daemon dirname basename canonicalize_file_name strcasecmp localtime_r fallocate64 posix_fallocate memmem strsep strtold syslog valloc getpagesize posix_memalign statvfs htonll ntohll mkdtemp])
103AC_PROG_INSTALL
104AC_PROG_MAKE_SET
105ACX_PTHREAD
106
107if test "x$ac_cv_func_strtold" != "xyes" ; then
108    CPPFLAGS="$CPPFLAGS -Dstrtold=strtod"
109fi
110
111AC_SEARCH_LIBS(cos, [m])
112AC_SEARCH_LIBS([socket], [socket net])
113AC_SEARCH_LIBS([gethostbyname], [nsl bind])
114AC_SEARCH_LIBS([quotacursor_skipidtype], [quota])
115PKG_CHECK_MODULES(OPENSSL, [openssl >= $OPENSSL_MINIMUM], , [CHECK_SSL()])
116PKG_CHECK_MODULES(LIBCURL, [libcurl >= $CURL_MINIMUM])
117PKG_CHECK_MODULES(LIBEVENT, [libevent >= $LIBEVENT_MINIMUM])
118PKG_CHECK_MODULES(ZLIB, [zlib >= $ZLIB_MINIMUM])
119
120AC_SYS_LARGEFILE
121AC_CHECK_FUNCS([lseek64])
122
123AC_FUNC_GETMNTENT
124
125dnl ----------------------------------------------------------------------------
126dnl
127dnl posix_fadvise
128
129dnl can posix_fadvise be used
130AC_CHECK_DECLS(posix_fadvise, [], [], [
131#define _XOPEN_SOURCE 600
132#include <fcntl.h>])
133AC_CHECK_FUNCS([posix_fadvise])
134
135
136dnl ----------------------------------------------------------------------------
137dnl
138dnl file monitoring for the daemon
139
140AC_CHECK_HEADER([sys/inotify.h],
141                [AC_CHECK_FUNC([inotify_init],[have_inotify="yes"],[have_inotify="no"])],
142                [have_inotify="no"])
143AC_ARG_WITH([inotify],
144            [AS_HELP_STRING([--with-inotify],[Enable inotify support (default=auto)])],
145            [want_inotify=${withval}],
146            [want_inotify=${have_inotify}])
147if test "x$want_inotify" = "xyes" ; then
148    if test "x$have_inotify" = "xyes"; then
149      AC_DEFINE([WITH_INOTIFY],[1])
150    else
151      AC_MSG_ERROR("inotify not found!")
152    fi
153fi
154
155AC_CHECK_HEADER([sys/event.h],
156                [AC_CHECK_FUNC([kqueue],[have_kqueue="yes"],[have_kqueue="no"])],
157                [have_kqueue="no"])
158AC_ARG_WITH([kqueue],
159            [AS_HELP_STRING([--with-kqueue],[Enable kqueue support (default=auto)])],
160            [want_kqueue=${withval}],
161            [want_kqueue=${have_kqueue}])
162if test "x$want_kqueue" = "xyes" ; then
163    if test "x$have_kqueue" = "xyes"; then
164      AC_DEFINE([WITH_KQUEUE],[1])
165    else
166      AC_MSG_ERROR("kqueue not found!")
167    fi
168fi
169
170AC_CHECK_HEADERS([sys/statvfs.h \
171                  xfs/xfs.h])
172
173
174dnl ----------------------------------------------------------------------------
175dnl
176dnl file monitoring for the daemon
177
178# Check whether to enable systemd startup notification.
179# This requires libsystemd-daemon.
180AC_ARG_WITH([systemd-daemon], AS_HELP_STRING([--with-systemd-daemon],
181            [Add support for systemd startup notification (default is autodetected)]),
182            [USE_SYSTEMD_DAEMON=$withval], [USE_SYSTEMD_DAEMON=auto])
183AS_IF([test "x$USE_SYSTEMD_DAEMON" != "xno"], [
184    PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
185        [AC_DEFINE(USE_SYSTEMD_DAEMON,1,[Use systemd startup notification])],
186        [AS_IF([test "x$USE_SYSTEMD_DAEMON" = "xyes"],
187            [AC_MSG_ERROR([systemd startup notification support requested, but libsystemd-daemon not found.])]
188        )]
189    )
190])
191
192
193dnl ----------------------------------------------------------------------------
194dnl
195dnl  dht
196
197DHT_CFLAGS="-I\$(top_srcdir)/third-party/dht"
198DHT_LIBS="\$(top_builddir)/third-party/dht/libdht.a"
199AC_SUBST(DHT_CFLAGS)
200AC_SUBST(DHT_LIBS)
201
202
203dnl ----------------------------------------------------------------------------
204dnl
205dnl  utp
206
207AC_CHECK_LIB([rt],
208             [clock_gettime],
209             [libutp_extra_libs="-lrt"],
210             [libutp_extra_libs=""])
211
212AC_MSG_CHECKING([µTP])
213build_utp="no"
214
215ac_save_LIBS="$LIBS"
216LIBS="-lutp"
217AC_LINK_IFELSE(
218  [AC_LANG_PROGRAM([#include <libutp/utp.h>],
219                   [struct UTPFunctionTable func;])],
220  [have_utp="yes"],
221  [have_utp="no"]
222)
223LIBS=$ac_save_LIBS
224
225AC_ARG_ENABLE([utp],
226              AS_HELP_STRING([--enable-utp],[build µTP support]),
227              [want_utp=${enableval}],
228              [want_utp=${have_utp}])
229if test "x$want_utp" = "xyes"; then
230    if test "x$have_utp" = "xyes"; then
231        dnl Would be lovely if it had pkgconfig
232        LIBUTP_CFLAGS=""
233        LIBUTP_LIBS="-lutp $libutp_extra_libs"
234        LIBUTP_LIBS_QT="-lutp $libutp_extra_libs"
235        AC_DEFINE([WITH_UTP],[1])
236        build_utp="system"
237    elif test "x$CXX" != "x"; then
238        LIBUTP_CFLAGS="-I\$(top_srcdir)/third-party/"
239        LIBUTP_LIBS="\$(top_builddir)/third-party/libutp/libutp.a"
240        LIBUTP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/libutp/libutp.a"
241        if test "x$libutp_extra_libs" != "x" ; then
242            LIBUTP_LIBS="$LIBUTP_LIBS $libutp_extra_libs"
243            LIBUTP_LIBS_QT="$LIBUTP_LIBS_QT $libutp_extra_libs"
244        fi
245        AC_DEFINE([WITH_UTP],[1])
246        build_utp="yes"
247    else
248      AC_MSG_ERROR("Unable to build uTP support -- C++ compiler not found")
249    fi
250fi
251AC_SUBST(LIBUTP_CFLAGS)
252AC_SUBST(LIBUTP_LIBS)
253AC_SUBST(LIBUTP_LIBS_QT)
254AM_CONDITIONAL([BUILD_UTP],[test "x$build_utp" = "xyes"])
255AC_MSG_RESULT([$build_utp])
256
257
258dnl
259dnl  look for preinstalled miniupnpc...
260dnl
261
262ac_save_LIBS="$LIBS"
263LIBS="-lminiupnpc"
264AC_MSG_CHECKING([system miniupnpc library])
265
266dnl See if ANY version of miniupnpc is installed
267AC_LINK_IFELSE(
268  [AC_LANG_PROGRAM([#include <miniupnpc/miniupnpc.h>],
269                   [struct UPNPDev dev;])],
270  [upnp_version="unknown"],
271  [upnp_version="none"]
272)
273
274dnl Let's hope it's 1.7 or higher, since it provides
275dnl MINIUPNPC_API_VERSION and we won't have to figure
276dnl it out on our own
277if test "x$upnp_version" = "xunknown" ; then
278  AC_RUN_IFELSE(
279    [AC_LANG_PROGRAM(
280      [#include <stdlib.h>
281       #include <miniupnpc/miniupnpc.h>],
282      [#ifdef MINIUPNPC_API_VERSION
283       return EXIT_SUCCESS;
284       #else
285       return EXIT_FAILURE;
286       #endif]
287    )],
288    [upnp_version=">= 1.7"]
289  )
290fi
291
292dnl Or maybe it's miniupnp 1.6
293if test "x$upnp_version" = "xunknown" ; then
294  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
295    #include <stdlib.h>
296    #include <errno.h>
297    #include <miniupnpc/miniupnpc.h>
298    #include <miniupnpc/upnpcommands.h>
299  ]], [[
300    struct UPNPDev * devlist;
301    struct UPNPUrls urls;
302    struct IGDdatas data;
303    char lanaddr[16];
304    char portStr[8];
305    char intPort[8];
306    char intClient[16];
307    upnpDiscover( 2000, NULL, NULL, 0, 0, &errno );
308    UPNP_GetValidIGD( devlist, &urls, &data, lanaddr, sizeof( lanaddr ) );
309    UPNP_GetSpecificPortMappingEntry( urls.controlURL, data.first.servicetype,
310                        portStr, "TCP", intClient, intPort, NULL, NULL, NULL );
311  ]])],[
312  AC_DEFINE(MINIUPNPC_API_VERSION, 8, [miniupnpc 1.6 has API version 8])
313  upnp_version="1.6"])
314fi
315
316dnl Or maybe it's miniupnp 1.5
317if test "x$upnp_version" = "xunknown" ; then
318  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
319    #include <stdlib.h>
320    #include <miniupnpc/miniupnpc.h>
321    #include <miniupnpc/upnpcommands.h>
322  ]], [[
323    struct UPNPDev * devlist;
324    struct UPNPUrls urls;
325    struct IGDdatas data;
326    char lanaddr[16];
327    char portStr[8];
328    char intPort[8];
329    char intClient[16];
330    upnpDiscover( 2000, NULL, NULL, 0 );
331    UPNP_GetValidIGD( devlist, &urls, &data, lanaddr, sizeof( lanaddr ) );
332    UPNP_GetSpecificPortMappingEntry( urls.controlURL, data.first.servicetype,
333                        portStr, "TCP", intClient, intPort );
334  ]])],[
335  AC_DEFINE(MINIUPNPC_API_VERSION, 5, [miniupnpc 1.5 has API version 5])
336  upnp_version="1.5"])
337fi
338
339# ... and the results of our tests
340LIBS="$ac_save_LIBS"
341AC_MSG_RESULT([$upnp_version])
342AM_CONDITIONAL([BUILD_MINIUPNP],[test "x$upnp_version" = "xnone"])
343if test "x$upnp_version" = "xnone" ; then
344    LIBUPNP_CFLAGS="-I\$(top_srcdir)/third-party/"
345    LIBUPNP_LIBS="\$(top_builddir)/third-party/miniupnp/libminiupnp.a"
346    LIBUPNP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/miniupnp/libminiupnp.a"
347else
348    AC_DEFINE([SYSTEM_MINIUPNP])
349    LIBUPNP_CFLAGS=""
350    LIBUPNP_LIBS="-lminiupnpc"
351    LIBUPNP_LIBS_QT="-lminiupnpc"
352fi
353AC_SUBST(LIBUPNP_CFLAGS)
354AC_SUBST(LIBUPNP_LIBS)
355AC_SUBST(LIBUPNP_LIBS_QT)
356
357
358 
359
360dnl ----------------------------------------------------------------------------
361dnl
362dnl  Allow usage of system natpmp library
363
364LIBNATPMP_CFLAGS="-I\$(top_srcdir)/third-party/libnatpmp/"
365LIBNATPMP_LIBS="\$(top_builddir)/third-party/libnatpmp/libnatpmp.a"
366LIBNATPMP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/libnatpmp/libnatpmp.a"
367build_bundled_natpmp="yes"
368AC_ARG_ENABLE([external-natpmp],
369              AS_HELP_STRING([--enable-external-natpmp],[Use system external-natpmp]),
370              [want_external_natpmp=${enableval}],
371              [want_external_natpmp=no])
372if test "x$want_external_natpmp" != "xno" ; then
373        dnl Would be lovely if it had pkgconfig
374        LIBNATPMP_CFLAGS="" 
375        LIBNATPMP_LIBS="-lnatpmp"
376        LIBNATPMP_LIBS_QT="-lnatpmp"
377        build_bundled_natpmp="no"
378fi
379AM_CONDITIONAL([BUILD_NATPMP],[test "x$build_bundled_natpmp" = "xyes"])
380AC_SUBST(LIBNATPMP_CFLAGS)
381AC_SUBST(LIBNATPMP_LIBS)
382AC_SUBST(LIBNATPMP_LIBS_QT)
383
384
385dnl ----------------------------------------------------------------------------
386dnl
387dnl  detection for the GTK+ client
388
389AC_ARG_ENABLE([nls],
390              [AS_HELP_STRING([--enable-nls],[enable native language support])],,
391              [enable_nls=yes])
392PKG_CHECK_EXISTS([gtk+-3.0 >= $GTK_MINIMUM
393                  glib-2.0 >= $GLIB_MINIMUM
394                  gio-2.0 >= $GIO_MINIMUM,
395                  gmodule-2.0 >= $GLIB_MINIMUM
396                  gthread-2.0 >= $GLIB_MINIMUM],
397                 [have_gtk=yes],
398                 [have_gtk=no])
399AC_ARG_WITH([gtk], AS_HELP_STRING([--with-gtk],[with Gtk]),
400            [with_gtk=$withval],
401            [with_gtk=$have_gtk])
402AM_CONDITIONAL([BUILD_GTK],[test "x$with_gtk" = "xyes"])
403use_libappindicator=no
404if test "x$with_gtk" = "xyes" ; then
405
406    if test "x$enable_nls" = "xno" ; then
407        AC_MSG_ERROR("The gtk client cannot be built without nls support.  Try adding either --enable-nls or --without-gtk" )
408    fi
409
410    PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= $GTK_MINIMUM
411                              glib-2.0 >= $GLIB_MINIMUM
412                              gio-2.0 >= $GIO_MINIMUM,
413                              gmodule-2.0 >= $GLIB_MINIMUM
414                              gthread-2.0 >= $GLIB_MINIMUM])
415    PKG_CHECK_MODULES([LIBAPPINDICATOR],
416                      [appindicator3-0.1 >= $LIBAPPINDICATOR_MINIMUM],
417                      [have_libappindicator=yes],
418                      [have_libappindicator=no])
419    if test "x$have_libappindicator" = "xyes"; then
420        use_libappindicator=yes
421        AC_DEFINE([HAVE_LIBAPPINDICATOR], 1)
422    else
423        LIBAPPINDICATOR_CFLAGS=
424        LIBAPPINDICATOR_LIBS=
425    fi
426fi
427
428dnl This section is only used for internationalization.
429dnl If you don't need translations and this section gives you trouble --
430dnl such as if you're building for a headless system --
431dnl it's okay to tear this section out and re-build the configure script.
432dnl
433dnl Note to packagers: the bump to intltool 0.40 was made to fix
434dnl a "make check" failure on some systems.  if upgrading to 0.40 is
435dnl a problem and the old version was working fine for you,
436dnl it should be safe to re-edit 0.40 back down to 0.23
437
438use_nls=no
439if test "x$enable_nls" = "xyes" ; then
440    use_nls=yes
441    m4_ifdef([IT_PROG_INTLTOOL],
442             [IT_PROG_INTLTOOL([0.35.0],[no-xml])],
443             [AC_MSG_ERROR("--enable-nls requires intltool to be installed.")])
444    AC_CHECK_HEADERS([libintl.h])
445    GETTEXT_PACKAGE=transmission-gtk
446    AC_SUBST(GETTEXT_PACKAGE)
447    AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
448    AM_GLIB_GNU_GETTEXT
449    transmissionlocaledir='${prefix}/${DATADIRNAME}/locale'
450    AC_SUBST(transmissionlocaledir)
451fi
452AC_SUBST(INTLLIBS)
453
454
455dnl ----------------------------------------------------------------------------
456dnl
457dnl  platform-specific stuff.
458
459AC_CANONICAL_HOST
460have_darwin="no"
461have_msw="no"
462case $host_os in
463
464   *mingw32*)
465     have_msw="yes"
466     CXXFLAGS="$CXXFLAGS -mms-bitfields -mwin32 -mwindows"
467     CPPFLAGS="$CPPFLAGS -DWINVER=0x0600 -D_WIN32_WINNT=0x0600 -DWIN32_LEAN_AND_MEAN"
468     # CPPFLAGS="$CPPFLAGS -D__USE_MINGW_ANSI_STDIO=1 -D__STDC_FORMAT_MACROS=1"
469     LIBS="$LIBS -liphlpapi -lshell32 -lws2_32"
470     transmissionlocaledir="locale"
471     if test -z "$host_alias"; then
472       hostaliaswindres=
473     else
474       hostaliaswindres="$host_alias-windres";
475     fi
476     AC_CHECK_TOOL(WINDRES, windres)
477     ;;
478
479  *darwin*)
480    have_darwin="yes"
481    ;;
482
483esac
484
485AC_ARG_ENABLE([lightweight],
486              AS_HELP_STRING([--enable-lightweight],[optimize libtransmission for low-resource systems: smaller cache size, prefer unencrypted peer connections, etc.]),
487              [enable_lightweight=${enableval}],
488              [enable_lightweight="no"])
489if test "x$enable_lightweight" = "xyes" ; then
490  AC_DEFINE([TR_LIGHTWEIGHT],[1],[optimize libtransmission for low-resource systems])
491fi
492
493AC_ARG_ENABLE([cli],
494              [AS_HELP_STRING([--enable-cli],[build command-line client])],
495              [build_cli=${enableval}],
496              [build_cli="yes"])
497AM_CONDITIONAL([BUILD_CLI],[test "x$build_cli" = "xyes"])
498
499AC_ARG_ENABLE([mac],
500              [AS_HELP_STRING([--enable-mac],[build Mac client])],
501              [build_mac=${enableval}],
502              [build_mac=${have_darwin}])
503AM_CONDITIONAL([BUILD_MAC],[test "x$build_mac" = "xyes"])
504
505AC_ARG_ENABLE([daemon],
506              [AS_HELP_STRING([--enable-daemon],[build daemon])],
507              [build_daemon=${enableval}],
508              [build_daemon="yes"])
509AM_CONDITIONAL([BUILD_DAEMON],[test "x$build_daemon" = "xyes"])
510
511
512if test "x$build_mac" = "xyes" ; then
513   AC_DEFINE([BUILD_MAC_CLIENT], 1)
514    # Make sure the proper Mac SDK is installed
515    if test ! -d /Developer/SDKs/MacOSX10.5.sdk; then
516      cat << EOF
517You need to install the Mac OS X 10.5 SDK in order to build Transmission
518with --enable-mac:
519  Get your Xcode CD or package
520  Restart the install
521  When it gets to "Installation Type", select "Customize"
522  Select "Mac OS X 10.5 SDK" under "Cross Development"
523  Finish the install.
524EOF
525      exit 1
526    fi
527fi
528AM_CONDITIONAL(WIN32, test "x$have_msw" = "xyes")
529
530dnl ----------------------------------------------------------------------------
531dnl
532dnl  Generate the output
533
534AC_CONFIG_FILES([Makefile
535                 transmission-gtk.spec
536                 cli/Makefile
537                 daemon/Makefile
538                 extras/Makefile
539                 libtransmission/Makefile
540                 utils/Makefile
541                 third-party/Makefile
542                 third-party/dht/Makefile
543                 third-party/libutp/Makefile
544                 third-party/libnatpmp/Makefile
545                 third-party/miniupnp/Makefile
546                 macosx/Makefile
547                 gtk/Makefile
548                 gtk/icons/Makefile
549                 qt/config.pri
550                 web/Makefile
551                 web/images/Makefile
552                 web/style/Makefile
553                 web/style/jqueryui/Makefile
554                 web/style/jqueryui/images/Makefile
555                 web/style/transmission/Makefile
556                 web/style/transmission/images/Makefile
557                 web/style/transmission/images/buttons/Makefile
558                 web/javascript/Makefile
559                 web/javascript/jquery/Makefile
560                 po/Makefile.in])
561
562AC_OUTPUT
563
564echo "
565
566Configuration:
567
568   Source code location:                              ${srcdir}
569   Compiler:                                          ${CXX}
570
571   Build libtransmission:                             yes
572      * optimized for low-resource systems:           ${enable_lightweight}
573      * µTP enabled:                                  ${build_utp}
574
575   Build Command-Line client:                         ${build_cli}
576
577   Build GTK+ client:                                 ${with_gtk}
578      * libappindicator for an Ubuntu-style tray:     ${use_libappindicator}
579
580   Build Daemon:                                      ${build_daemon}
581
582   Build Mac client:                                  ${build_mac}
583
584"
Note: See TracBrowser for help on using the repository browser.