source: trunk/configure.ac @ 8572

Last change on this file since 8572 was 8572, checked in by charles, 13 years ago

(trunk) yet another stab at building version.h portably

File size: 11.8 KB
Line 
1dnl convention: -TR MAJOR MINOR MAINT STATUS - (each a single char)
2dnl STATUS: "X" for prerelease beta builds,
3dnl         "Z" for unsupported trunk builds,
4dnl         "0" for stable, supported releases
5dnl these should be the only two lines you need to change
6m4_define([user_agent_prefix],[1.61+])
7m4_define([peer_id_prefix],[-TR161Z-])
8
9AC_INIT([transmission],
10        [user_agent_prefix],
11        [http://trac.transmissionbt.com/newticket])
12AC_SUBST(USERAGENT_PREFIX,[user_agent_prefix])
13AC_SUBST(PEERID_PREFIX,[peer_id_prefix])
14
15AC_CONFIG_MACRO_DIR([m4])
16
17dnl AM_CONFIG_HEADER(config.h)
18AC_CONFIG_SRCDIR(libtransmission/transmission.h)
19AM_INIT_AUTOMAKE([1.9 tar-ustar])
20AC_PROG_LIBTOOL
21
22if test m4_substr(peer_id_prefix,6,1) = "0"; then
23  supported_build=yes
24  if test "x$GCC" = "xyes" ; then
25    CFLAGS="$CFLAGS -g -O3 -funroll-loops "
26    CXXFLAGS="$CXXFLAGS -g -O3 -funroll-loops "
27  fi
28  AC_DEFINE(TR_STABLE_RELEASE, 1, [Define to 1 if this is a stable release of Transmission])
29else
30  supported_build=no
31  if test "x$GCC" = "xyes" ; then
32    CFLAGS="$CFLAGS -g -O0"
33    CXXFLAGS="$CXXFLAGS -g -O0"
34  fi
35  if test m4_substr(peer_id_prefix,6,1) = "X"; then
36    AC_DEFINE(TR_BETA_RELEASE, 1, [Define to 1 if this is a beta release of Transmission])
37  else
38    AC_DEFINE(TR_NIGHTLY_RELEASE, 1, [Define to 1 if this is a nightly release of Transmission])
39  fi
40fi
41AM_CONDITIONAL(TR_UNSTABLE, test "x$supported_build" = "xno")
42
43OPENSSL_MINIMUM=0.9.4
44CURL_MINIMUM=7.16.3
45GIO_MINIMUM=2.15.5
46GLIB_MINIMUM=2.6.0
47GTK_MINIMUM=2.6.0
48WX_MINIMUM=2.6.0
49LIBNOTIFY_MINIMUM=0.4.3
50DBUS_GLIB_MINIMUM=0.70
51AC_SUBST(OPENSSL_MINIMUM)
52AC_SUBST(CURL_MINIMUM)
53AC_SUBST(GIO_MINIMUM)
54AC_SUBST(GLIB_MINIMUM)
55AC_SUBST(GTK_MINIMUM)
56AC_SUBST(WX_MINIMUM)
57AC_SUBST(LIBNOTIFY_MINIMUM)
58AC_SUBST(DBUS_GLIB_MINIMUM)
59
60AC_PROG_CC
61AC_PROG_CXX
62AC_C_INLINE
63if test "x$GCC" = "xyes" ; then
64
65    CFLAGS="$CFLAGS -std=gnu99 -ggdb3 -Wall -W -Wpointer-arith -Wformat-security -Wcast-align -Wundef -Wcast-align -Wstrict-prototypes -Wmissing-declarations -Wmissing-format-attribute -Wredundant-decls -Wnested-externs -Wunused-parameter -Wwrite-strings"
66
67    dnl figure out gcc version
68    AC_MSG_CHECKING([gcc version])
69    GCC_VERSION=`$CC -dumpversion`
70    GCC_MAJOR=`echo $GCC_VERSION | cut -d . -f1`
71    GCC_MINOR=`echo $GCC_VERSION | cut -d . -f2`
72    GCC_VERSION_NUM=`(expr $GCC_MAJOR "*" 100 + $GCC_MINOR) 2>/dev/null`
73
74    AC_MSG_RESULT($GCC_VERSION)
75    if test $GCC_VERSION_NUM -ge 304; then
76        dnl these were added in 3.4
77        CFLAGS="$CFLAGS -Wextra -Wdeclaration-after-statement -Winit-self"
78    fi
79fi
80
81AC_HEADER_STDC
82AC_HEADER_TIME
83
84AC_MSG_CHECKING([for fallocate])
85AC_TRY_LINK([#include <linux/falloc.h>],
86            [return fallocate(-1,0,0,0);],
87            [AC_DEFINE([HAVE_FALLOCATE],[1],[Defined if fallocate() exists])
88             AC_MSG_RESULT([yes])],
89            [AC_MSG_RESULT([no])])
90AC_CHECK_FUNCS([lrintf strlcpy daemon dirname basename daemon strcasecmp localtime_r posix_fallocate memmem])
91AC_PROG_INSTALL
92AC_PROG_MAKE_SET
93ACX_PTHREAD
94
95AC_SEARCH_LIBS([socket], [socket net])
96AC_SEARCH_LIBS([gethostbyname], [nsl bind])
97PKG_CHECK_MODULES(OPENSSL, [openssl >= $OPENSSL_MINIMUM], , [CHECK_SSL()])
98PKG_CHECK_MODULES(LIBCURL, [libcurl >= $CURL_MINIMUM])
99AC_PATH_ZLIB
100
101AC_SYS_LARGEFILE
102
103
104dnl ----------------------------------------------------------------------------
105dnl
106dnl posix_fadvise
107
108dnl can posix_fadvise be used
109AC_CHECK_DECLS(posix_fadvise, [], [], [
110#define _XOPEN_SOURCE 600
111#include <fcntl.h>])
112AC_CHECK_FUNCS([posix_fadvise])
113
114
115dnl ----------------------------------------------------------------------------
116dnl
117dnl file monitoring for the daemon
118
119AC_CHECK_HEADER([sys/inotify.h],
120                [AC_CHECK_FUNC([inotify_init],[have_inotify="yes"],[have_inotify="no"])],
121                [have_inotify="no"])
122AC_ARG_WITH([inotify],
123            [AS_HELP_STRING([--with-inotify],[Enable inotify support (default=auto)])],
124            [want_inotify=${enableval}],
125            [want_inotify=${have_inotify}])
126if test "x$want_inotify" = "xyes" ; then
127    if test "x$have_inotify" = "xyes"; then
128      AC_DEFINE([WITH_INOTIFY],[1])
129    else
130      AC_MSG_ERROR("inotify not found!")
131    fi
132fi
133 
134AC_CHECK_HEADER([sys/event.h],
135                [AC_CHECK_FUNC([kqueue],[have_kqueue="yes"],[have_kqueue="no"])],
136                [have_kqueue="no"])
137AC_ARG_WITH([kqueue],
138            [AS_HELP_STRING([--with-kqueue],[Enable kqueue support (default=auto)])],
139            [want_kqueue=${enableval}],
140            [want_kqueue=${have_kqueue}])
141if test "x$want_kqueue" = "xyes" ; then
142    if test "x$have_kqueue" = "xyes"; then
143      AC_DEFINE([WITH_KQUEUE],[1])
144    else
145      AC_MSG_ERROR("kqueue not found!")
146    fi
147fi
148
149AC_CHECK_HEADERS([xfs/xfs.h])
150
151
152dnl ----------------------------------------------------------------------------
153dnl
154dnl va_copy
155
156AC_MSG_CHECKING([how to copy va_list])
157AC_TRY_LINK([#include <stdarg.h>], [va_list ap1, ap2; va_copy(ap1, ap2);],
158    AC_MSG_RESULT([va_copy]),
159        [ AH_TEMPLATE([va_copy], [define if va_copy is not available])
160        AC_TRY_LINK([#include <stdarg.h>], [va_list ap1, ap2; __va_copy(ap1, ap2);],
161        [ AC_DEFINE([va_copy], [__va_copy])
162        AC_MSG_RESULT([__va_copy])],
163        [ AC_DEFINE([va_copy(dest,src)], [memcpy(&dest,&src,sizeof(va_list))])
164        AC_MSG_RESULT([memcpy])]
165    )
166])
167
168dnl ----------------------------------------------------------------------------
169dnl
170dnl  libevent fun
171dnl
172dnl  we have to add the builddir into the include path because event-config.h
173dnl  is generated when libevent is build
174
175AC_CONFIG_SUBDIRS([third-party/libevent])
176AC_MSG_NOTICE([invoking libevent's configure script])
177LIBEVENT_CPPFLAGS="-I\$(top_srcdir)/third-party/libevent -I\$(top_builddir)/third-party/libevent"
178AC_SUBST(LIBEVENT_CPPFLAGS)
179
180
181dnl ----------------------------------------------------------------------------
182dnl
183dnl  detection for the GTK+ client
184
185PKG_CHECK_MODULES(GTK,
186                  [gtk+-2.0 >= $GTK_MINIMUM
187                   glib-2.0 >= $GLIB_MINIMUM
188                   gmodule-2.0 >= $GLIB_MINIMUM
189                   gthread-2.0 >= $GLIB_MINIMUM],
190                  [have_gtk=yes],
191                  [have_gtk=no])
192AC_ARG_ENABLE([gtk],
193              AS_HELP_STRING([--enable-gtk],[build gtk client]),
194              [want_gtk=${enableval}],
195              [want_gtk=${have_gtk}])
196build_gtk=no
197use_gio=no
198use_libnotify=no
199use_dbus_glib=no
200if test "x$want_gtk" = "xyes" ; then
201    if test "x$have_gtk" = "xyes"; then
202      build_gtk=yes
203    else
204      AC_MSG_ERROR("GTK+ not found!")
205    fi
206fi
207AM_CONDITIONAL([BUILD_GTK],[test "x$build_gtk" = "xyes"])
208AC_SUBST(GTK_LIBS)
209AC_SUBST(GTK_CFLAGS)
210
211if test "x$build_gtk" = "xyes"; then
212
213    PKG_CHECK_MODULES([GIO],
214                      [gio-2.0 >= $GIO_MINIMUM],
215                      [use_gio=yes],
216                      [use_gio=no])
217    AC_SUBST(GIO_LIBS)
218    AC_SUBST(GIO_CFLAGS)
219    if test "x$use_gio" = "xyes"; then
220        AC_DEFINE([HAVE_GIO], 1)
221    fi
222
223    PKG_CHECK_MODULES([LIBNOTIFY],
224                      [libnotify >= $LIBNOTIFY_MINIMUM],
225                      [have_libnotify=yes],
226                      [have_libnotify=no])
227    AC_ARG_ENABLE([libnotify],
228                  AS_HELP_STRING([--enable-libnotify],[enable notifications]),,
229                  [enable_libnotify=yes])
230    use_libnotify=no
231    if test "x$enable_libnotify" = "xyes" ; then
232        if test "x$have_libnotify" = "xyes"; then
233            use_libnotify=yes
234            AC_SUBST(LIBNOTIFY_LIBS)
235            AC_SUBST(LIBNOTIFY_CFLAGS)
236            AC_DEFINE([HAVE_LIBNOTIFY], 1)
237        fi
238    fi
239
240    PKG_CHECK_MODULES([DBUS_GLIB],
241                      [dbus-glib-1 >= $DBUS_GLIB_MINIMUM],
242                      [use_dbus_glib=yes],
243                      [use_dbus_glib=no])
244    AC_SUBST(DBUS_GLIB_LIBS)
245    AC_SUBST(DBUS_GLIB_CFLAGS)
246    if test "x$use_dbus_glib" = "xyes"; then
247        AC_DEFINE([HAVE_DBUS_GLIB], 1)
248    fi
249    if test "x$use_dbus_glib" = "xyes"; then
250        AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool, no)
251        if test "x$DBUS_BINDING_TOOL" = xno; then
252          AC_MSG_WARN([Cannot find dbus-binding-tool])
253          use_dbus_glib="no (dbus-binding-tool not found)"
254        fi
255    fi
256fi
257
258AC_ARG_ENABLE([nls],
259              AS_HELP_STRING([--enable-nls],[enable native language support]),,
260              [enable_nls=yes])
261
262if test "x$build_gtk" = "xyes" -a  "x$enable_nls" = "xno" ; then
263    AC_MSG_ERROR("The gtk client cannot be built without nls support.  Try adding either --enable-nls or --disable-gtk" )
264fi
265
266use_nls=no
267if test "x$enable_nls" = "xyes" ; then
268    use_nls=yes
269    IT_PROG_INTLTOOL([0.35],[no-xml])
270    AC_CHECK_HEADERS([libintl.h])
271    GETTEXT_PACKAGE=transmission
272    AC_SUBST(GETTEXT_PACKAGE)
273    AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
274    AM_GLIB_GNU_GETTEXT
275    transmissionlocaledir='${prefix}/${DATADIRNAME}/locale'
276    AC_SUBST(transmissionlocaledir)
277fi
278
279
280dnl ----------------------------------------------------------------------------
281dnl
282dnl  platform-specific stuff.
283
284AC_CANONICAL_HOST
285have_darwin="no"
286have_msw="no"
287case $host_os in
288
289   *cygwin|*mingw32*)
290     have_msw="yes"
291     CXXFLAGS="$CXXFLAGS -mms-bitfields -mwin32 -mwindows"
292     CPPFLAGS="$CPPFLAGS -DWIN32 -D_WIN32 -DWIN32_LEAN_AND_MEAN"
293     LIBS="$LIBS -lshell32 -lws2_32"
294     transmissionlocaledir="locale"
295     if test -z "$host_alias"; then
296       hostaliaswindres=
297     else
298       hostaliaswindres="$host_alias-windres";
299     fi
300     AC_CHECK_TOOL(WINDRES, windres)
301     ;;
302
303  *darwin*)
304    have_darwin="yes"
305    # Make sure the Universal SDK is installed
306    if test ! -d /Developer/SDKs/MacOSX10.4u.sdk; then
307      cat << EOF
308You need to install the Universal SDK in order to build Transmission:
309  Get your Xcode CD or package
310  Restart the install
311  When it gets to "Installation Type", select "Customize"
312  Select "Mac OS X 10.4 (Universal) SDK" under "Cross Development"
313  Finish the install.
314EOF
315      exit 1
316    fi
317    ;;
318
319esac
320
321AC_ARG_ENABLE([cli],
322              [AS_HELP_STRING([--enable-cli],[build command-line client])],
323              [build_cli=${enableval}],
324              [build_cli="yes"])
325AM_CONDITIONAL([BUILD_CLI],[test "x$build_cli" = "xyes"])
326
327AC_ARG_ENABLE([mac],
328              [AS_HELP_STRING([--enable-mac],[build OS X client])],
329              [build_mac=${enableval}],
330              [build_mac=${have_darwin}])
331AM_CONDITIONAL([BUILD_MAC],[test "x$build_mac" = "xyes"])
332
333AC_ARG_ENABLE([daemon],
334              [AS_HELP_STRING([--enable-daemon],[build daemon])],
335              [build_daemon=${enableval}],
336              [build_daemon="yes"])
337AM_CONDITIONAL([BUILD_DAEMON],[test "x$build_daemon" = "xyes"])
338
339
340if test "x$have_darwin" = "xyes"; then
341    AC_DEFINE([HAVE_DARWIN], 1)
342fi
343if test "x$have_msw" = "xyes"; then
344    AC_DEFINE([HAVE_MSW], 1)
345fi
346AM_CONDITIONAL(WIN32, test "x$have_msw" = "xyes")
347
348dnl ----------------------------------------------------------------------------
349dnl
350dnl  Generate the output
351
352AC_CONFIG_FILES([Makefile
353                 transmission.spec
354                 cli/Makefile
355                 daemon/Makefile
356                 doc/Makefile
357                 libtransmission/Makefile
358                 third-party/Makefile
359                 third-party/miniupnp/Makefile
360                 third-party/libnatpmp/Makefile
361                 third-party/dht/Makefile
362                 macosx/Makefile
363                 gtk/Makefile
364                 gtk/icons/Makefile
365                 po/Makefile.in])
366
367ac_configure_args="$ac_configure_args --enable-static --disable-shared -q"
368AC_OUTPUT
369
370echo "
371
372Configuration:
373
374        Source code location:       ${srcdir}
375        Compiler:                   ${CXX}
376        Build Command-Line client:  ${build_cli}
377        Build Daemon:               ${build_daemon}
378        Build GTK+ client:          ${build_gtk}
379          ... gio support:          ${use_gio}
380          ... dbus-glib support:    ${use_dbus_glib}
381          ... libnotify support:    ${use_libnotify}
382        Build OS X client:          ${build_mac}
383
384"
Note: See TracBrowser for help on using the repository browser.