source: trunk/configure.ac @ 8614

Last change on this file since 8614 was 8614, checked in by charles, 13 years ago

(trunk) update news and bump version to 1.70

File size: 12.2 KB
Line 
1dnl convention: -TR MAJOR MINOR MAINT STATUS - (each a single char)
2dnl STATUS: "X" for prerelease beta builds,
3dnl         "Z" for unsupported trunk builds,
4dnl         "0" for stable, supported releases
5dnl these should be the only two lines you need to change
6m4_define([user_agent_prefix],[1.70])
7m4_define([peer_id_prefix],[-TR1700-])
8
9AC_INIT([transmission],
10        [user_agent_prefix],
11        [http://trac.transmissionbt.com/newticket])
12AC_SUBST(USERAGENT_PREFIX,[user_agent_prefix])
13AC_SUBST(PEERID_PREFIX,[peer_id_prefix])
14
15AC_CONFIG_MACRO_DIR([m4])
16
17dnl AM_CONFIG_HEADER(config.h)
18AC_CONFIG_SRCDIR(libtransmission/transmission.h)
19AM_INIT_AUTOMAKE([1.9 tar-ustar])
20AC_PROG_LIBTOOL
21
22if test m4_substr(peer_id_prefix,6,1) = "0"; then
23  supported_build=yes
24  if test "x$GCC" = "xyes" ; then
25    CFLAGS="$CFLAGS -g -O3 "
26    CXXFLAGS="$CXXFLAGS -g -O3 "
27  fi
28  AC_DEFINE(TR_STABLE_RELEASE, 1, [Define to 1 if this is a stable release of Transmission])
29else
30  supported_build=no
31  if test "x$GCC" = "xyes" ; then
32    CFLAGS="$CFLAGS -g -O0"
33    CXXFLAGS="$CXXFLAGS -g -O0"
34  fi
35  if test m4_substr(peer_id_prefix,6,1) = "X"; then
36    AC_DEFINE(TR_BETA_RELEASE, 1, [Define to 1 if this is a beta release of Transmission])
37  else
38    AC_DEFINE(TR_NIGHTLY_RELEASE, 1, [Define to 1 if this is a nightly release of Transmission])
39  fi
40fi
41AM_CONDITIONAL(TR_UNSTABLE, test "x$supported_build" = "xno")
42
43OPENSSL_MINIMUM=0.9.4
44CURL_MINIMUM=7.16.3
45GIO_MINIMUM=2.15.5
46GLIB_MINIMUM=2.6.0
47GTK_MINIMUM=2.6.0
48LIBNOTIFY_MINIMUM=0.4.3
49DBUS_GLIB_MINIMUM=0.70
50LIBEVENT_MINIMUM=1.4.5
51AC_SUBST(OPENSSL_MINIMUM)
52AC_SUBST(CURL_MINIMUM)
53AC_SUBST(GIO_MINIMUM)
54AC_SUBST(GLIB_MINIMUM)
55AC_SUBST(GTK_MINIMUM)
56AC_SUBST(LIBNOTIFY_MINIMUM)
57AC_SUBST(DBUS_GLIB_MINIMUM)
58AC_SUBST(LIBEVENT_MINIUM)
59
60AC_PROG_CC
61AC_PROG_CXX
62AC_C_INLINE
63if test "x$GCC" = "xyes" ; then
64
65    CFLAGS="$CFLAGS -std=gnu99 -ggdb3 -Wall -W -Wpointer-arith -Wformat-security -Wcast-align -Wundef -Wcast-align -Wstrict-prototypes -Wmissing-declarations -Wmissing-format-attribute -Wredundant-decls -Wnested-externs -Wunused-parameter -Wwrite-strings"
66
67    dnl figure out gcc version
68    AC_MSG_CHECKING([gcc version])
69    GCC_VERSION=`$CC -dumpversion`
70    GCC_MAJOR=`echo $GCC_VERSION | cut -d . -f1`
71    GCC_MINOR=`echo $GCC_VERSION | cut -d . -f2`
72    GCC_VERSION_NUM=`(expr $GCC_MAJOR "*" 100 + $GCC_MINOR) 2>/dev/null`
73
74    AC_MSG_RESULT($GCC_VERSION)
75    if test $GCC_VERSION_NUM -ge 304; then
76        dnl these were added in 3.4
77        CFLAGS="$CFLAGS -Wextra -Wdeclaration-after-statement -Winit-self"
78    fi
79fi
80
81AC_HEADER_STDC
82AC_HEADER_TIME
83
84AC_MSG_CHECKING([for fallocate])
85AC_TRY_LINK([#include <linux/falloc.h>],
86            [return fallocate(-1,0,0,0);],
87            [AC_DEFINE([HAVE_FALLOCATE],[1],[Defined if fallocate() exists])
88             AC_MSG_RESULT([yes])],
89            [AC_MSG_RESULT([no])])
90AC_CHECK_FUNCS([lrintf strlcpy daemon dirname basename daemon strcasecmp localtime_r posix_fallocate memmem])
91AC_PROG_INSTALL
92AC_PROG_MAKE_SET
93ACX_PTHREAD
94
95AC_SEARCH_LIBS([socket], [socket net])
96AC_SEARCH_LIBS([gethostbyname], [nsl bind])
97PKG_CHECK_MODULES(OPENSSL, [openssl >= $OPENSSL_MINIMUM], , [CHECK_SSL()])
98PKG_CHECK_MODULES(LIBCURL, [libcurl >= $CURL_MINIMUM])
99AC_PATH_ZLIB
100
101AC_SYS_LARGEFILE
102
103
104dnl ----------------------------------------------------------------------------
105dnl
106dnl posix_fadvise
107
108dnl can posix_fadvise be used
109AC_CHECK_DECLS(posix_fadvise, [], [], [
110#define _XOPEN_SOURCE 600
111#include <fcntl.h>])
112AC_CHECK_FUNCS([posix_fadvise])
113
114
115dnl ----------------------------------------------------------------------------
116dnl
117dnl file monitoring for the daemon
118
119AC_CHECK_HEADER([sys/inotify.h],
120                [AC_CHECK_FUNC([inotify_init],[have_inotify="yes"],[have_inotify="no"])],
121                [have_inotify="no"])
122AC_ARG_WITH([inotify],
123            [AS_HELP_STRING([--with-inotify],[Enable inotify support (default=auto)])],
124            [want_inotify=${enableval}],
125            [want_inotify=${have_inotify}])
126if test "x$want_inotify" = "xyes" ; then
127    if test "x$have_inotify" = "xyes"; then
128      AC_DEFINE([WITH_INOTIFY],[1])
129    else
130      AC_MSG_ERROR("inotify not found!")
131    fi
132fi
133 
134AC_CHECK_HEADER([sys/event.h],
135                [AC_CHECK_FUNC([kqueue],[have_kqueue="yes"],[have_kqueue="no"])],
136                [have_kqueue="no"])
137AC_ARG_WITH([kqueue],
138            [AS_HELP_STRING([--with-kqueue],[Enable kqueue support (default=auto)])],
139            [want_kqueue=${enableval}],
140            [want_kqueue=${have_kqueue}])
141if test "x$want_kqueue" = "xyes" ; then
142    if test "x$have_kqueue" = "xyes"; then
143      AC_DEFINE([WITH_KQUEUE],[1])
144    else
145      AC_MSG_ERROR("kqueue not found!")
146    fi
147fi
148
149AC_CHECK_HEADERS([xfs/xfs.h])
150
151
152dnl ----------------------------------------------------------------------------
153dnl
154dnl va_copy
155
156AC_MSG_CHECKING([how to copy va_list])
157AC_TRY_LINK([#include <stdarg.h>], [va_list ap1, ap2; va_copy(ap1, ap2);],
158    AC_MSG_RESULT([va_copy]),
159        [ AH_TEMPLATE([va_copy], [define if va_copy is not available])
160        AC_TRY_LINK([#include <stdarg.h>], [va_list ap1, ap2; __va_copy(ap1, ap2);],
161        [ AC_DEFINE([va_copy], [__va_copy])
162        AC_MSG_RESULT([__va_copy])],
163        [ AC_DEFINE([va_copy(dest,src)], [memcpy(&dest,&src,sizeof(va_list))])
164        AC_MSG_RESULT([memcpy])]
165    )
166])
167
168
169AC_CHECK_HEADER([event-config.h],
170                [libevent_source=system
171                 LIBEVENT_CPPFLAGS=""
172                 LIBEVENT_LIBS="-levent"],
173                [libevent_source=bundled
174                 AC_MSG_NOTICE([couldn't find event-config.h, so using our own copy of libevent from third-party/libevent/.])
175                 AC_MSG_NOTICE([if you are cross-compiling this is probably NOT what you want.])
176                 AC_CONFIG_SUBDIRS([third-party/libevent])
177                 LIBEVENT_CPPFLAGS="-I\$(top_srcdir)/third-party/libevent -I\$(top_builddir)/third-party/libevent"
178                 LIBEVENT_LIBS="\$(top_builddir)/third-party/libevent/.libs/libevent.a"])
179AM_CONDITIONAL([BUILD_LIBEVENT], [test x$libevent_source = xbundled])
180AC_SUBST(LIBEVENT_CPPFLAGS)
181AC_SUBST(LIBEVENT_LIBS)
182
183
184dnl ----------------------------------------------------------------------------
185dnl
186dnl  detection for the GTK+ client
187
188PKG_CHECK_MODULES(GTK,
189                  [gtk+-2.0 >= $GTK_MINIMUM
190                   glib-2.0 >= $GLIB_MINIMUM
191                   gmodule-2.0 >= $GLIB_MINIMUM
192                   gthread-2.0 >= $GLIB_MINIMUM],
193                  [have_gtk=yes],
194                  [have_gtk=no])
195AC_ARG_ENABLE([gtk],
196              AS_HELP_STRING([--enable-gtk],[build gtk client]),
197              [want_gtk=${enableval}],
198              [want_gtk=${have_gtk}])
199build_gtk=no
200use_gio=no
201use_libnotify=no
202use_dbus_glib=no
203if test "x$want_gtk" = "xyes" ; then
204    if test "x$have_gtk" = "xyes"; then
205      build_gtk=yes
206    else
207      AC_MSG_ERROR("GTK+ not found!")
208    fi
209fi
210AM_CONDITIONAL([BUILD_GTK],[test "x$build_gtk" = "xyes"])
211AC_SUBST(GTK_LIBS)
212AC_SUBST(GTK_CFLAGS)
213
214if test "x$build_gtk" = "xyes"; then
215
216    PKG_CHECK_MODULES([GIO],
217                      [gio-2.0 >= $GIO_MINIMUM],
218                      [use_gio=yes],
219                      [use_gio=no])
220    AC_SUBST(GIO_LIBS)
221    AC_SUBST(GIO_CFLAGS)
222    if test "x$use_gio" = "xyes"; then
223        AC_DEFINE([HAVE_GIO], 1)
224    fi
225
226    PKG_CHECK_MODULES([LIBNOTIFY],
227                      [libnotify >= $LIBNOTIFY_MINIMUM],
228                      [have_libnotify=yes],
229                      [have_libnotify=no])
230    AC_ARG_ENABLE([libnotify],
231                  AS_HELP_STRING([--enable-libnotify],[enable notifications]),,
232                  [enable_libnotify=yes])
233    use_libnotify=no
234    if test "x$enable_libnotify" = "xyes" ; then
235        if test "x$have_libnotify" = "xyes"; then
236            use_libnotify=yes
237            AC_SUBST(LIBNOTIFY_LIBS)
238            AC_SUBST(LIBNOTIFY_CFLAGS)
239            AC_DEFINE([HAVE_LIBNOTIFY], 1)
240        fi
241    fi
242
243    PKG_CHECK_MODULES([DBUS_GLIB],
244                      [dbus-glib-1 >= $DBUS_GLIB_MINIMUM],
245                      [use_dbus_glib=yes],
246                      [use_dbus_glib=no])
247    AC_SUBST(DBUS_GLIB_LIBS)
248    AC_SUBST(DBUS_GLIB_CFLAGS)
249    if test "x$use_dbus_glib" = "xyes"; then
250        AC_DEFINE([HAVE_DBUS_GLIB], 1)
251    fi
252    if test "x$use_dbus_glib" = "xyes"; then
253        AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool, no)
254        if test "x$DBUS_BINDING_TOOL" = xno; then
255          AC_MSG_WARN([Cannot find dbus-binding-tool])
256          use_dbus_glib="no (dbus-binding-tool not found)"
257        fi
258    fi
259fi
260
261AC_ARG_ENABLE([nls],
262              AS_HELP_STRING([--enable-nls],[enable native language support]),,
263              [enable_nls=yes])
264
265if test "x$build_gtk" = "xyes" -a  "x$enable_nls" = "xno" ; then
266    AC_MSG_ERROR("The gtk client cannot be built without nls support.  Try adding either --enable-nls or --disable-gtk" )
267fi
268
269use_nls=no
270if test "x$enable_nls" = "xyes" ; then
271    use_nls=yes
272    IT_PROG_INTLTOOL([0.35],[no-xml])
273    AC_CHECK_HEADERS([libintl.h])
274    GETTEXT_PACKAGE=transmission
275    AC_SUBST(GETTEXT_PACKAGE)
276    AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
277    AM_GLIB_GNU_GETTEXT
278    transmissionlocaledir='${prefix}/${DATADIRNAME}/locale'
279    AC_SUBST(transmissionlocaledir)
280fi
281
282
283dnl ----------------------------------------------------------------------------
284dnl
285dnl  platform-specific stuff.
286
287AC_CANONICAL_HOST
288have_darwin="no"
289have_msw="no"
290case $host_os in
291
292   *cygwin|*mingw32*)
293     have_msw="yes"
294     CXXFLAGS="$CXXFLAGS -mms-bitfields -mwin32 -mwindows"
295     CPPFLAGS="$CPPFLAGS -DWIN32 -D_WIN32 -DWIN32_LEAN_AND_MEAN"
296     LIBS="$LIBS -lshell32 -lws2_32"
297     transmissionlocaledir="locale"
298     if test -z "$host_alias"; then
299       hostaliaswindres=
300     else
301       hostaliaswindres="$host_alias-windres";
302     fi
303     AC_CHECK_TOOL(WINDRES, windres)
304     ;;
305
306  *darwin*)
307    have_darwin="yes"
308    # Make sure the Universal SDK is installed
309    if test ! -d /Developer/SDKs/MacOSX10.4u.sdk; then
310      cat << EOF
311You need to install the Universal SDK in order to build Transmission:
312  Get your Xcode CD or package
313  Restart the install
314  When it gets to "Installation Type", select "Customize"
315  Select "Mac OS X 10.4 (Universal) SDK" under "Cross Development"
316  Finish the install.
317EOF
318      exit 1
319    fi
320    ;;
321
322esac
323
324AC_ARG_ENABLE([cli],
325              [AS_HELP_STRING([--enable-cli],[build command-line client])],
326              [build_cli=${enableval}],
327              [build_cli="yes"])
328AM_CONDITIONAL([BUILD_CLI],[test "x$build_cli" = "xyes"])
329
330AC_ARG_ENABLE([mac],
331              [AS_HELP_STRING([--enable-mac],[build OS X client])],
332              [build_mac=${enableval}],
333              [build_mac=${have_darwin}])
334AM_CONDITIONAL([BUILD_MAC],[test "x$build_mac" = "xyes"])
335
336AC_ARG_ENABLE([daemon],
337              [AS_HELP_STRING([--enable-daemon],[build daemon])],
338              [build_daemon=${enableval}],
339              [build_daemon="yes"])
340AM_CONDITIONAL([BUILD_DAEMON],[test "x$build_daemon" = "xyes"])
341
342
343if test "x$have_darwin" = "xyes"; then
344    AC_DEFINE([HAVE_DARWIN], 1)
345fi
346if test "x$have_msw" = "xyes"; then
347    AC_DEFINE([HAVE_MSW], 1)
348fi
349AM_CONDITIONAL(WIN32, test "x$have_msw" = "xyes")
350
351dnl ----------------------------------------------------------------------------
352dnl
353dnl  Generate the output
354
355AC_CONFIG_FILES([Makefile
356                 transmission.spec
357                 cli/Makefile
358                 daemon/Makefile
359                 doc/Makefile
360                 libtransmission/Makefile
361                 third-party/Makefile
362                 third-party/miniupnp/Makefile
363                 third-party/libnatpmp/Makefile
364                 third-party/dht/Makefile
365                 macosx/Makefile
366                 gtk/Makefile
367                 gtk/icons/Makefile
368                 po/Makefile.in])
369
370ac_configure_args="$ac_configure_args --enable-static --disable-shared -q"
371AC_OUTPUT
372
373echo "
374
375Configuration:
376
377        Source code location:          ${srcdir}
378        Compiler:                      ${CXX}
379        System or bundled libevent:    ${libevent_source}
380
381        Build OS X client:             ${build_mac}
382        Build GTK+ client:             ${build_gtk}
383          ... with gio support:        ${use_gio}
384          ... with dbus-glib support:  ${use_dbus_glib}
385          ... with libnotify support:  ${use_libnotify}
386        Build Command-Line client:     ${build_cli}
387        Build Daemon:                  ${build_daemon}
388
389"
Note: See TracBrowser for help on using the repository browser.