source: trunk/configure.ac @ 14409

Last change on this file since 14409 was 14409, checked in by mikedld, 7 years ago

#5808: Don't embed path to DHT_LIBS in qtr.pro (patch by jbeich)

File size: 18.4 KB
Line 
1dnl convention: -TR MAJOR MINOR MAINT STATUS - (each a single char)
2dnl STATUS: "X" for prerelease beta builds,
3dnl         "Z" for unsupported trunk builds,
4dnl         "0" for stable, supported releases
5dnl these should be the only two lines you need to change
6m4_define([user_agent_prefix],[2.84+])
7m4_define([peer_id_prefix],[-TR284Z-])
8
9AC_INIT([transmission],[user_agent_prefix],[http://trac.transmissionbt.com/newticket])
10AC_SUBST(USERAGENT_PREFIX,[user_agent_prefix])
11AC_SUBST(PEERID_PREFIX,[peer_id_prefix])
12
13m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
14
15AC_CONFIG_MACRO_DIR([m4])
16
17dnl AM_CONFIG_HEADER(config.h)
18AC_CONFIG_SRCDIR(libtransmission/transmission.h)
19AM_INIT_AUTOMAKE([1.9 tar-pax no-dist-gzip dist-xz])
20LT_INIT
21LT_LIB_M
22
23if test m4_substr(peer_id_prefix,6,1) = "0"; then
24  supported_build=yes
25  CPPFLAGS="$CPPFLAGS -DNDEBUG"
26else
27  supported_build=no
28  if test "x$GCC" = "xyes" ; then
29    CFLAGS="$CFLAGS -g -O0"
30    CXXFLAGS="$CXXFLAGS -g -O0"
31  fi
32fi
33AM_CONDITIONAL(TR_UNSTABLE, test "x$supported_build" = "xno")
34
35##
36##
37##   MANDATORY for everything
38##
39##
40CURL_MINIMUM=7.15.4
41AC_SUBST(CURL_MINIMUM)
42LIBEVENT_MINIMUM=2.0.10
43AC_SUBST(LIBEVENT_MINIMUM)
44OPENSSL_MINIMUM=0.9.4
45AC_SUBST(OPENSSL_MINIMUM)
46ZLIB_MINIMUM=1.2.3
47AC_SUBST(ZLIB_MINIMUM)
48
49##
50##
51##   MANDATORY for the GTK+ client
52##
53##
54
55GTK_MINIMUM=3.4.0
56AC_SUBST(GTK_MINIMUM)
57GLIB_MINIMUM=2.32.0
58AC_SUBST(GLIB_MINIMUM)
59GIO_MINIMUM=2.26.0
60AC_SUBST(GIO_MINIMUM)
61
62##
63##
64##   OPTIONAL for the GTK+ client
65##
66##
67
68# create the tray icon with AppIndicator
69LIBAPPINDICATOR_MINIMUM=0.4.90
70AC_SUBST(LIBAPPINDICATOR_MINIMUM)
71
72
73AC_PROG_CC
74AC_PROG_CXX
75AC_C_INLINE
76if test "x$GCC" = "xyes" ; then
77
78    CFLAGS="$CFLAGS -std=gnu99 -ggdb3 -Wall -W -Wpointer-arith -Wformat-security -Wundef -Wcast-align -Wstrict-prototypes -Wmissing-declarations -Wmissing-format-attribute -Wredundant-decls -Wnested-externs -Wunused-parameter -Wwrite-strings -Winline -Wfloat-equal"
79
80    dnl figure out gcc version
81    AC_MSG_CHECKING([gcc version])
82    GCC_VERSION=`$CC -dumpversion`
83    GCC_MAJOR=`echo $GCC_VERSION | cut -d . -f1`
84    GCC_MINOR=`echo $GCC_VERSION | cut -d . -f2`
85    GCC_VERSION_NUM=`(expr $GCC_MAJOR "*" 100 + $GCC_MINOR) 2>/dev/null`
86
87    AC_MSG_RESULT($GCC_VERSION)
88    if test $GCC_VERSION_NUM -ge 304; then
89        dnl these were added in 3.4
90        CFLAGS="$CFLAGS -Wextra -Wdeclaration-after-statement -Winit-self"
91    fi
92    if test $GCC_VERSION_NUM -ge 403; then
93        dnl these were added in 4.3
94        CFLAGS="$CFLAGS -Wvariadic-macros"
95    fi
96fi
97
98AC_HEADER_STDC
99AC_HEADER_TIME
100
101AC_CHECK_HEADERS([stdbool.h])
102AC_CHECK_FUNCS([iconv_open pread pwrite lrintf strlcpy daemon dirname basename canonicalize_file_name strcasecmp localtime_r fallocate64 posix_fallocate memmem strsep strtold syslog valloc getpagesize posix_memalign statvfs htonll ntohll mkdtemp])
103AC_PROG_INSTALL
104AC_PROG_MAKE_SET
105ACX_PTHREAD
106
107if test "x$ac_cv_func_strtold" != "xyes" ; then
108    CPPFLAGS="$CPPFLAGS -Dstrtold=strtod"
109fi
110
111AC_SEARCH_LIBS(cos, [m])
112AC_SEARCH_LIBS([socket], [socket net])
113AC_SEARCH_LIBS([gethostbyname], [nsl bind])
114AC_SEARCH_LIBS([quotacursor_skipidtype], [quota])
115PKG_CHECK_MODULES(OPENSSL, [openssl >= $OPENSSL_MINIMUM], , [CHECK_SSL()])
116PKG_CHECK_MODULES(LIBCURL, [libcurl >= $CURL_MINIMUM])
117PKG_CHECK_MODULES(LIBEVENT, [libevent >= $LIBEVENT_MINIMUM])
118PKG_CHECK_MODULES(ZLIB, [zlib >= $ZLIB_MINIMUM])
119
120AC_SYS_LARGEFILE
121AC_CHECK_FUNCS([lseek64])
122
123AC_FUNC_GETMNTENT
124
125dnl ----------------------------------------------------------------------------
126dnl
127dnl posix_fadvise
128
129dnl can posix_fadvise be used
130AC_CHECK_DECLS(posix_fadvise, [], [], [
131#define _XOPEN_SOURCE 600
132#include <fcntl.h>])
133AC_CHECK_FUNCS([posix_fadvise])
134
135
136dnl ----------------------------------------------------------------------------
137dnl
138dnl file monitoring for the daemon
139
140AC_CHECK_HEADER([sys/inotify.h],
141                [AC_CHECK_FUNC([inotify_init],[have_inotify="yes"],[have_inotify="no"])],
142                [have_inotify="no"])
143AC_ARG_WITH([inotify],
144            [AS_HELP_STRING([--with-inotify],[Enable inotify support (default=auto)])],
145            [want_inotify=${withval}],
146            [want_inotify=${have_inotify}])
147if test "x$want_inotify" = "xyes" ; then
148    if test "x$have_inotify" = "xyes"; then
149      AC_DEFINE([WITH_INOTIFY],[1])
150    else
151      AC_MSG_ERROR("inotify not found!")
152    fi
153fi
154
155AC_CHECK_HEADER([sys/event.h],
156                [AC_CHECK_FUNC([kqueue],[have_kqueue="yes"],[have_kqueue="no"])],
157                [have_kqueue="no"])
158AC_ARG_WITH([kqueue],
159            [AS_HELP_STRING([--with-kqueue],[Enable kqueue support (default=auto)])],
160            [want_kqueue=${withval}],
161            [want_kqueue=${have_kqueue}])
162if test "x$want_kqueue" = "xyes" ; then
163    if test "x$have_kqueue" = "xyes"; then
164      AC_DEFINE([WITH_KQUEUE],[1])
165    else
166      AC_MSG_ERROR("kqueue not found!")
167    fi
168fi
169
170AC_CHECK_HEADERS([sys/statvfs.h \
171                  xfs/xfs.h])
172
173
174dnl ----------------------------------------------------------------------------
175dnl
176dnl file monitoring for the daemon
177
178# Check whether to enable systemd startup notification.
179# This requires libsystemd-daemon.
180AC_ARG_WITH([systemd-daemon], AS_HELP_STRING([--with-systemd-daemon],
181            [Add support for systemd startup notification (default is autodetected)]),
182            [USE_SYSTEMD_DAEMON=$withval], [USE_SYSTEMD_DAEMON=auto])
183AS_IF([test "x$USE_SYSTEMD_DAEMON" != "xno"], [
184    PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
185        [AC_DEFINE(USE_SYSTEMD_DAEMON,1,[Use systemd startup notification])],
186        [AS_IF([test "x$USE_SYSTEMD_DAEMON" = "xyes"],
187            [AC_MSG_ERROR([systemd startup notification support requested, but libsystemd-daemon not found.])]
188        )]
189    )
190])
191
192
193dnl ----------------------------------------------------------------------------
194dnl
195dnl  dht
196
197DHT_CFLAGS="-I\$(top_srcdir)/third-party/dht"
198DHT_LIBS="\$(top_builddir)/third-party/dht/libdht.a"
199DHT_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/dht/libdht.a"
200AC_SUBST(DHT_CFLAGS)
201AC_SUBST(DHT_LIBS)
202AC_SUBST(DHT_LIBS_QT)
203
204
205dnl ----------------------------------------------------------------------------
206dnl
207dnl  utp
208
209AC_CHECK_LIB([rt],
210             [clock_gettime],
211             [libutp_extra_libs="-lrt"],
212             [libutp_extra_libs=""])
213
214AC_MSG_CHECKING([µTP])
215build_utp="no"
216
217ac_save_LIBS="$LIBS"
218LIBS="-lutp"
219AC_LINK_IFELSE(
220  [AC_LANG_PROGRAM([#include <libutp/utp.h>],
221                   [struct UTPFunctionTable func;])],
222  [have_utp="yes"],
223  [have_utp="no"]
224)
225LIBS="$ac_save_LIBS"
226
227if test "x$have_utp" = "xyes" -o "x$CXX" != "x"; then
228    want_utp_default="yes"
229else
230    want_utp_default="no"
231fi
232
233AC_ARG_ENABLE([utp],
234              AS_HELP_STRING([--enable-utp],[build µTP support]),
235              [want_utp=${enableval}],
236              [want_utp=${want_utp_default}])
237if test "x$want_utp" = "xyes"; then
238    if test "x$have_utp" = "xyes"; then
239        dnl Would be lovely if it had pkgconfig
240        LIBUTP_CFLAGS=""
241        LIBUTP_LIBS="-lutp $libutp_extra_libs"
242        LIBUTP_LIBS_QT="-lutp $libutp_extra_libs"
243        AC_DEFINE([WITH_UTP],[1])
244        build_utp="system"
245    elif test "x$CXX" != "x"; then
246        LIBUTP_CFLAGS="-I\$(top_srcdir)/third-party/"
247        LIBUTP_LIBS="\$(top_builddir)/third-party/libutp/libutp.a"
248        LIBUTP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/libutp/libutp.a"
249        if test "x$libutp_extra_libs" != "x" ; then
250            LIBUTP_LIBS="$LIBUTP_LIBS $libutp_extra_libs"
251            LIBUTP_LIBS_QT="$LIBUTP_LIBS_QT $libutp_extra_libs"
252        fi
253        AC_DEFINE([WITH_UTP],[1])
254        build_utp="yes"
255    else
256      AC_MSG_ERROR("Unable to build uTP support -- C++ compiler not found")
257    fi
258fi
259AC_SUBST(LIBUTP_CFLAGS)
260AC_SUBST(LIBUTP_LIBS)
261AC_SUBST(LIBUTP_LIBS_QT)
262AM_CONDITIONAL([BUILD_UTP],[test "x$build_utp" = "xyes"])
263AC_MSG_RESULT([$build_utp])
264
265
266dnl
267dnl  look for preinstalled miniupnpc...
268dnl
269
270ac_save_LIBS="$LIBS"
271LIBS="-lminiupnpc"
272AC_MSG_CHECKING([system miniupnpc library])
273
274dnl See if ANY version of miniupnpc is installed
275AC_LINK_IFELSE(
276  [AC_LANG_PROGRAM([#include <miniupnpc/miniupnpc.h>],
277                   [struct UPNPDev dev;])],
278  [upnp_version="unknown"],
279  [upnp_version="none"]
280)
281
282dnl Let's hope it's 1.7 or higher, since it provides
283dnl MINIUPNPC_API_VERSION and we won't have to figure
284dnl it out on our own
285if test "x$upnp_version" = "xunknown" ; then
286  AC_RUN_IFELSE(
287    [AC_LANG_PROGRAM(
288      [#include <stdlib.h>
289       #include <miniupnpc/miniupnpc.h>],
290      [#ifdef MINIUPNPC_API_VERSION
291       return EXIT_SUCCESS;
292       #else
293       return EXIT_FAILURE;
294       #endif]
295    )],
296    [upnp_version=">= 1.7"]
297  )
298fi
299
300dnl Or maybe it's miniupnp 1.6
301if test "x$upnp_version" = "xunknown" ; then
302  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
303    #include <stdlib.h>
304    #include <errno.h>
305    #include <miniupnpc/miniupnpc.h>
306    #include <miniupnpc/upnpcommands.h>
307  ]], [[
308    struct UPNPDev * devlist;
309    struct UPNPUrls urls;
310    struct IGDdatas data;
311    char lanaddr[16];
312    char portStr[8];
313    char intPort[8];
314    char intClient[16];
315    upnpDiscover( 2000, NULL, NULL, 0, 0, &errno );
316    UPNP_GetValidIGD( devlist, &urls, &data, lanaddr, sizeof( lanaddr ) );
317    UPNP_GetSpecificPortMappingEntry( urls.controlURL, data.first.servicetype,
318                        portStr, "TCP", intClient, intPort, NULL, NULL, NULL );
319  ]])],[
320  AC_DEFINE(MINIUPNPC_API_VERSION, 8, [miniupnpc 1.6 has API version 8])
321  upnp_version="1.6"])
322fi
323
324dnl Or maybe it's miniupnp 1.5
325if test "x$upnp_version" = "xunknown" ; then
326  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
327    #include <stdlib.h>
328    #include <miniupnpc/miniupnpc.h>
329    #include <miniupnpc/upnpcommands.h>
330  ]], [[
331    struct UPNPDev * devlist;
332    struct UPNPUrls urls;
333    struct IGDdatas data;
334    char lanaddr[16];
335    char portStr[8];
336    char intPort[8];
337    char intClient[16];
338    upnpDiscover( 2000, NULL, NULL, 0 );
339    UPNP_GetValidIGD( devlist, &urls, &data, lanaddr, sizeof( lanaddr ) );
340    UPNP_GetSpecificPortMappingEntry( urls.controlURL, data.first.servicetype,
341                        portStr, "TCP", intClient, intPort );
342  ]])],[
343  AC_DEFINE(MINIUPNPC_API_VERSION, 5, [miniupnpc 1.5 has API version 5])
344  upnp_version="1.5"])
345fi
346
347# ... and the results of our tests
348LIBS="$ac_save_LIBS"
349AC_MSG_RESULT([$upnp_version])
350AM_CONDITIONAL([BUILD_MINIUPNP],[test "x$upnp_version" = "xnone"])
351if test "x$upnp_version" = "xnone" ; then
352    LIBUPNP_CFLAGS="-I\$(top_srcdir)/third-party/"
353    LIBUPNP_LIBS="\$(top_builddir)/third-party/miniupnp/libminiupnp.a"
354    LIBUPNP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/miniupnp/libminiupnp.a"
355else
356    AC_DEFINE([SYSTEM_MINIUPNP])
357    LIBUPNP_CFLAGS=""
358    LIBUPNP_LIBS="-lminiupnpc"
359    LIBUPNP_LIBS_QT="-lminiupnpc"
360fi
361AC_SUBST(LIBUPNP_CFLAGS)
362AC_SUBST(LIBUPNP_LIBS)
363AC_SUBST(LIBUPNP_LIBS_QT)
364
365
366 
367
368dnl ----------------------------------------------------------------------------
369dnl
370dnl  Allow usage of system natpmp library
371
372LIBNATPMP_CFLAGS="-I\$(top_srcdir)/third-party/libnatpmp/"
373LIBNATPMP_LIBS="\$(top_builddir)/third-party/libnatpmp/libnatpmp.a"
374LIBNATPMP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/libnatpmp/libnatpmp.a"
375build_bundled_natpmp="yes"
376AC_ARG_ENABLE([external-natpmp],
377              AS_HELP_STRING([--enable-external-natpmp],[Use system external-natpmp]),
378              [want_external_natpmp=${enableval}],
379              [want_external_natpmp=no])
380if test "x$want_external_natpmp" != "xno" ; then
381        dnl Would be lovely if it had pkgconfig
382        LIBNATPMP_CFLAGS="" 
383        LIBNATPMP_LIBS="-lnatpmp"
384        LIBNATPMP_LIBS_QT="-lnatpmp"
385        build_bundled_natpmp="no"
386fi
387AM_CONDITIONAL([BUILD_NATPMP],[test "x$build_bundled_natpmp" = "xyes"])
388AC_SUBST(LIBNATPMP_CFLAGS)
389AC_SUBST(LIBNATPMP_LIBS)
390AC_SUBST(LIBNATPMP_LIBS_QT)
391
392
393dnl ----------------------------------------------------------------------------
394dnl
395dnl  detection for the GTK+ client
396
397AC_ARG_ENABLE([nls],
398              [AS_HELP_STRING([--enable-nls],[enable native language support])],,
399              [enable_nls=yes])
400PKG_CHECK_EXISTS([gtk+-3.0 >= $GTK_MINIMUM
401                  glib-2.0 >= $GLIB_MINIMUM
402                  gio-2.0 >= $GIO_MINIMUM,
403                  gmodule-2.0 >= $GLIB_MINIMUM
404                  gthread-2.0 >= $GLIB_MINIMUM],
405                 [have_gtk=yes],
406                 [have_gtk=no])
407AC_ARG_WITH([gtk], AS_HELP_STRING([--with-gtk],[with Gtk]),
408            [with_gtk=$withval],
409            [with_gtk=$have_gtk])
410AM_CONDITIONAL([BUILD_GTK],[test "x$with_gtk" = "xyes"])
411use_libappindicator=no
412if test "x$with_gtk" = "xyes" ; then
413
414    if test "x$enable_nls" = "xno" ; then
415        AC_MSG_ERROR("The gtk client cannot be built without nls support.  Try adding either --enable-nls or --without-gtk" )
416    fi
417
418    PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= $GTK_MINIMUM
419                              glib-2.0 >= $GLIB_MINIMUM
420                              gio-2.0 >= $GIO_MINIMUM,
421                              gmodule-2.0 >= $GLIB_MINIMUM
422                              gthread-2.0 >= $GLIB_MINIMUM])
423    PKG_CHECK_MODULES([LIBAPPINDICATOR],
424                      [appindicator3-0.1 >= $LIBAPPINDICATOR_MINIMUM],
425                      [have_libappindicator=yes],
426                      [have_libappindicator=no])
427    if test "x$have_libappindicator" = "xyes"; then
428        use_libappindicator=yes
429        AC_DEFINE([HAVE_LIBAPPINDICATOR], 1)
430    else
431        LIBAPPINDICATOR_CFLAGS=
432        LIBAPPINDICATOR_LIBS=
433    fi
434fi
435
436dnl This section is only used for internationalization.
437dnl If you don't need translations and this section gives you trouble --
438dnl such as if you're building for a headless system --
439dnl it's okay to tear this section out and re-build the configure script.
440dnl
441dnl Note to packagers: the bump to intltool 0.40 was made to fix
442dnl a "make check" failure on some systems.  if upgrading to 0.40 is
443dnl a problem and the old version was working fine for you,
444dnl it should be safe to re-edit 0.40 back down to 0.23
445
446use_nls=no
447if test "x$enable_nls" = "xyes" ; then
448    use_nls=yes
449    m4_ifdef([IT_PROG_INTLTOOL],
450             [IT_PROG_INTLTOOL([0.35.0],[no-xml])],
451             [AC_MSG_ERROR("--enable-nls requires intltool to be installed.")])
452    AC_CHECK_HEADERS([libintl.h])
453    GETTEXT_PACKAGE=transmission-gtk
454    AC_SUBST(GETTEXT_PACKAGE)
455    AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
456    AM_GLIB_GNU_GETTEXT
457    transmissionlocaledir='${prefix}/${DATADIRNAME}/locale'
458    AC_SUBST(transmissionlocaledir)
459fi
460AC_SUBST(INTLLIBS)
461
462
463dnl ----------------------------------------------------------------------------
464dnl
465dnl  platform-specific stuff.
466
467AC_CANONICAL_HOST
468have_darwin="no"
469have_msw="no"
470case $host_os in
471
472   *mingw32*)
473     have_msw="yes"
474     CXXFLAGS="$CXXFLAGS -mms-bitfields -mwin32 -mwindows"
475     CPPFLAGS="$CPPFLAGS -DWINVER=0x0600 -D_WIN32_WINNT=0x0600 -DWIN32_LEAN_AND_MEAN"
476     # CPPFLAGS="$CPPFLAGS -D__USE_MINGW_ANSI_STDIO=1 -D__STDC_FORMAT_MACROS=1"
477     LIBS="$LIBS -liphlpapi -lshell32 -lws2_32"
478     transmissionlocaledir="locale"
479     if test -z "$host_alias"; then
480       hostaliaswindres=
481     else
482       hostaliaswindres="$host_alias-windres";
483     fi
484     AC_CHECK_TOOL(WINDRES, windres)
485     ;;
486
487  *darwin*)
488    have_darwin="yes"
489    ;;
490
491esac
492
493AC_ARG_ENABLE([lightweight],
494              AS_HELP_STRING([--enable-lightweight],[optimize libtransmission for low-resource systems: smaller cache size, prefer unencrypted peer connections, etc.]),
495              [enable_lightweight=${enableval}],
496              [enable_lightweight="no"])
497if test "x$enable_lightweight" = "xyes" ; then
498  AC_DEFINE([TR_LIGHTWEIGHT],[1],[optimize libtransmission for low-resource systems])
499fi
500
501AC_ARG_ENABLE([cli],
502              [AS_HELP_STRING([--enable-cli],[build command-line client])],
503              [build_cli=${enableval}],
504              [build_cli="yes"])
505AM_CONDITIONAL([BUILD_CLI],[test "x$build_cli" = "xyes"])
506
507AC_ARG_ENABLE([mac],
508              [AS_HELP_STRING([--enable-mac],[build Mac client])],
509              [build_mac=${enableval}],
510              [build_mac=${have_darwin}])
511AM_CONDITIONAL([BUILD_MAC],[test "x$build_mac" = "xyes"])
512
513AC_ARG_ENABLE([daemon],
514              [AS_HELP_STRING([--enable-daemon],[build daemon])],
515              [build_daemon=${enableval}],
516              [build_daemon="yes"])
517AM_CONDITIONAL([BUILD_DAEMON],[test "x$build_daemon" = "xyes"])
518
519
520if test "x$build_mac" = "xyes" ; then
521   AC_DEFINE([BUILD_MAC_CLIENT], 1)
522    # Make sure the proper Mac SDK is installed
523    if test ! -d /Developer/SDKs/MacOSX10.5.sdk; then
524      cat << EOF
525You need to install the Mac OS X 10.5 SDK in order to build Transmission
526with --enable-mac:
527  Get your Xcode CD or package
528  Restart the install
529  When it gets to "Installation Type", select "Customize"
530  Select "Mac OS X 10.5 SDK" under "Cross Development"
531  Finish the install.
532EOF
533      exit 1
534    fi
535fi
536AM_CONDITIONAL(WIN32, test "x$have_msw" = "xyes")
537
538dnl ----------------------------------------------------------------------------
539dnl
540dnl  Generate the output
541
542AC_CONFIG_FILES([Makefile
543                 transmission-gtk.spec
544                 cli/Makefile
545                 daemon/Makefile
546                 extras/Makefile
547                 libtransmission/Makefile
548                 utils/Makefile
549                 third-party/Makefile
550                 third-party/dht/Makefile
551                 third-party/libutp/Makefile
552                 third-party/libnatpmp/Makefile
553                 third-party/miniupnp/Makefile
554                 macosx/Makefile
555                 gtk/Makefile
556                 gtk/icons/Makefile
557                 qt/config.pri
558                 web/Makefile
559                 web/images/Makefile
560                 web/style/Makefile
561                 web/style/jqueryui/Makefile
562                 web/style/jqueryui/images/Makefile
563                 web/style/transmission/Makefile
564                 web/style/transmission/images/Makefile
565                 web/style/transmission/images/buttons/Makefile
566                 web/javascript/Makefile
567                 web/javascript/jquery/Makefile
568                 po/Makefile.in])
569
570AC_OUTPUT
571
572echo "
573
574Configuration:
575
576   Source code location:                              ${srcdir}
577   Compiler:                                          ${CXX}
578
579   Build libtransmission:                             yes
580      * optimized for low-resource systems:           ${enable_lightweight}
581      * µTP enabled:                                  ${build_utp}
582
583   Build Command-Line client:                         ${build_cli}
584
585   Build GTK+ client:                                 ${with_gtk}
586      * libappindicator for an Ubuntu-style tray:     ${use_libappindicator}
587
588   Build Daemon:                                      ${build_daemon}
589
590   Build Mac client:                                  ${build_mac}
591
592"
Note: See TracBrowser for help on using the repository browser.