source: trunk/qt/qtr.pro @ 11985

Last change on this file since 11985 was 11985, checked in by jordan, 11 years ago

(trunk) fix uTP FTBFS in Wheezy, patch by taem

File size: 2.1 KB
Line 
1TARGET = transmission-qt
2NAME = "Transmission"
3DESCRIPTION = "Transmission: a fast, easy, and free BitTorrent client"
4VERSION = 2.00
5LICENSE = "GPL"
6
7target.path = /bin
8INSTALLS += target
9
10unix: INSTALLS += man
11man.path = /share/man/man1/
12man.files = transmission-qt.1
13
14CONFIG += qt qdbus thread debug link_pkgconfig
15QT += network
16PKGCONFIG = fontconfig libcurl openssl libevent
17
18TRANSMISSION_TOP = ..
19INCLUDEPATH = $${EVENT_TOP}/include $${INCLUDEPATH}
20INCLUDEPATH += $${TRANSMISSION_TOP}
21LIBS += $${TRANSMISSION_TOP}/libtransmission/libtransmission.a
22LIBS += $${TRANSMISSION_TOP}/third-party/libutp/libutp.a
23LIBS += $${TRANSMISSION_TOP}/third-party/dht/libdht.a
24LIBS += $${TRANSMISSION_TOP}/third-party/miniupnp/libminiupnp.a
25LIBS += $${TRANSMISSION_TOP}/third-party/libnatpmp/libnatpmp.a
26unix: LIBS += -L$${EVENT_TOP}/lib -levent -lz -lrt
27win32:DEFINES += QT_DBUS
28win32:LIBS += -levent -lws2_32 -lintl
29win32:LIBS += -lidn -liconv -lwldap32 -liphlpapi
30
31TRANSLATIONS += translations/transmission_en.ts \
32                translations/transmission_es.ts \
33                translations/transmission_pt_BR.ts \
34                translations/transmission_ru.ts
35
36FORMS += mainwin.ui
37RESOURCES += application.qrc
38SOURCES += about.cc \
39           add-data.cc \
40           app.cc \
41           dbus-adaptor.cc \
42           details.cc \
43           favicon.cc \
44           file-tree.cc \
45           filterbar.cc \
46           filters.cc \
47           formatter.cc \
48           hig.cc \
49           license.cc \
50           mainwin.cc \
51           make-dialog.cc \
52           options.cc \
53           prefs.cc \
54           prefs-dialog.cc \
55           relocate.cc \
56           session.cc \
57           session-dialog.cc \
58           squeezelabel.cc \
59           stats-dialog.cc \
60           torrent.cc torrent-delegate.cc \
61           torrent-delegate-min.cc \
62           torrent-filter.cc \
63           torrent-model.cc \
64           tracker-delegate.cc \
65           tracker-model.cc \
66           tracker-model-filter.cc \
67           triconpushbutton.cc \
68           utils.cc \
69           watchdir.cc
70HEADERS += $$replace(SOURCES, .cc, .h)
71HEADERS += speed.h types.h
72
73win32:RC_FILE = qtr.rc
Note: See TracBrowser for help on using the repository browser.