source: trunk/qt/qtr.pro @ 14391

Last change on this file since 14391 was 14391, checked in by mikedld, 8 years ago

Rework statistics dialog in Qt client to load from .ui

Fix "Started %n time(s)" phrase (remove space in "time (s)", add proper
English translation for numeric forms).

File size: 2.5 KB
Line 
1TARGET = transmission-qt
2NAME = "Transmission"
3DESCRIPTION = "Transmission: a fast, easy, and free BitTorrent client"
4VERSION = 2.81
5LICENSE = "GPL"
6
7target.path = /bin
8INSTALLS += target
9
10unix: INSTALLS += man
11man.path = /share/man/man1/
12man.files = transmission-qt.1
13
14CONFIG += qt thread debug link_pkgconfig c++11 warn_on
15QT += network dbus
16PKGCONFIG = fontconfig libcurl openssl libevent
17
18greaterThan(QT_MAJOR_VERSION, 4) {
19    QT += widgets
20}
21
22TRANSMISSION_TOP = ..
23
24include(config.pri)
25
26INCLUDEPATH = $${EVENT_TOP}/include $${INCLUDEPATH}
27INCLUDEPATH += $${TRANSMISSION_TOP}
28LIBS += $${TRANSMISSION_TOP}/libtransmission/libtransmission.a
29LIBS += $${LIBUTP_LIBS}
30LIBS += $${TRANSMISSION_TOP}/third-party/dht/libdht.a
31LIBS += $${LIBUPNP_LIBS}
32LIBS += $${LIBNATPMP_LIBS}
33unix: LIBS += -L$${EVENT_TOP}/lib -lz -lrt
34win32:DEFINES += QT_DBUS
35win32:LIBS += -levent-2.0 -lws2_32 -lintl
36win32:LIBS += -lidn -liconv -lwldap32 -liphlpapi
37
38TRANSLATIONS += translations/transmission_en.ts \
39                translations/transmission_es.ts \
40                translations/transmission_eu.ts \
41                translations/transmission_fr.ts \
42                translations/transmission_hu.ts \
43                translations/transmission_kk.ts \
44                translations/transmission_lt.ts \
45                translations/transmission_pt_BR.ts \
46                translations/transmission_ru.ts \
47                translations/transmission_uk.ts
48
49FORMS += details.ui \
50         mainwin.ui \
51         stats-dialog.ui
52RESOURCES += application.qrc
53SOURCES += about.cc \
54           add-data.cc \
55           app.cc \
56           dbus-adaptor.cc \
57           details.cc \
58           favicon.cc \
59           file-tree.cc \
60           filterbar.cc \
61           filters.cc \
62           freespace-label.cc \
63           formatter.cc \
64           hig.cc \
65           license.cc \
66           mainwin.cc \
67           make-dialog.cc \
68           options.cc \
69           prefs.cc \
70           prefs-dialog.cc \
71           relocate.cc \
72           session.cc \
73           session-dialog.cc \
74           squeezelabel.cc \
75           stats-dialog.cc \
76           torrent.cc torrent-delegate.cc \
77           torrent-delegate-min.cc \
78           torrent-filter.cc \
79           torrent-model.cc \
80           tracker-delegate.cc \
81           tracker-model.cc \
82           tracker-model-filter.cc \
83           tricontoolbutton.cc \
84           utils.cc \
85           watchdir.cc
86HEADERS += $$replace(SOURCES, .cc, .h)
87HEADERS += speed.h types.h
88
89win32:RC_FILE = qtr.rc
Note: See TracBrowser for help on using the repository browser.