source: trunk/configure.ac @ 14410

Last change on this file since 14410 was 14410, checked in by mikedld, 7 years ago

#5809: Allow building against system dht library (patch by jbeich)

File size: 18.9 KB
Line 
1dnl convention: -TR MAJOR MINOR MAINT STATUS - (each a single char)
2dnl STATUS: "X" for prerelease beta builds,
3dnl         "Z" for unsupported trunk builds,
4dnl         "0" for stable, supported releases
5dnl these should be the only two lines you need to change
6m4_define([user_agent_prefix],[2.84+])
7m4_define([peer_id_prefix],[-TR284Z-])
8
9AC_INIT([transmission],[user_agent_prefix],[http://trac.transmissionbt.com/newticket])
10AC_SUBST(USERAGENT_PREFIX,[user_agent_prefix])
11AC_SUBST(PEERID_PREFIX,[peer_id_prefix])
12
13m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
14
15AC_CONFIG_MACRO_DIR([m4])
16
17dnl AM_CONFIG_HEADER(config.h)
18AC_CONFIG_SRCDIR(libtransmission/transmission.h)
19AM_INIT_AUTOMAKE([1.9 tar-pax no-dist-gzip dist-xz])
20LT_INIT
21LT_LIB_M
22
23if test m4_substr(peer_id_prefix,6,1) = "0"; then
24  supported_build=yes
25  CPPFLAGS="$CPPFLAGS -DNDEBUG"
26else
27  supported_build=no
28  if test "x$GCC" = "xyes" ; then
29    CFLAGS="$CFLAGS -g -O0"
30    CXXFLAGS="$CXXFLAGS -g -O0"
31  fi
32fi
33AM_CONDITIONAL(TR_UNSTABLE, test "x$supported_build" = "xno")
34
35##
36##
37##   MANDATORY for everything
38##
39##
40CURL_MINIMUM=7.15.4
41AC_SUBST(CURL_MINIMUM)
42LIBEVENT_MINIMUM=2.0.10
43AC_SUBST(LIBEVENT_MINIMUM)
44OPENSSL_MINIMUM=0.9.4
45AC_SUBST(OPENSSL_MINIMUM)
46ZLIB_MINIMUM=1.2.3
47AC_SUBST(ZLIB_MINIMUM)
48
49##
50##
51##   MANDATORY for the GTK+ client
52##
53##
54
55GTK_MINIMUM=3.4.0
56AC_SUBST(GTK_MINIMUM)
57GLIB_MINIMUM=2.32.0
58AC_SUBST(GLIB_MINIMUM)
59GIO_MINIMUM=2.26.0
60AC_SUBST(GIO_MINIMUM)
61
62##
63##
64##   OPTIONAL for the GTK+ client
65##
66##
67
68# create the tray icon with AppIndicator
69LIBAPPINDICATOR_MINIMUM=0.4.90
70AC_SUBST(LIBAPPINDICATOR_MINIMUM)
71
72
73AC_PROG_CC
74AC_PROG_CXX
75AC_C_INLINE
76if test "x$GCC" = "xyes" ; then
77
78    CFLAGS="$CFLAGS -std=gnu99 -ggdb3 -Wall -W -Wpointer-arith -Wformat-security -Wundef -Wcast-align -Wstrict-prototypes -Wmissing-declarations -Wmissing-format-attribute -Wredundant-decls -Wnested-externs -Wunused-parameter -Wwrite-strings -Winline -Wfloat-equal"
79
80    dnl figure out gcc version
81    AC_MSG_CHECKING([gcc version])
82    GCC_VERSION=`$CC -dumpversion`
83    GCC_MAJOR=`echo $GCC_VERSION | cut -d . -f1`
84    GCC_MINOR=`echo $GCC_VERSION | cut -d . -f2`
85    GCC_VERSION_NUM=`(expr $GCC_MAJOR "*" 100 + $GCC_MINOR) 2>/dev/null`
86
87    AC_MSG_RESULT($GCC_VERSION)
88    if test $GCC_VERSION_NUM -ge 304; then
89        dnl these were added in 3.4
90        CFLAGS="$CFLAGS -Wextra -Wdeclaration-after-statement -Winit-self"
91    fi
92    if test $GCC_VERSION_NUM -ge 403; then
93        dnl these were added in 4.3
94        CFLAGS="$CFLAGS -Wvariadic-macros"
95    fi
96fi
97
98AC_HEADER_STDC
99AC_HEADER_TIME
100
101AC_CHECK_HEADERS([stdbool.h])
102AC_CHECK_FUNCS([iconv_open pread pwrite lrintf strlcpy daemon dirname basename canonicalize_file_name strcasecmp localtime_r fallocate64 posix_fallocate memmem strsep strtold syslog valloc getpagesize posix_memalign statvfs htonll ntohll mkdtemp])
103AC_PROG_INSTALL
104AC_PROG_MAKE_SET
105ACX_PTHREAD
106
107if test "x$ac_cv_func_strtold" != "xyes" ; then
108    CPPFLAGS="$CPPFLAGS -Dstrtold=strtod"
109fi
110
111AC_SEARCH_LIBS(cos, [m])
112AC_SEARCH_LIBS([socket], [socket net])
113AC_SEARCH_LIBS([gethostbyname], [nsl bind])
114AC_SEARCH_LIBS([quotacursor_skipidtype], [quota])
115PKG_CHECK_MODULES(OPENSSL, [openssl >= $OPENSSL_MINIMUM], , [CHECK_SSL()])
116PKG_CHECK_MODULES(LIBCURL, [libcurl >= $CURL_MINIMUM])
117PKG_CHECK_MODULES(LIBEVENT, [libevent >= $LIBEVENT_MINIMUM])
118PKG_CHECK_MODULES(ZLIB, [zlib >= $ZLIB_MINIMUM])
119
120AC_SYS_LARGEFILE
121AC_CHECK_FUNCS([lseek64])
122
123AC_FUNC_GETMNTENT
124
125dnl ----------------------------------------------------------------------------
126dnl
127dnl posix_fadvise
128
129dnl can posix_fadvise be used
130AC_CHECK_DECLS(posix_fadvise, [], [], [
131#define _XOPEN_SOURCE 600
132#include <fcntl.h>])
133AC_CHECK_FUNCS([posix_fadvise])
134
135
136dnl ----------------------------------------------------------------------------
137dnl
138dnl file monitoring for the daemon
139
140AC_CHECK_HEADER([sys/inotify.h],
141                [AC_CHECK_FUNC([inotify_init],[have_inotify="yes"],[have_inotify="no"])],
142                [have_inotify="no"])
143AC_ARG_WITH([inotify],
144            [AS_HELP_STRING([--with-inotify],[Enable inotify support (default=auto)])],
145            [want_inotify=${withval}],
146            [want_inotify=${have_inotify}])
147if test "x$want_inotify" = "xyes" ; then
148    if test "x$have_inotify" = "xyes"; then
149      AC_DEFINE([WITH_INOTIFY],[1])
150    else
151      AC_MSG_ERROR("inotify not found!")
152    fi
153fi
154
155AC_CHECK_HEADER([sys/event.h],
156                [AC_CHECK_FUNC([kqueue],[have_kqueue="yes"],[have_kqueue="no"])],
157                [have_kqueue="no"])
158AC_ARG_WITH([kqueue],
159            [AS_HELP_STRING([--with-kqueue],[Enable kqueue support (default=auto)])],
160            [want_kqueue=${withval}],
161            [want_kqueue=${have_kqueue}])
162if test "x$want_kqueue" = "xyes" ; then
163    if test "x$have_kqueue" = "xyes"; then
164      AC_DEFINE([WITH_KQUEUE],[1])
165    else
166      AC_MSG_ERROR("kqueue not found!")
167    fi
168fi
169
170AC_CHECK_HEADERS([sys/statvfs.h \
171                  xfs/xfs.h])
172
173
174dnl ----------------------------------------------------------------------------
175dnl
176dnl file monitoring for the daemon
177
178# Check whether to enable systemd startup notification.
179# This requires libsystemd-daemon.
180AC_ARG_WITH([systemd-daemon], AS_HELP_STRING([--with-systemd-daemon],
181            [Add support for systemd startup notification (default is autodetected)]),
182            [USE_SYSTEMD_DAEMON=$withval], [USE_SYSTEMD_DAEMON=auto])
183AS_IF([test "x$USE_SYSTEMD_DAEMON" != "xno"], [
184    PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
185        [AC_DEFINE(USE_SYSTEMD_DAEMON,1,[Use systemd startup notification])],
186        [AS_IF([test "x$USE_SYSTEMD_DAEMON" = "xyes"],
187            [AC_MSG_ERROR([systemd startup notification support requested, but libsystemd-daemon not found.])]
188        )]
189    )
190])
191
192
193dnl ----------------------------------------------------------------------------
194dnl
195dnl  dht
196
197DHT_CFLAGS="-I\$(top_srcdir)/third-party/dht"
198DHT_LIBS="\$(top_builddir)/third-party/dht/libdht.a"
199DHT_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/dht/libdht.a"
200build_bundled_dht="yes"
201AC_ARG_ENABLE([external-dht],
202              AS_HELP_STRING([--enable-external-dht],[Use system external-dht]),
203              [want_external_dht=${enableval}],
204              [want_external_dht=no])
205if test "x$want_external_dht" != "xno" ; then
206       dnl Would be lovely if it had pkgconfig
207       DHT_CFLAGS=""
208       DHT_LIBS="-ldht"
209       DHT_LIBS_QT="-ldht"
210       build_bundled_dht="no"
211fi
212
213AM_CONDITIONAL([BUILD_DHT],[test "x$build_bundled_dht" = "xyes"])
214AC_SUBST(DHT_CFLAGS)
215AC_SUBST(DHT_LIBS)
216AC_SUBST(DHT_LIBS_QT)
217
218
219dnl ----------------------------------------------------------------------------
220dnl
221dnl  utp
222
223AC_CHECK_LIB([rt],
224             [clock_gettime],
225             [libutp_extra_libs="-lrt"],
226             [libutp_extra_libs=""])
227
228AC_MSG_CHECKING([µTP])
229build_utp="no"
230
231ac_save_LIBS="$LIBS"
232LIBS="-lutp"
233AC_LINK_IFELSE(
234  [AC_LANG_PROGRAM([#include <libutp/utp.h>],
235                   [struct UTPFunctionTable func;])],
236  [have_utp="yes"],
237  [have_utp="no"]
238)
239LIBS="$ac_save_LIBS"
240
241if test "x$have_utp" = "xyes" -o "x$CXX" != "x"; then
242    want_utp_default="yes"
243else
244    want_utp_default="no"
245fi
246
247AC_ARG_ENABLE([utp],
248              AS_HELP_STRING([--enable-utp],[build µTP support]),
249              [want_utp=${enableval}],
250              [want_utp=${want_utp_default}])
251if test "x$want_utp" = "xyes"; then
252    if test "x$have_utp" = "xyes"; then
253        dnl Would be lovely if it had pkgconfig
254        LIBUTP_CFLAGS=""
255        LIBUTP_LIBS="-lutp $libutp_extra_libs"
256        LIBUTP_LIBS_QT="-lutp $libutp_extra_libs"
257        AC_DEFINE([WITH_UTP],[1])
258        build_utp="system"
259    elif test "x$CXX" != "x"; then
260        LIBUTP_CFLAGS="-I\$(top_srcdir)/third-party/"
261        LIBUTP_LIBS="\$(top_builddir)/third-party/libutp/libutp.a"
262        LIBUTP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/libutp/libutp.a"
263        if test "x$libutp_extra_libs" != "x" ; then
264            LIBUTP_LIBS="$LIBUTP_LIBS $libutp_extra_libs"
265            LIBUTP_LIBS_QT="$LIBUTP_LIBS_QT $libutp_extra_libs"
266        fi
267        AC_DEFINE([WITH_UTP],[1])
268        build_utp="yes"
269    else
270      AC_MSG_ERROR("Unable to build uTP support -- C++ compiler not found")
271    fi
272fi
273AC_SUBST(LIBUTP_CFLAGS)
274AC_SUBST(LIBUTP_LIBS)
275AC_SUBST(LIBUTP_LIBS_QT)
276AM_CONDITIONAL([BUILD_UTP],[test "x$build_utp" = "xyes"])
277AC_MSG_RESULT([$build_utp])
278
279
280dnl
281dnl  look for preinstalled miniupnpc...
282dnl
283
284ac_save_LIBS="$LIBS"
285LIBS="-lminiupnpc"
286AC_MSG_CHECKING([system miniupnpc library])
287
288dnl See if ANY version of miniupnpc is installed
289AC_LINK_IFELSE(
290  [AC_LANG_PROGRAM([#include <miniupnpc/miniupnpc.h>],
291                   [struct UPNPDev dev;])],
292  [upnp_version="unknown"],
293  [upnp_version="none"]
294)
295
296dnl Let's hope it's 1.7 or higher, since it provides
297dnl MINIUPNPC_API_VERSION and we won't have to figure
298dnl it out on our own
299if test "x$upnp_version" = "xunknown" ; then
300  AC_RUN_IFELSE(
301    [AC_LANG_PROGRAM(
302      [#include <stdlib.h>
303       #include <miniupnpc/miniupnpc.h>],
304      [#ifdef MINIUPNPC_API_VERSION
305       return EXIT_SUCCESS;
306       #else
307       return EXIT_FAILURE;
308       #endif]
309    )],
310    [upnp_version=">= 1.7"]
311  )
312fi
313
314dnl Or maybe it's miniupnp 1.6
315if test "x$upnp_version" = "xunknown" ; then
316  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
317    #include <stdlib.h>
318    #include <errno.h>
319    #include <miniupnpc/miniupnpc.h>
320    #include <miniupnpc/upnpcommands.h>
321  ]], [[
322    struct UPNPDev * devlist;
323    struct UPNPUrls urls;
324    struct IGDdatas data;
325    char lanaddr[16];
326    char portStr[8];
327    char intPort[8];
328    char intClient[16];
329    upnpDiscover( 2000, NULL, NULL, 0, 0, &errno );
330    UPNP_GetValidIGD( devlist, &urls, &data, lanaddr, sizeof( lanaddr ) );
331    UPNP_GetSpecificPortMappingEntry( urls.controlURL, data.first.servicetype,
332                        portStr, "TCP", intClient, intPort, NULL, NULL, NULL );
333  ]])],[
334  AC_DEFINE(MINIUPNPC_API_VERSION, 8, [miniupnpc 1.6 has API version 8])
335  upnp_version="1.6"])
336fi
337
338dnl Or maybe it's miniupnp 1.5
339if test "x$upnp_version" = "xunknown" ; then
340  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
341    #include <stdlib.h>
342    #include <miniupnpc/miniupnpc.h>
343    #include <miniupnpc/upnpcommands.h>
344  ]], [[
345    struct UPNPDev * devlist;
346    struct UPNPUrls urls;
347    struct IGDdatas data;
348    char lanaddr[16];
349    char portStr[8];
350    char intPort[8];
351    char intClient[16];
352    upnpDiscover( 2000, NULL, NULL, 0 );
353    UPNP_GetValidIGD( devlist, &urls, &data, lanaddr, sizeof( lanaddr ) );
354    UPNP_GetSpecificPortMappingEntry( urls.controlURL, data.first.servicetype,
355                        portStr, "TCP", intClient, intPort );
356  ]])],[
357  AC_DEFINE(MINIUPNPC_API_VERSION, 5, [miniupnpc 1.5 has API version 5])
358  upnp_version="1.5"])
359fi
360
361# ... and the results of our tests
362LIBS="$ac_save_LIBS"
363AC_MSG_RESULT([$upnp_version])
364AM_CONDITIONAL([BUILD_MINIUPNP],[test "x$upnp_version" = "xnone"])
365if test "x$upnp_version" = "xnone" ; then
366    LIBUPNP_CFLAGS="-I\$(top_srcdir)/third-party/"
367    LIBUPNP_LIBS="\$(top_builddir)/third-party/miniupnp/libminiupnp.a"
368    LIBUPNP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/miniupnp/libminiupnp.a"
369else
370    AC_DEFINE([SYSTEM_MINIUPNP])
371    LIBUPNP_CFLAGS=""
372    LIBUPNP_LIBS="-lminiupnpc"
373    LIBUPNP_LIBS_QT="-lminiupnpc"
374fi
375AC_SUBST(LIBUPNP_CFLAGS)
376AC_SUBST(LIBUPNP_LIBS)
377AC_SUBST(LIBUPNP_LIBS_QT)
378
379
380 
381
382dnl ----------------------------------------------------------------------------
383dnl
384dnl  Allow usage of system natpmp library
385
386LIBNATPMP_CFLAGS="-I\$(top_srcdir)/third-party/libnatpmp/"
387LIBNATPMP_LIBS="\$(top_builddir)/third-party/libnatpmp/libnatpmp.a"
388LIBNATPMP_LIBS_QT="\$\${TRANSMISSION_TOP}/third-party/libnatpmp/libnatpmp.a"
389build_bundled_natpmp="yes"
390AC_ARG_ENABLE([external-natpmp],
391              AS_HELP_STRING([--enable-external-natpmp],[Use system external-natpmp]),
392              [want_external_natpmp=${enableval}],
393              [want_external_natpmp=no])
394if test "x$want_external_natpmp" != "xno" ; then
395        dnl Would be lovely if it had pkgconfig
396        LIBNATPMP_CFLAGS="" 
397        LIBNATPMP_LIBS="-lnatpmp"
398        LIBNATPMP_LIBS_QT="-lnatpmp"
399        build_bundled_natpmp="no"
400fi
401AM_CONDITIONAL([BUILD_NATPMP],[test "x$build_bundled_natpmp" = "xyes"])
402AC_SUBST(LIBNATPMP_CFLAGS)
403AC_SUBST(LIBNATPMP_LIBS)
404AC_SUBST(LIBNATPMP_LIBS_QT)
405
406
407dnl ----------------------------------------------------------------------------
408dnl
409dnl  detection for the GTK+ client
410
411AC_ARG_ENABLE([nls],
412              [AS_HELP_STRING([--enable-nls],[enable native language support])],,
413              [enable_nls=yes])
414PKG_CHECK_EXISTS([gtk+-3.0 >= $GTK_MINIMUM
415                  glib-2.0 >= $GLIB_MINIMUM
416                  gio-2.0 >= $GIO_MINIMUM,
417                  gmodule-2.0 >= $GLIB_MINIMUM
418                  gthread-2.0 >= $GLIB_MINIMUM],
419                 [have_gtk=yes],
420                 [have_gtk=no])
421AC_ARG_WITH([gtk], AS_HELP_STRING([--with-gtk],[with Gtk]),
422            [with_gtk=$withval],
423            [with_gtk=$have_gtk])
424AM_CONDITIONAL([BUILD_GTK],[test "x$with_gtk" = "xyes"])
425use_libappindicator=no
426if test "x$with_gtk" = "xyes" ; then
427
428    if test "x$enable_nls" = "xno" ; then
429        AC_MSG_ERROR("The gtk client cannot be built without nls support.  Try adding either --enable-nls or --without-gtk" )
430    fi
431
432    PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= $GTK_MINIMUM
433                              glib-2.0 >= $GLIB_MINIMUM
434                              gio-2.0 >= $GIO_MINIMUM,
435                              gmodule-2.0 >= $GLIB_MINIMUM
436                              gthread-2.0 >= $GLIB_MINIMUM])
437    PKG_CHECK_MODULES([LIBAPPINDICATOR],
438                      [appindicator3-0.1 >= $LIBAPPINDICATOR_MINIMUM],
439                      [have_libappindicator=yes],
440                      [have_libappindicator=no])
441    if test "x$have_libappindicator" = "xyes"; then
442        use_libappindicator=yes
443        AC_DEFINE([HAVE_LIBAPPINDICATOR], 1)
444    else
445        LIBAPPINDICATOR_CFLAGS=
446        LIBAPPINDICATOR_LIBS=
447    fi
448fi
449
450dnl This section is only used for internationalization.
451dnl If you don't need translations and this section gives you trouble --
452dnl such as if you're building for a headless system --
453dnl it's okay to tear this section out and re-build the configure script.
454dnl
455dnl Note to packagers: the bump to intltool 0.40 was made to fix
456dnl a "make check" failure on some systems.  if upgrading to 0.40 is
457dnl a problem and the old version was working fine for you,
458dnl it should be safe to re-edit 0.40 back down to 0.23
459
460use_nls=no
461if test "x$enable_nls" = "xyes" ; then
462    use_nls=yes
463    m4_ifdef([IT_PROG_INTLTOOL],
464             [IT_PROG_INTLTOOL([0.35.0],[no-xml])],
465             [AC_MSG_ERROR("--enable-nls requires intltool to be installed.")])
466    AC_CHECK_HEADERS([libintl.h])
467    GETTEXT_PACKAGE=transmission-gtk
468    AC_SUBST(GETTEXT_PACKAGE)
469    AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
470    AM_GLIB_GNU_GETTEXT
471    transmissionlocaledir='${prefix}/${DATADIRNAME}/locale'
472    AC_SUBST(transmissionlocaledir)
473fi
474AC_SUBST(INTLLIBS)
475
476
477dnl ----------------------------------------------------------------------------
478dnl
479dnl  platform-specific stuff.
480
481AC_CANONICAL_HOST
482have_darwin="no"
483have_msw="no"
484case $host_os in
485
486   *mingw32*)
487     have_msw="yes"
488     CXXFLAGS="$CXXFLAGS -mms-bitfields -mwin32 -mwindows"
489     CPPFLAGS="$CPPFLAGS -DWINVER=0x0600 -D_WIN32_WINNT=0x0600 -DWIN32_LEAN_AND_MEAN"
490     # CPPFLAGS="$CPPFLAGS -D__USE_MINGW_ANSI_STDIO=1 -D__STDC_FORMAT_MACROS=1"
491     LIBS="$LIBS -liphlpapi -lshell32 -lws2_32"
492     transmissionlocaledir="locale"
493     if test -z "$host_alias"; then
494       hostaliaswindres=
495     else
496       hostaliaswindres="$host_alias-windres";
497     fi
498     AC_CHECK_TOOL(WINDRES, windres)
499     ;;
500
501  *darwin*)
502    have_darwin="yes"
503    ;;
504
505esac
506
507AC_ARG_ENABLE([lightweight],
508              AS_HELP_STRING([--enable-lightweight],[optimize libtransmission for low-resource systems: smaller cache size, prefer unencrypted peer connections, etc.]),
509              [enable_lightweight=${enableval}],
510              [enable_lightweight="no"])
511if test "x$enable_lightweight" = "xyes" ; then
512  AC_DEFINE([TR_LIGHTWEIGHT],[1],[optimize libtransmission for low-resource systems])
513fi
514
515AC_ARG_ENABLE([cli],
516              [AS_HELP_STRING([--enable-cli],[build command-line client])],
517              [build_cli=${enableval}],
518              [build_cli="yes"])
519AM_CONDITIONAL([BUILD_CLI],[test "x$build_cli" = "xyes"])
520
521AC_ARG_ENABLE([mac],
522              [AS_HELP_STRING([--enable-mac],[build Mac client])],
523              [build_mac=${enableval}],
524              [build_mac=${have_darwin}])
525AM_CONDITIONAL([BUILD_MAC],[test "x$build_mac" = "xyes"])
526
527AC_ARG_ENABLE([daemon],
528              [AS_HELP_STRING([--enable-daemon],[build daemon])],
529              [build_daemon=${enableval}],
530              [build_daemon="yes"])
531AM_CONDITIONAL([BUILD_DAEMON],[test "x$build_daemon" = "xyes"])
532
533
534if test "x$build_mac" = "xyes" ; then
535   AC_DEFINE([BUILD_MAC_CLIENT], 1)
536    # Make sure the proper Mac SDK is installed
537    if test ! -d /Developer/SDKs/MacOSX10.5.sdk; then
538      cat << EOF
539You need to install the Mac OS X 10.5 SDK in order to build Transmission
540with --enable-mac:
541  Get your Xcode CD or package
542  Restart the install
543  When it gets to "Installation Type", select "Customize"
544  Select "Mac OS X 10.5 SDK" under "Cross Development"
545  Finish the install.
546EOF
547      exit 1
548    fi
549fi
550AM_CONDITIONAL(WIN32, test "x$have_msw" = "xyes")
551
552dnl ----------------------------------------------------------------------------
553dnl
554dnl  Generate the output
555
556AC_CONFIG_FILES([Makefile
557                 transmission-gtk.spec
558                 cli/Makefile
559                 daemon/Makefile
560                 extras/Makefile
561                 libtransmission/Makefile
562                 utils/Makefile
563                 third-party/Makefile
564                 third-party/dht/Makefile
565                 third-party/libutp/Makefile
566                 third-party/libnatpmp/Makefile
567                 third-party/miniupnp/Makefile
568                 macosx/Makefile
569                 gtk/Makefile
570                 gtk/icons/Makefile
571                 qt/config.pri
572                 web/Makefile
573                 web/images/Makefile
574                 web/style/Makefile
575                 web/style/jqueryui/Makefile
576                 web/style/jqueryui/images/Makefile
577                 web/style/transmission/Makefile
578                 web/style/transmission/images/Makefile
579                 web/style/transmission/images/buttons/Makefile
580                 web/javascript/Makefile
581                 web/javascript/jquery/Makefile
582                 po/Makefile.in])
583
584AC_OUTPUT
585
586echo "
587
588Configuration:
589
590   Source code location:                              ${srcdir}
591   Compiler:                                          ${CXX}
592
593   Build libtransmission:                             yes
594      * optimized for low-resource systems:           ${enable_lightweight}
595      * µTP enabled:                                  ${build_utp}
596
597   Build Command-Line client:                         ${build_cli}
598
599   Build GTK+ client:                                 ${with_gtk}
600      * libappindicator for an Ubuntu-style tray:     ${use_libappindicator}
601
602   Build Daemon:                                      ${build_daemon}
603
604   Build Mac client:                                  ${build_mac}
605
606"
Note: See TracBrowser for help on using the repository browser.