source: trunk/qt/qtr.pro @ 13991

Last change on this file since 13991 was 13991, checked in by jordan, 9 years ago

(trunk) first draft of changing the FreeSpace? API to behave as https://trac.transmissionbt.com/ticket/4076#comment:25 -- libT, rpc, qt, and gtk implementations.

File size: 2.3 KB
Line 
1TARGET = transmission-qt
2NAME = "Transmission"
3DESCRIPTION = "Transmission: a fast, easy, and free BitTorrent client"
4VERSION = 2.00
5LICENSE = "GPL"
6
7target.path = /bin
8INSTALLS += target
9
10unix: INSTALLS += man
11man.path = /share/man/man1/
12man.files = transmission-qt.1
13
14CONFIG += qt qdbus thread debug link_pkgconfig
15QT += network
16PKGCONFIG = fontconfig libcurl openssl libevent
17
18TRANSMISSION_TOP = ..
19
20include(config.pri)
21
22INCLUDEPATH = $${EVENT_TOP}/include $${INCLUDEPATH}
23INCLUDEPATH += $${TRANSMISSION_TOP}
24LIBS += $${TRANSMISSION_TOP}/libtransmission/libtransmission.a
25LIBS += $${LIBUTP_LIBS}
26LIBS += $${TRANSMISSION_TOP}/third-party/dht/libdht.a
27LIBS += $${LIBUPNP_LIBS}
28LIBS += $${LIBNATPMP_LIBS}
29unix: LIBS += -L$${EVENT_TOP}/lib -lz -lrt
30win32:DEFINES += QT_DBUS
31win32:LIBS += -levent-2.0 -lws2_32 -lintl
32win32:LIBS += -lidn -liconv -lwldap32 -liphlpapi
33
34TRANSLATIONS += translations/transmission_en.ts \
35                translations/transmission_es.ts \
36                translations/transmission_eu.ts \
37                translations/transmission_fr.ts \
38                translations/transmission_kk.ts \
39                translations/transmission_lt.ts \
40                translations/transmission_pt_BR.ts \
41                translations/transmission_ru.ts \
42                translations/transmission_hu.ts
43
44FORMS += mainwin.ui
45RESOURCES += application.qrc
46SOURCES += about.cc \
47           add-data.cc \
48           app.cc \
49           dbus-adaptor.cc \
50           details.cc \
51           favicon.cc \
52           file-tree.cc \
53           filterbar.cc \
54           filters.cc \
55           freespace-label.cc \
56           formatter.cc \
57           hig.cc \
58           license.cc \
59           mainwin.cc \
60           make-dialog.cc \
61           options.cc \
62           prefs.cc \
63           prefs-dialog.cc \
64           relocate.cc \
65           session.cc \
66           session-dialog.cc \
67           squeezelabel.cc \
68           stats-dialog.cc \
69           torrent.cc torrent-delegate.cc \
70           torrent-delegate-min.cc \
71           torrent-filter.cc \
72           torrent-model.cc \
73           tracker-delegate.cc \
74           tracker-model.cc \
75           tracker-model-filter.cc \
76           triconpushbutton.cc \
77           utils.cc \
78           watchdir.cc
79HEADERS += $$replace(SOURCES, .cc, .h)
80HEADERS += speed.h types.h
81
82win32:RC_FILE = qtr.rc
Note: See TracBrowser for help on using the repository browser.