source: trunk/configure.ac @ 14408

Last change on this file since 14408 was 14408, checked in by mikedld, 7 years ago

#5805: Use bundled libutp by default if no system libutp found

File size: 18.3 KB
Line 
1dnl convention: -TR MAJOR MINOR MAINT STATUS - (each a single char)
2dnl STATUS: "X" for prerelease beta builds,
3dnl         "Z" for unsupported trunk builds,
4dnl         "0" for stable, supported releases
5dnl these should be the only two lines you need to change
6m4_define([user_agent_prefix],[2.84+])
7m4_define([peer_id_prefix],[-TR284Z-])
8
9AC_INIT([transmission],[user_agent_prefix],[http://trac.transmissionbt.com/newticket])
10AC_SUBST(USERAGENT_PREFIX,[user_agent_prefix])
11AC_SUBST(PEERID_PREFIX,[peer_id_prefix])
12
13m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
14
15AC_CONFIG_MACRO_DIR([m4])
16
17dnl AM_CONFIG_HEADER(config.h)
18AC_CONFIG_SRCDIR(libtransmission/transmission.h)
19AM_INIT_AUTOMAKE([1.9 tar-pax no-dist-gzip dist-xz])
20LT_INIT
21LT_LIB_M
22
23if test m4_substr(peer_id_prefix,6,1) = "0"; then
24  supported_build=yes
25  CPPFLAGS="$CPPFLAGS -DNDEBUG"
26else
27  supported_build=no
28  if test "x$GCC" = "xyes" ; then
29    CFLAGS="$CFLAGS -g -O0"
30    CXXFLAGS="$CXXFLAGS -g -O0"
31  fi
32fi
33AM_CONDITIONAL(TR_UNSTABLE, test "x$supported_build" = "xno")
34
35##
36##
37##   MANDATORY for everything
38##
39##
40CURL_MINIMUM=7.15.4
41AC_SUBST(CURL_MINIMUM)
42LIBEVENT_MINIMUM=2.0.10
43AC_SUBST(LIBEVENT_MINIMUM)
44OPENSSL_MINIMUM=0.9.4
45AC_SUBST(OPENSSL_MINIMUM)
46ZLIB_MINIMUM=1.2.3
47AC_SUBST(ZLIB_MINIMUM)
48
49##
50##
51##   MANDATORY for the GTK+ client
52##
53##
54
55GTK_MINIMUM=3.4.0
56AC_SUBST(GTK_MINIMUM)
57GLIB_MINIMUM=2.32.0
58AC_SUBST(GLIB_MINIMUM)
59GIO_MINIMUM=2.26.0
60AC_SUBST(GIO_MINIMUM)
61
62##
63##
64##   OPTIONAL for the GTK+ client
65##
66##
67
68# create the tray icon with AppIndicator
69LIBAPPINDICATOR_MINIMUM=0.4.90
70AC_SUBST(LIBAPPINDICATOR_MINIMUM)
71
72
73AC_PROG_CC
74AC_PROG_CXX
75AC_C_INLINE
76if test "x$GCC" = "xyes" ; then
77
78    CFLAGS="$CFLAGS -std=gnu99 -ggdb3 -Wall -W -Wpointer-arith -Wformat-security -Wundef -Wcast-align -Wstrict-prototypes -Wmissing-declarations -Wmissing-format-attribute -Wredundant-decls -Wnested-externs -Wunused-parameter -Wwrite-strings -Winline -Wfloat-equal"
79
80    dnl figure out gcc version
81    AC_MSG_CHECKING([gcc version])
82    GCC_VERSION=`$CC -dumpversion`
83    GCC_MAJOR=`echo $GCC_VERSION | cut -d . -f1`
84    GCC_MINOR=`echo $GCC_VERSION | cut -d . -f2`
85    GCC_VERSION_NUM=`(expr $GCC_MAJOR "*" 100 + $GCC_MINOR) 2>/dev/null`
86
87    AC_MSG_RESULT($GCC_VERSION)
88    if test $GCC_VERSION_NUM -ge 304; then
89        dnl these were added in 3.4
90        CFLAGS="$CFLAGS -Wextra -Wdeclaration-after-statement -Winit-self"
91    fi
92    if test $GCC_VERSION_NUM -ge 403; then
93        dnl these were added in 4.3
94        CFLAGS="$CFLAGS -Wvariadic-macros"
95    fi
96fi
97
98AC_HEADER_STDC
99AC_HEADER_TIME
100
101AC_CHECK_HEADERS([stdbool.h])
102AC_CHECK_FUNCS([iconv_open pread pwrite lrintf strlcpy daemon dirname basename canonicalize_file_name strcasecmp localtime_r fallocate64 posix_fallocate memmem strsep strtold syslog valloc getpagesize posix_memalign statvfs htonll ntohll mkdtemp])
103AC_PROG_INSTALL
104AC_PROG_MAKE_SET
105ACX_PTHREAD
106
107if test "x$ac_cv_func_strtold" != "xyes" ; then
108    CPPFLAGS="$CPPFLAGS -Dstrtold=strtod"
109fi
110
111AC_SEARCH_LIBS(cos, [m])
112AC_SEARCH_LIBS([socket], [socket net])
113AC_SEARCH_LIBS([gethostbyname], [nsl bind])
114AC_SEARCH_LIBS([quotacursor_skipidtype], [quota])
115PKG_CHECK_MODULES(OPENSSL, [openssl >= $OPENSSL_MINIMUM], , [CHECK_SSL()])
116PKG_CHECK_MODULES(LIBCURL, [libcurl >= $CURL_MINIMUM])
117PKG_CHECK_MODULES(LIBEVENT, [libevent >= $LIBEVENT_MINIMUM])
118PKG_CHECK_MODULES(ZLIB, [zlib >= $ZLIB_MINIMUM])
119
120AC_SYS_LARGEFILE
121AC_CHECK_FUNCS([lseek64])
122
123AC_FUNC_GETMNTENT
124
125dnl ----------------------------------------------------------------------------
126dnl
127dnl posix_fadvise
128
129dnl can posix_fadvise be used
130AC_CHECK_DECLS(posix_fadvise, [], [], [
131#define _XOPEN_SOURCE 600
132#include <fcntl.h>])
133AC_CHECK_FUNCS([posix_fadvise])
134
135
136dnl ----------------------------------------------------------------------------
137dnl
138dnl file monitoring for the daemon
139
140AC_CHECK_HEADER([sys/inotify.h],
141                [AC_CHECK_FUNC([inotify_init],[have_inotify="yes"],[have_inotify="no"])],
142                [have_inotify="no"])
143AC_ARG_WITH([inotify],
144            [AS_HELP_STRING([--with-inotify],[Enable inotify support (default=auto)])],
145            [want_inotify=${withval}],
146            [want_inotify=${have_inotify}])
147if test "x$want_inotify" = "xyes" ; then
148    if test "x$have_inotify" = "xyes"; then
149      AC_DEFINE([WITH_INOTIFY],[1])
150    else
151      AC_MSG_ERROR("inotify not found!")
152    fi
153fi
154
155AC_CHECK_HEADER([sys/event.h],
156                [AC_CHECK_FUNC([kqueue],[have_kqueue="yes"],[have_kqueue="no"])],
157                [have_kqueue="no"])
158AC_ARG_WITH([kqueue],
159            [AS_HELP_STRING([--with-kqueue],[Enable kqueue support (default=auto)])],
160            [want_kqueue=${withval}],
161            [want_kqueue=${have_kqueue}])
162if test "x$want_kqueue" = "xyes" ; then
163    if test "x$have_kqueue" = "xyes"; then
164      AC_DEFINE([WITH_KQUEUE],[1])
165    else
166      AC_MSG_ERROR("kqueue not found!")
167    fi
168fi
169
170AC_CHECK_HEADERS([sys/statvfs.h \
171                  xfs/xfs.h])
172
173
174dnl ----------------------------------------------------------------------------
175dnl
176dnl file monitoring for the daemon
177
178# Check whether to enable systemd startup notification.
179# This requires libsystemd-daemon.
180AC_ARG_WITH([systemd-daemon], AS_HELP_STRING([--with-systemd-daemon],
181            [Add support for systemd startup notification (default is autodetected)]),
182            [USE_SYSTEMD_DAEMON=$withval], [USE_SYSTEMD_DAEMON=auto])
183AS_IF([test "x$USE_SYSTEMD_DAEMON" != "xno"], [
184    PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
185        [AC_DEFINE(USE_SYSTEMD_DAEMON,1,[Use systemd startup notification])],
186        [AS_IF([test "x$USE_SYSTEMD_DAEMON" = "xyes"],
187            [AC_MSG_ERROR([systemd startup notification support requested, but libsystemd-daemon not found.])]
188        )]
189    )
190])
191
192
193dnl ----------------------------------------------------------------------------
194dnl
195dnl  dht
196
197DHT_CFLAGS="-I\$(top_srcdir)/third-party/dht"
198DHT_LIBS="\$(top_builddir)/third-party/dht/libdht.a"
199AC_SUBST(DHT_CFLAGS)
200AC_SUBST(DHT_LIBS)
201
202
203dnl ----------------------------------------------------------------------------
204dnl
205dnl  utp
206
207AC_CHECK_LIB([rt],
208             [clock_gettime],
209             [libutp_extra_libs="-lrt"],
210             [libutp_extra_libs=""])
211
212AC_MSG_CHECKING([µTP])
213build_utp="no"
214
215ac_save_LIBS="$LIBS"
216LIBS="-lutp"
217AC_LINK_IFELSE(
218  [AC_LANG_PROGRAM([#include <libutp/utp.h>],
219                   [struct UTPFunctionTable func;])],
220  [have_utp="yes"],
221  [have_utp="no"]
222)
223LIBS="$ac_save_LIBS"
224
225if test "x$have_utp" = "xyes" -o "x$CXX" != "x"; then
226    want_utp_default="yes"
227else
228    want_utp_default="no"
229fi
230
231AC_ARG_ENABLE([utp],
232              AS_HELP_STRING([--enable-utp],[build µTP support]),
233              [want_utp=${enableval}],
234              [want_utp=${want_utp_default}])
235if test "x$want_utp" = "xyes"; then
236    if test "x$have_utp" = "xyes"; then
237        dnl Would be lovely if it had pkgconfig
238        LIBUTP_CFLAGS=""
239        LIBUTP_LIBS="-lutp $libutp_extra_libs"
240        LIBUTP_LIBS_QT="-lutp $libutp_extra_libs"
241        AC_DEFINE([WITH_UTP],[1])
242        build_utp="system"
243    elif test "x$CXX" != "x"; then
244        LIBUTP_CFLAGS="-I\$(top_srcdir)/third-party/"
245        LIBUTP_LIBS="\$(top_builddir)/third-party/libutp/libutp.a"
246        LIBUTP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/libutp/libutp.a"
247        if test "x$libutp_extra_libs" != "x" ; then
248            LIBUTP_LIBS="$LIBUTP_LIBS $libutp_extra_libs"
249            LIBUTP_LIBS_QT="$LIBUTP_LIBS_QT $libutp_extra_libs"
250        fi
251        AC_DEFINE([WITH_UTP],[1])
252        build_utp="yes"
253    else
254      AC_MSG_ERROR("Unable to build uTP support -- C++ compiler not found")
255    fi
256fi
257AC_SUBST(LIBUTP_CFLAGS)
258AC_SUBST(LIBUTP_LIBS)
259AC_SUBST(LIBUTP_LIBS_QT)
260AM_CONDITIONAL([BUILD_UTP],[test "x$build_utp" = "xyes"])
261AC_MSG_RESULT([$build_utp])
262
263
264dnl
265dnl  look for preinstalled miniupnpc...
266dnl
267
268ac_save_LIBS="$LIBS"
269LIBS="-lminiupnpc"
270AC_MSG_CHECKING([system miniupnpc library])
271
272dnl See if ANY version of miniupnpc is installed
273AC_LINK_IFELSE(
274  [AC_LANG_PROGRAM([#include <miniupnpc/miniupnpc.h>],
275                   [struct UPNPDev dev;])],
276  [upnp_version="unknown"],
277  [upnp_version="none"]
278)
279
280dnl Let's hope it's 1.7 or higher, since it provides
281dnl MINIUPNPC_API_VERSION and we won't have to figure
282dnl it out on our own
283if test "x$upnp_version" = "xunknown" ; then
284  AC_RUN_IFELSE(
285    [AC_LANG_PROGRAM(
286      [#include <stdlib.h>
287       #include <miniupnpc/miniupnpc.h>],
288      [#ifdef MINIUPNPC_API_VERSION
289       return EXIT_SUCCESS;
290       #else
291       return EXIT_FAILURE;
292       #endif]
293    )],
294    [upnp_version=">= 1.7"]
295  )
296fi
297
298dnl Or maybe it's miniupnp 1.6
299if test "x$upnp_version" = "xunknown" ; then
300  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
301    #include <stdlib.h>
302    #include <errno.h>
303    #include <miniupnpc/miniupnpc.h>
304    #include <miniupnpc/upnpcommands.h>
305  ]], [[
306    struct UPNPDev * devlist;
307    struct UPNPUrls urls;
308    struct IGDdatas data;
309    char lanaddr[16];
310    char portStr[8];
311    char intPort[8];
312    char intClient[16];
313    upnpDiscover( 2000, NULL, NULL, 0, 0, &errno );
314    UPNP_GetValidIGD( devlist, &urls, &data, lanaddr, sizeof( lanaddr ) );
315    UPNP_GetSpecificPortMappingEntry( urls.controlURL, data.first.servicetype,
316                        portStr, "TCP", intClient, intPort, NULL, NULL, NULL );
317  ]])],[
318  AC_DEFINE(MINIUPNPC_API_VERSION, 8, [miniupnpc 1.6 has API version 8])
319  upnp_version="1.6"])
320fi
321
322dnl Or maybe it's miniupnp 1.5
323if test "x$upnp_version" = "xunknown" ; then
324  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
325    #include <stdlib.h>
326    #include <miniupnpc/miniupnpc.h>
327    #include <miniupnpc/upnpcommands.h>
328  ]], [[
329    struct UPNPDev * devlist;
330    struct UPNPUrls urls;
331    struct IGDdatas data;
332    char lanaddr[16];
333    char portStr[8];
334    char intPort[8];
335    char intClient[16];
336    upnpDiscover( 2000, NULL, NULL, 0 );
337    UPNP_GetValidIGD( devlist, &urls, &data, lanaddr, sizeof( lanaddr ) );
338    UPNP_GetSpecificPortMappingEntry( urls.controlURL, data.first.servicetype,
339                        portStr, "TCP", intClient, intPort );
340  ]])],[
341  AC_DEFINE(MINIUPNPC_API_VERSION, 5, [miniupnpc 1.5 has API version 5])
342  upnp_version="1.5"])
343fi
344
345# ... and the results of our tests
346LIBS="$ac_save_LIBS"
347AC_MSG_RESULT([$upnp_version])
348AM_CONDITIONAL([BUILD_MINIUPNP],[test "x$upnp_version" = "xnone"])
349if test "x$upnp_version" = "xnone" ; then
350    LIBUPNP_CFLAGS="-I\$(top_srcdir)/third-party/"
351    LIBUPNP_LIBS="\$(top_builddir)/third-party/miniupnp/libminiupnp.a"
352    LIBUPNP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/miniupnp/libminiupnp.a"
353else
354    AC_DEFINE([SYSTEM_MINIUPNP])
355    LIBUPNP_CFLAGS=""
356    LIBUPNP_LIBS="-lminiupnpc"
357    LIBUPNP_LIBS_QT="-lminiupnpc"
358fi
359AC_SUBST(LIBUPNP_CFLAGS)
360AC_SUBST(LIBUPNP_LIBS)
361AC_SUBST(LIBUPNP_LIBS_QT)
362
363
364 
365
366dnl ----------------------------------------------------------------------------
367dnl
368dnl  Allow usage of system natpmp library
369
370LIBNATPMP_CFLAGS="-I\$(top_srcdir)/third-party/libnatpmp/"
371LIBNATPMP_LIBS="\$(top_builddir)/third-party/libnatpmp/libnatpmp.a"
372LIBNATPMP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/libnatpmp/libnatpmp.a"
373build_bundled_natpmp="yes"
374AC_ARG_ENABLE([external-natpmp],
375              AS_HELP_STRING([--enable-external-natpmp],[Use system external-natpmp]),
376              [want_external_natpmp=${enableval}],
377              [want_external_natpmp=no])
378if test "x$want_external_natpmp" != "xno" ; then
379        dnl Would be lovely if it had pkgconfig
380        LIBNATPMP_CFLAGS="" 
381        LIBNATPMP_LIBS="-lnatpmp"
382        LIBNATPMP_LIBS_QT="-lnatpmp"
383        build_bundled_natpmp="no"
384fi
385AM_CONDITIONAL([BUILD_NATPMP],[test "x$build_bundled_natpmp" = "xyes"])
386AC_SUBST(LIBNATPMP_CFLAGS)
387AC_SUBST(LIBNATPMP_LIBS)
388AC_SUBST(LIBNATPMP_LIBS_QT)
389
390
391dnl ----------------------------------------------------------------------------
392dnl
393dnl  detection for the GTK+ client
394
395AC_ARG_ENABLE([nls],
396              [AS_HELP_STRING([--enable-nls],[enable native language support])],,
397              [enable_nls=yes])
398PKG_CHECK_EXISTS([gtk+-3.0 >= $GTK_MINIMUM
399                  glib-2.0 >= $GLIB_MINIMUM
400                  gio-2.0 >= $GIO_MINIMUM,
401                  gmodule-2.0 >= $GLIB_MINIMUM
402                  gthread-2.0 >= $GLIB_MINIMUM],
403                 [have_gtk=yes],
404                 [have_gtk=no])
405AC_ARG_WITH([gtk], AS_HELP_STRING([--with-gtk],[with Gtk]),
406            [with_gtk=$withval],
407            [with_gtk=$have_gtk])
408AM_CONDITIONAL([BUILD_GTK],[test "x$with_gtk" = "xyes"])
409use_libappindicator=no
410if test "x$with_gtk" = "xyes" ; then
411
412    if test "x$enable_nls" = "xno" ; then
413        AC_MSG_ERROR("The gtk client cannot be built without nls support.  Try adding either --enable-nls or --without-gtk" )
414    fi
415
416    PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= $GTK_MINIMUM
417                              glib-2.0 >= $GLIB_MINIMUM
418                              gio-2.0 >= $GIO_MINIMUM,
419                              gmodule-2.0 >= $GLIB_MINIMUM
420                              gthread-2.0 >= $GLIB_MINIMUM])
421    PKG_CHECK_MODULES([LIBAPPINDICATOR],
422                      [appindicator3-0.1 >= $LIBAPPINDICATOR_MINIMUM],
423                      [have_libappindicator=yes],
424                      [have_libappindicator=no])
425    if test "x$have_libappindicator" = "xyes"; then
426        use_libappindicator=yes
427        AC_DEFINE([HAVE_LIBAPPINDICATOR], 1)
428    else
429        LIBAPPINDICATOR_CFLAGS=
430        LIBAPPINDICATOR_LIBS=
431    fi
432fi
433
434dnl This section is only used for internationalization.
435dnl If you don't need translations and this section gives you trouble --
436dnl such as if you're building for a headless system --
437dnl it's okay to tear this section out and re-build the configure script.
438dnl
439dnl Note to packagers: the bump to intltool 0.40 was made to fix
440dnl a "make check" failure on some systems.  if upgrading to 0.40 is
441dnl a problem and the old version was working fine for you,
442dnl it should be safe to re-edit 0.40 back down to 0.23
443
444use_nls=no
445if test "x$enable_nls" = "xyes" ; then
446    use_nls=yes
447    m4_ifdef([IT_PROG_INTLTOOL],
448             [IT_PROG_INTLTOOL([0.35.0],[no-xml])],
449             [AC_MSG_ERROR("--enable-nls requires intltool to be installed.")])
450    AC_CHECK_HEADERS([libintl.h])
451    GETTEXT_PACKAGE=transmission-gtk
452    AC_SUBST(GETTEXT_PACKAGE)
453    AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
454    AM_GLIB_GNU_GETTEXT
455    transmissionlocaledir='${prefix}/${DATADIRNAME}/locale'
456    AC_SUBST(transmissionlocaledir)
457fi
458AC_SUBST(INTLLIBS)
459
460
461dnl ----------------------------------------------------------------------------
462dnl
463dnl  platform-specific stuff.
464
465AC_CANONICAL_HOST
466have_darwin="no"
467have_msw="no"
468case $host_os in
469
470   *mingw32*)
471     have_msw="yes"
472     CXXFLAGS="$CXXFLAGS -mms-bitfields -mwin32 -mwindows"
473     CPPFLAGS="$CPPFLAGS -DWINVER=0x0600 -D_WIN32_WINNT=0x0600 -DWIN32_LEAN_AND_MEAN"
474     # CPPFLAGS="$CPPFLAGS -D__USE_MINGW_ANSI_STDIO=1 -D__STDC_FORMAT_MACROS=1"
475     LIBS="$LIBS -liphlpapi -lshell32 -lws2_32"
476     transmissionlocaledir="locale"
477     if test -z "$host_alias"; then
478       hostaliaswindres=
479     else
480       hostaliaswindres="$host_alias-windres";
481     fi
482     AC_CHECK_TOOL(WINDRES, windres)
483     ;;
484
485  *darwin*)
486    have_darwin="yes"
487    ;;
488
489esac
490
491AC_ARG_ENABLE([lightweight],
492              AS_HELP_STRING([--enable-lightweight],[optimize libtransmission for low-resource systems: smaller cache size, prefer unencrypted peer connections, etc.]),
493              [enable_lightweight=${enableval}],
494              [enable_lightweight="no"])
495if test "x$enable_lightweight" = "xyes" ; then
496  AC_DEFINE([TR_LIGHTWEIGHT],[1],[optimize libtransmission for low-resource systems])
497fi
498
499AC_ARG_ENABLE([cli],
500              [AS_HELP_STRING([--enable-cli],[build command-line client])],
501              [build_cli=${enableval}],
502              [build_cli="yes"])
503AM_CONDITIONAL([BUILD_CLI],[test "x$build_cli" = "xyes"])
504
505AC_ARG_ENABLE([mac],
506              [AS_HELP_STRING([--enable-mac],[build Mac client])],
507              [build_mac=${enableval}],
508              [build_mac=${have_darwin}])
509AM_CONDITIONAL([BUILD_MAC],[test "x$build_mac" = "xyes"])
510
511AC_ARG_ENABLE([daemon],
512              [AS_HELP_STRING([--enable-daemon],[build daemon])],
513              [build_daemon=${enableval}],
514              [build_daemon="yes"])
515AM_CONDITIONAL([BUILD_DAEMON],[test "x$build_daemon" = "xyes"])
516
517
518if test "x$build_mac" = "xyes" ; then
519   AC_DEFINE([BUILD_MAC_CLIENT], 1)
520    # Make sure the proper Mac SDK is installed
521    if test ! -d /Developer/SDKs/MacOSX10.5.sdk; then
522      cat << EOF
523You need to install the Mac OS X 10.5 SDK in order to build Transmission
524with --enable-mac:
525  Get your Xcode CD or package
526  Restart the install
527  When it gets to "Installation Type", select "Customize"
528  Select "Mac OS X 10.5 SDK" under "Cross Development"
529  Finish the install.
530EOF
531      exit 1
532    fi
533fi
534AM_CONDITIONAL(WIN32, test "x$have_msw" = "xyes")
535
536dnl ----------------------------------------------------------------------------
537dnl
538dnl  Generate the output
539
540AC_CONFIG_FILES([Makefile
541                 transmission-gtk.spec
542                 cli/Makefile
543                 daemon/Makefile
544                 extras/Makefile
545                 libtransmission/Makefile
546                 utils/Makefile
547                 third-party/Makefile
548                 third-party/dht/Makefile
549                 third-party/libutp/Makefile
550                 third-party/libnatpmp/Makefile
551                 third-party/miniupnp/Makefile
552                 macosx/Makefile
553                 gtk/Makefile
554                 gtk/icons/Makefile
555                 qt/config.pri
556                 web/Makefile
557                 web/images/Makefile
558                 web/style/Makefile
559                 web/style/jqueryui/Makefile
560                 web/style/jqueryui/images/Makefile
561                 web/style/transmission/Makefile
562                 web/style/transmission/images/Makefile
563                 web/style/transmission/images/buttons/Makefile
564                 web/javascript/Makefile
565                 web/javascript/jquery/Makefile
566                 po/Makefile.in])
567
568AC_OUTPUT
569
570echo "
571
572Configuration:
573
574   Source code location:                              ${srcdir}
575   Compiler:                                          ${CXX}
576
577   Build libtransmission:                             yes
578      * optimized for low-resource systems:           ${enable_lightweight}
579      * µTP enabled:                                  ${build_utp}
580
581   Build Command-Line client:                         ${build_cli}
582
583   Build GTK+ client:                                 ${with_gtk}
584      * libappindicator for an Ubuntu-style tray:     ${use_libappindicator}
585
586   Build Daemon:                                      ${build_daemon}
587
588   Build Mac client:                                  ${build_mac}
589
590"
Note: See TracBrowser for help on using the repository browser.